Fonction avec MOYENNE, SI, ET

[campesinos]

Bonjour,

j'utilise Excel 2002 et j'ai un problème avec une fonction.
Je souhaite calculer la moyenne d'un tableau comprenant :
Colonne A => Régions
Colonne B => Quantité

Pour cela j'utilise les fonctions suivantes :
{=MOYENNE(SI(ET(A10:A900="IDF";A10:A900="PACA";A10:A900="CENTRE");B10:F900))}

Mon problème c'est que lorsque j'utilise l'opérateur ET pour une sélection multiple j'obtiens le résultat 0 (alors qu'il y a bien des valeurs).
Sans l'opérateur ET ma fonction marche impeccable.

Un peu d'aide serait bienvenue car je coince un peu.

Merci

 

[tototiti2008]

Re : Fonction avec MOYENNE, SI, ET

Bonjour campesinos,

Bienvenue sur XLD,

Comme ta région ne peut être IDF, PACA et CENTRE en même temps, essaye de modifier ton ET en OU

 

[tdenfert]

Re : Fonction avec MOYENNE, SI, ET

Bonjour

Il n'est pas possible d'avoir dans la même cellule IDF et PACA et CENTRE
Change le et par ou

Bonjour TOTOTITI2008 même combat

 

[Guest]

Bonjour,

Essaie avec:

{=MOYENNE(SI((A10:A900="IDF")*(A10:A900="PACA")*(A10:A900="CENTRE");B10:F900))}

A+

 

[campesinos]

Re : Fonction avec MOYENNE, SI, ET

Re-bonjour et merci pour votre aide 🙂

J'ai remplacé le ET par le OU comme suit :
{=MOYENNE(SI(OU(A10:A900="IDF";A10:A900="PACA";A10 :A900="CENTRE");B10:F900))}

Malheureusement j'obtiens la moyenne sur l'ensemble de mes 22 régions et n'ont pas uniquement sur les 3 régions demandées.

J'ai aussi essayé avec la fonction proposée par Hasco et le résultat est un "DIV/0!
Je continus à chercher.

 

[tototiti2008]

Re : Fonction avec MOYENNE, SI, ET

Bonjour tdenfer, Bonjour Hasco,
Re,

peut-être

=SOMMEPROD((A2:A32="IDF")+(A2:A32="PACA")+(A2:A32="CENTRE");B2:B32)/SOMMEPROD((A2:A32="IDF")+(A2:A32="PACA")+(A2:A32="CENTRE"))

 

[campesinos]

Re : Fonction avec MOYENNE, SI, ET

Ca ne passe pas non plus.
Je comprends pas, je dois raté un truc c'est pas possible.

 

[tototiti2008]

Re : Fonction avec MOYENNE, SI, ET

Re

Ca ne passe pas non plus.

Sur mon test ça marchait bien
tu peux nous poster un classeur exemple ?

 

[campesinos]

Re : Fonction avec MOYENNE, SI, ET

Je viens de tester ta fonction sur mon fichier mais avec Excel 2007 (je ne suis plus au taf) et ça passe sans problème.
Par contre avec la fonction ou j'utilise OU je n'ai pas le même résultat (le bon étant celui obtenu avec SOMMMEPROD).
J'ai enregistré le classeur au format Excel 97-2003 donc je ne sais pas si demains ça passera au taf avec mon Excel 2002, je testerai, mais c'est très bizarre et contraignant vu que ne ne peux utiliser que cette version.

Voici le classeur

 

[CISCO]

Re : Fonction avec MOYENNE, SI, ET

Bonsoir

Différentes formules en pièce jointe explicitant l'origine des différences.

@ plus

 

[campesinos]

Re : Fonction avec MOYENNE, SI, ET

Bonjour,

J'ai essayé avec les fonctions suivantes :

=SOMMEPROD((A2:A32="IDF")+(A2:A32="PACA")+(A2:A32="CENTRE");B2:B32)/SOMMEPROD((A2:A32="IDF")+(A2:A32="PACA")+(A2:A32="CENTRE"))

=SOMME(((A8:A31="IDF")+(A8:A31="CENTRE")+(A8:A31="PACA"))*B8:B31)/(NB.SI(A8:A31;"IDF")+NB.SI(A8:A31;"CENTRE")+NB.SI(A8:A31;"PACA"))

Dans les 2 cas ça passe sous Excel 2002 que j'utilise.

Merci beaucoup pour votre aide et vos explications.

Cordialement

 

[Guest]

Bonjour à tous.

J'ai fait une erreur de logique. Remplacer * par + . C'est vrai qu'une cellule ne peut avoir deux valeurs à la fois.

Fonction matricielle qui retourne 19.95:

=MOYENNE(SI((A8:A31="IDF")+(A8:A31="CENTRE")+(A8:A31="PACA");B8:B31))

A valider par CTRL+MAJ+ENTREE

A+ à tous

 

[tototiti2008]

Re : Fonction avec MOYENNE, SI, ET

Bonjour à tous,

@Hasco : Bien vu, en remplaçant le OU par + ça fonctionne... reste plus qu'à comprendre pouquoi l'un divise par toutes les lignes et pas l'autre 😉

 

[campesinos]

Re : Fonction avec MOYENNE, SI, ET

Merci Hasco pour ta formule.
Je la note car c'est celle qui se rapproche le plus de ma formule de départ.
Je devrais pouvoir la mémoriser plus facilement, même si je me garde les autres sous le coude. 🙂