XL 2010 Faire une somme même s'il y a du texte

[sophiem63]

Bonjour à tous,
Je cherche une solution pour pouvoir faire dans la colonne G, la somme des valeurs des cases N, U AB, AI, ... (voir fichier joint).
Dans ces cases à sommer, il se peut qu'il y ait du texte et je souhaiterai alors que la valeur dans la colonne G soit ce texte (il n'y aura jamais deux cases avec du texte sur une même ligne). (comme sur la ligne 1)
S'il n'y a pas de texte et qu'il n'y a que des nombres, je souhaite faire la somme de ces nombres. (comme sur la ligne 2)
Dans le 1er cas, je n'obtient que des #VALEUR... Je sèche depuis 2 heures...
Merci par avance de votre aide !
Sophie

 

[Yurperqod]

Bonjour le forum

Avec cette formule, c'est bon ?
=SOMME(N1;U1;AB1;AI1;AP1;AW1;BD1;BK1;BR1;BY1;CF1;CM1;CT1;DA1;DH1)

 

[Jocelyn]

Bonjour le Forum,
Bonjour sophiem63,

tu peux tester en G1,

=SOMMEPROD((MOD(COLONNE(I1:DH1);7)=0)*1;I1:DH1)

ou

=SOMME(N1;U1;AB1;AI1;AP1;AW1;BD1;BK1;BR1;BY1;CF1;CM1;CT1;DA1;DH1)

Cordialement

EDIT : Bonjour Yurperqod, désolé pour la collision

 

[sophiem63]

Merci de vos réponses rapides, malheureusement, ces formules me donnent comme résultat "0", ce qui n'est pas faux, certes ...
Mais je souhaiterai avoir comme résultat dans G1 : "Compris"
et dans G2 : "18", ça c'est bon ça marche sans soucis.

 

[Jocelyn]

re,

Hum hum ce n'est pas bien de ne pas donner toutes les consigne d'un coup

bon alors avec le sommeprod

=SI(SOMMEPROD((MOD(COLONNE(I1:DH1);7)=0)*1;I1:DH1)=0;RECHERCHE("zzzz";I1:DH1);SOMMEPROD((MOD(COLONNE(I1:DH1);7)=0)*1;I1:DH1))

avec le somme

SI(SOMME(N1;U1;AB1;AI1;AP1;AW1;BD1;BK1;BR1;BY1;CF1;CM1;CT1;DA1;DH1)=0;RECHERCHE("zzzz";I1:DH1);SOMME(N1;U1;AB1;AI1;AP1;AW1;BD1;BK1;BR1;BY1;CF1;CM1;CT1;DA1;DH1))

Regardes et dis nous

Cordialement

 

[Yurperqod]

Bonjour jocelyn

Si on remplace ta formule en G2 par une avec SOMME sur le modèle de celle que jocelyn et moi on a posté, ça affiche bien 18 pourtant.

 

[sophiem63]

re,

Hum hum ce n'est pas bien de ne pas donner toutes les consigne d'un coup

bon alors avec le sommeprod

=SI(SOMMEPROD((MOD(COLONNE(I1:DH1);7)=0)*1;I1:DH1)=0;RECHERCHE("zzzz";I1:DH1);SOMMEPROD((MOD(COLONNE(I1:DH1);7)=0)*1;I1:DH1))

avec le somme

SI(SOMME(N1;U1;AB1;AI1;AP1;AW1;BD1;BK1;BR1;BY1;CF1;CM1;CT1;DA1;DH1)=0;RECHERCHE("zzzz";I1:DH1);SOMME(N1;U1;AB1;AI1;AP1;AW1;BD1;BK1;BR1;BY1;CF1;CM1;CT1;DA1;DH1))

Regardes et dis nous

Cordialement

Re,
Ah ben avec la 2nde ça fonctionne impeccable !
Je m'étais peut-être mal exprimée : "et je souhaiterai alors que la valeur dans la colonne G soit ce texte", désolée !

Du coup, si je comprend bien, il faut que le texte dans les différentes cases soit "inférieur" à zzzz, en gros ?

 

[Jocelyn]

C'est ca puisque ZZZZ ne sera a priori jamais trouvé car aucun mot a ma connaissance ne commence par 4 Z

Donc la partie recherche("zzzz";I1: DH1) va renvoyer la valeur texte de la cellule la plus éloignée dans cette plage dans l'exemple "Compris" est en colonne AG1 si tu mets par exemple "Achat" bd1 le renvoie en G sera achat pour simplifier la derniere valeur texte trouvée dans la plage I1H1

Cordialement

 

[sophiem63]

Ok super!!!
Mais en tirant la formule à tout mon tableau, je m’aperçois d'un petit problème... j'aurai besoin d'un petit complément, qui n'était pas demandé dans mon 1er post (une consigne en plus ) :
Si toutes les cellules de la sélection à sommer sont vides, j'ai un #N/A qui apparait.
Peut-on ajouter une condition ? En cas de somme égale à zéro, on a zéro (ou rien).
Pour info, cela peut être associée à la cellule F1 : si F1 n'a pas de valeur numérique, je sais que je n'aurai rien dans ma sélection et je souhaite mettre zéro (ou rien) en G1.
Si F1 a une valeur numérique, je sais que j'aurai des chiffres ou des mots dans ma sélection et j'utilise ta fonction de somme citée plus haut.

Désolée de ne voir ça que maintenant ...

 

[Jocelyn]

re,

Pas de soucis j'étais juste en format plaisanterie avec les consignes,

alors comme je ne sais par quelle formule tu préfères

avec sommeprod()

=sierreur(SI(SOMMEPROD((MOD(COLONNE(I1:DH1);7)=0)*1;I1:DH1)=0;RECHERCHE("zzzz";I1:DH1);SOMMEPROD((MOD(COLONNE(I1:DH1);7)=0)*1;I1:DH1));"")

avec somme

=SIERREUR(SI(SOMME(N1;U1;AB1;AI1;AP1;AW1;BD1;BK1;BR1;BY1;CF1;CM1;CT1;DA1;DH1)=0;RECHERCHE("zzzz";I1:DH1);SOMME(N1;U1;AB1;AI1;AP1;AW1;BD1;BK1;BR1;BY1;CF1;CM1;CT1;DA1;DH1));"")

Voila

 

[sophiem63]

re,

Pas de soucis j'étais juste en format plaisanterie avec les consignes,

alors comme je ne sais par quelle formule tu préfères

avec sommeprod()

=sierreur(SI(SOMMEPROD((MOD(COLONNE(I1:DH1);7)=0)*1;I1:DH1)=0;RECHERCHE("zzzz";I1:DH1);SOMMEPROD((MOD(COLONNE(I1:DH1);7)=0)*1;I1:DH1));"")

avec somme

=SIERREUR(SI(SOMME(N1;U1;AB1;AI1;AP1;AW1;BD1;BK1;BR1;BY1;CF1;CM1;CT1;DA1;DH1)=0;RECHERCHE("zzzz";I1:DH1);SOMME(N1;U1;AB1;AI1;AP1;AW1;BD1;BK1;BR1;BY1;CF1;CM1;CT1;DA1;DH1));"")

Voila

Super merci beaucoup !! ça fonctionne parfaitement!!