Faire la liste des mots-clefs d'un tableau

[rabany]

Soit un tableau de m lignes et n colonnes. Chaque cellule contient plusieurs mots-clefs séparés par des espaces. J'aimerais constituer dans une colonne extérieure au tableau ou dans une autre feuille une liste des mots-clefs avec un seul mot-clef par cellule sachant que le même mot-clef peut être contenu dans plusieurs cellules du tableau. Quelqu'un a-t-il une idée?
Merci

 

[skoobi]

Re : Faire la liste des mots-clefs d'un tableau

Bonjour,

Ci-joint un exemple sur ce que tu veux faire (à adapter).

 

[Hervé]

Re : Faire la liste des mots-clefs d'un tableau

bonjour

pour m'amuser le meme code avec un trie alphabetique des mots cléfs.

merci skoobi

Sub mot_clef()
Dim liste As New Collection
Dim cellule As Range
Dim mc, temp1, temp2, v
Dim i As Integer, j As Integer, n As Integer

For Each cellule In Range([A1], [A1].SpecialCells(xlCellTypeLastCell))
   mc = Split(cellule.Value, " ")
   For Each v In mc
      On Error Resume Next
      liste.Add v, CStr(v)
      On Error GoTo 0
   Next v

    
Next cellule


   For i = 1 To liste.Count - 1
        For j = i + 1 To liste.Count
            If liste(i) > liste(j) Then
                temp1 = liste(i)
                temp2 = liste(j)
                liste.Add temp1, before:=j
                liste.Add temp2, before:=i
                liste.Remove i + 1
                liste.Remove j + 1
            End If
        Next j
    Next i

For n = 1 To liste.Count
   With Sheets("Feuil2")
      .Cells(n, 1).Value = liste(n)
   End With
Next n
Sheets("Feuil2").Activate
End Sub

salut

 

[skoobi]

Re : Faire la liste des mots-clefs d'un tableau

Salut Hervé,
mais de rien 🙂