Faire une moyenne 10 valeurs par 10 valeurs - RESOLU

[Flavihec]

Bonjour à tous,

Dans l'exemple ci-joint, l'idée est de passer d'une période de 0,01 à une période de 0,1, je dois donc faire un changement d'échelle. Pour se faire, je souhaite calculer la moyenne des "valeurs 1" allant de 1,01 à 1,1 pour faire une valeur correspondant à 1,1.

Bien sûr, manuellement c'est très simple mais je souhaite automatiser tout ça (dans mon vrai fichier de travail j'ai plusieurs dizaines de milliers de lignes !)

Quelqu'un de vous pourrait m'aider ?!

Merci d'avance 😉

RÉSOLUTION : voir 1ère solution de la réponse de KenDev :
=(SOMME.SI(A$2:A5000;"<=" & D2;B$2:B$5000)-SOMME.SI(A$2:A5000;"<=" & D2-0,1;B$2:B$5000))/(NB.SI(A$2:A5000;"<=" & D2)-NB.SI(A$2:A5000;"<=" & D2-0,1))
Solution à faire défiler pour appliquer à toutes les colonnes

 

[KenDev]

Re : Faire une moyenne 10 valeurs par 10 valeurs

Bonjour Flavihec,

2 propositions :

=(SOMME.SI(A$2:A101;"<=" & D2;B$2:B$101)-SOMME.SI(A$2:A101;"<=" & D2-0,1;B$2:B$101))/(NB.SI(A$2:A101;"<=" & D2)-NB.SI(A$2:A101;"<=" & D2-0,1))

et

=(INDIRECT("B"&10*(LIGNE(A2)-2)+2)+INDIRECT("B"&10*(LIGNE(A2)-2)+3)+INDIRECT("B"&10*(LIGNE(A2)-2)+4)+INDIRECT("B"&10*(LIGNE(A2)-2)+5)+INDIRECT("B"&10*(LIGNE(A2)-2)+6)+INDIRECT("B"&10*(LIGNE(A2)-2)+7)+INDIRECT("B"&10*(LIGNE(A2)-2)+8)+INDIRECT("B"&10*(LIGNE(A2)-2)+9)+INDIRECT("B"&10*(LIGNE(A2)-2)+10)+INDIRECT("B"&10*(LIGNE(A2)-2)+11))/10

Cordialement

KD

 

[Compte Supprimé 979]

Re : Faire une moyenne 10 valeurs par 10 valeurs

Salut Flavihec ;-)

Si j'ai bien compris, tu mets en E2 la formule suivante

=SOMMEPROD((A$2:A$5000>=D2)*(A$2:A$5000<D3)*B$2:B$5000)/SOMMEPROD((A$2:A$5000>=D2)*(A$2:A$5000<D3))

Recopie ves le bas

A+

Edit : salut KD 😀

 

[Tibo]

Re : Faire une moyenne 10 valeurs par 10 valeurs

Bonjour le fil,

Un essai avec une formule matricielle en E2 :

=MOYENNE(SI(ENT($A$2:$A$101*10)/10=D2;$B$2:$B$101))

Formule matricielle à valider par CTRL + MAJ + ENTREE

à recopier vers le bas

@+

 

[CISCO]

Re : Faire une moyenne 10 valeurs par 10 valeurs

Bonjour

Une autre possibilité

MOYENNE(SI((D2-0,1<A$2:A$101)*(A$2:A$101<=D2);B$2:B$101))

toujours en matriciel

@ plus

 

[Flavihec]

Re : Faire une moyenne 10 valeurs par 10 valeurs

Bonjour à tous,
Merci bien pour toutes ces réponses ! J'ai tout essayé, et il semble que THE solution soit plutôt celle de KenDev, ça marche parfaitement dans mon cas.

Maintenant je vais essayer de décomposer la formule afin de bien la comprendre et de pouvoir la refaire, comme tout bon élève 🙂

Merci encore, à bientôt 😉

 

[KenDev]

Re : Faire une moyenne 10 valeurs par 10 valeurs - RESOLU

Merci bien pour toutes ces réponses ! J'ai tout essayé, et il semble que THE solution soit plutôt celle de KenDev, ça marche parfaitement dans mon cas.
RÉSOLUTION : voir 1ère solution de la réponse de ZenDee :
=(SOMME.SI(A$2:A5000;"<=" & D2;B$2:B$5000)-SOMME.SI(A$2:A5000;"<=" & D2-0,1;B$2:B$5000))/(NB.SI(A$2:A5000;"<=" & D2)-NB.SI(A$2:A5000;"<=" & D2-0,1))
Solution à faire défiler pour appliquer à toutes les colonnes

Bonjour à tous,

Mais c'est qui ce ZenDee 😕 La formule donnée marche bien mais il aurait été plus rigoureux de l'écrire

=(SOMME.SI(A$2:A$5000;"<=" & D6;B$2:B$5000)-SOMME.SI(A$2:A$5000;"<=" & D6-0,1;B$2:B$5000))/(NB.SI(A$2:A$5000;"<=" & D6)-NB.SI(A$2:A$5000;"<=" & D6-0,1))

La solution de Cisco marche très bien aussi et est plus courte...

Cordialement

KD