fonction fréquence

[JJ1]

Bonjour,
J'ai une plage A3:T9 contenant des nombres.
Je souhaiterais, à partir de U3 (ligne 3 donc) puis V3,W3, ........tous les nombres de cette plage A3:T9 qui n'y apparaissent qu'une seule fois.
Merci de votre aide
Bonne journée

 

[Gael]

Re : fonction fréquence

Bonjour JJ1,

Essaye la formule suivante:

=PETITE.VALEUR(SI(NB.SI($A$3:$T$9;$A$3:$T$9)=1;$A$3:$T$9);COLONNES($U$5:U$5))

à rentrer en U3 et recopier vers la droite.

Attention: formule matricielle à valider avec Ctrl-Maj-Entrée au lieu de Entrée.

@+

Gael

 

[JJ1]

Re : fonction fréquence

Bonjour Gael et merci pour ta formule matricielle, je teste ce soir.
Bon AM

 

[JJ1]

Re : fonction fréquence

Bonjour Gaël,

J'ai modifié hier soir ta formule :

=PETITE.VALEUR(SI(NB.SI($A$3:$T$9;$A$3:$T$9)=1;$A$3:$T$9);COLONNES($U$5:U$5))

pour avoir les nombres qui apparaissent 4 fois (=4 au lieu de =1), la formule fonctionne mais me copie le même nombre résultat....4 fois à la suite dans les colonnes?
Y-a-t-il moyen de modifier pour avoir le résultat une seule fois?
merci

 

[Gael]

Re : fonction fréquence

Bonjour JJ1,

Comme chaque nombre dans ce cas est présent plusieurs fois, il faut ajouter un test pour ne pas sélectionner un nombre déjà affiché précédemment, et si on élimine les nombres déjà affichés, on prendra à chaque fois la plus petite valeur restante ce qui permet d'utiliser la fonction Min plutot que Petite.valeur soit en cellule U6:

=MIN(SI(NB.SI($U$5:U$5;$A$3:$T$9)=0;SI(NB.SI($A$3:$T$9;$A$3:$T$9)=4;$A$3:$T$9)))

Pour la première cellule (U5), il n'est pas nécessaire de tester les affichages précédents et la formule est simplifiée:

=MIN(SI(NB.SI($A$3:$T$9;$A$3:$T$9)=4;$A$3:$T$9)))

@+

Gael