Microsoft 365 Fin de trimestre suivant à partir d'une date

kellypombal · 25 Août 2022

Bonjour à toutes et tous,

J'ai une petite problématique, je suis RH au sein d'une association et j'ai une liste de salarié qui doivent passer des entretiens professionnels.
Si ces entretiens ne sont pas faits (avec d'autres critères) alors je dois faire un paiement à la fin du trimestre suivant.
J'aimerais donc savoir s'il existe une formule pour me calculer le trimestre suivant de chaque date.

Ex :
- Date butoir de l'entretien le 13/12/2022. L'abondement (paiement) doit se faire le 31/01/2023.
- Date butoir de l'entretien le 17/01/2023. L'abondement (paiement) doit se faire le 30/06/2023.

J'ai commencé avec =MOIS.DECALE mais ça ne fonctionne pas...

Merci par avance

Hasco · 25 Août 2022

Bonsoir,

Fin Trimestre suivant la date en C1 avec la fonction LET :

=LET(Dte;MOIS.DECALER(C1;3);DATE(ANNEE(Dte);(ENT((MOIS(Dte)-4)/3)+2)*3+1;0))

Sans fonction LET (version excel inférieure à 2019)

=DATE(ANNEE(MOIS.DECALER(C1;3));(ENT((MOIS(MOIS.DECALER(C1;3))-4)/3)+2)*3+1;0)

Et d'autres possibles encore dont celle-ci qui devrait fonctionner :

=MOIS.DECALER(DATE(ANNEE(C1);MOIS(C1)+1;0);CHOISIR(MOD(MOIS(C1)+2;3)+1;5;4;3))

job75 · 26 Août 2022

Bonsoir,

kellypombal à dit:
- Date butoir de l'entretien le 13/12/2022. L'abondement (paiement) doit se faire le 31/01/2023.

Vous voulez dire le 31/03/2023 au lieu du 31/01/2023 ?

Si la date est en A1 entrez en B1 :

Code:

=FIN.MOIS(A1;5-MOD(MOIS(A1)-1;3))

Bonne nuit.

JHA · 26 Août 2022

Bonjour à tous,

Avec la date en "A2" pour le trimestre

VB:

=FIN.MOIS(DATE(ANNEE(A2);CHOISIR(EQUIV(MOIS(A2);{1;4;7;10};1);1;2;3;4)*3;1);0)

pour la date butoir

Code:

=FIN.MOIS(FIN.MOIS(DATE(ANNEE(A2);D1*3;1);0)+1;2)

ou

Code:

=FIN.MOIS(FIN.MOIS(DATE(ANNEE(A2);CHOISIR(EQUIV(MOIS(A2);{1;4;7;10};1);1;2;3;4)*3;1);0)+1;2)

JHA

Hasco · 26 Août 2022

Bonjour,

Pourquoi j'oublie toujours la fonction FIN.MOIS ? C'est pourtant jours de paie

Cordialement

kellypombal · 9 Septembre 2022

Merci beucoup à tous ! ça fonctionne

Microsoft 365 Fin de trimestre suivant à partir d'une date

kellypombal

XLDnaute Nouveau

Hasco

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

JHA

XLDnaute Barbatruc

Pièces jointes

Hasco

XLDnaute Barbatruc

kellypombal

XLDnaute Nouveau

Discussions similaires