XL 2016 Extraite lettre de cellule - RESOLU

gigiwin · 25 Septembre 2020

Bonjour,

Dans mon tableau j'ai en colonne G une liste de NOM Prénom.
Il me faut extraire les 3 premières lettres du PRÉNOM et du NOM, et mettre le tout en majuscule.
Par exemple DUBOIS Marie--->MARDUB.

J'ai bien trouvé la formule qui me fais cela:
=(MAJUSCULE(STXT(G2;TROUVE(" ";G2)+1;3))&(GAUCHE(G2;3)))
mais si j'ai une cellule avec NOM NOM Prénom; cela ne fonctionne pas. Et là, je sèche...
Que dois-je modifier au cas ou il y a 2 espace dans la cellule, mais que ça fonctionne aussi si il n'y en a qu'un?

Merci de votre aide.

Dugenou · 25 Septembre 2020

Bonjour,
Lier les deux noms avec _ au lieu d'un espace ??

herve62 · 25 Septembre 2020

Bonjour
Est ce un truc comme ça ? sauf que j'arrive pas à généraliser ... avec un SI imbriqué en plus ? mais là avec mon niveau en formules .....euh ?????

gigiwin · 25 Septembre 2020

Dugenou à dit:
Bonjour,
Lier les deux noms avec _ au lieu d'un espace ??

Bonjour,

Je ne peux pas modifier la liste de nom, donc je ne peux remplacer l'espace par un tiret,
mais merci pour la suggestion.

gigiwin · 25 Septembre 2020

herve62 à dit:
Bonjour
Est ce un truc comme ça ? sauf que j'arrive pas à généraliser ... avec un SI imbriqué en plus ? mais là avec mon niveau en formules .....euh ?????

bonjour Herve62,

merci pour l'aide et la formule, elle fonctionne mais seulement s'il y 2 espaces, pas avec 1 espace.
je continue mes recherches.

Dugenou · 25 Septembre 2020

Re,
On pourrait faire un calcul qui donne l'emplacement du dernier espace, mais vous allez certainement avoir des cas avec deux prénoms séparés par un espace..
Je suggère d'avoir une colonne avec l'emplacement de l'espace que vous corrigez à la main pour les cas particuliers.
Cordialement

gigiwin · 25 Septembre 2020

Dugenou à dit:
Re,
On pourrait faire un calcul qui donne l'emplacement du dernier espace, mais vous allez certainement avoir des cas avec deux prénoms séparés par un espace..
Je suggère d'avoir une colonne avec l'emplacement de l'espace que vous corrigez à la main pour les cas particuliers.
Cordialement

Merci de t'intéressé à mon problème.
j'aurais du spécifier dans ma demande que je ne peux pas ajouter de colonne.
je n'ai accès qu'à une seule colonne; celle où je dois mettre la formule recherchée.

Victor21 · 25 Septembre 2020

Bonjour à tous.

Essayez en AJ1 :

VB:

=SI(NBCAR(G3)-NBCAR(SUBSTITUE(G3;" ";""))=1;MAJUSCULE(STXT(G3;TROUVE(" ";G3)+1;3))&(GAUCHE(G3;3));
SI(NBCAR(G3)-NBCAR(SUBSTITUE(G3;" ";""))=2;MAJUSCULE(STXT(G3;TROUVE(" ";G3)+TROUVE(" ";G3);3)&(GAUCHE(G3;3)));"Traitement manuel"))

Fonctionne pour concaténer les trois premières lettres du premier terme, et les trois premières lettres du deuxième terme s'il y en a deux, (JULLAM pour Lambert Julien )ou du troisième terme s'il y en a trois (MARFOR pour Fortin Piret Marie).

Pour Charles Henri De La Rochefoucault, il faudra trouver un magicien

job75 · 25 Septembre 2020

Bonjour à tous,

Victor21 à dit:
Pour Charles Henri De La Rochefoucault, il faudra trouver un magicien

Il suffira de télécharger sur le web la liste des prénoms recensés en France pour les distinguer.

En 2019 il y en avait 33000... C'est peanuts pour Excel...

A+

Dugenou · 25 Septembre 2020

Job,
Je savais bien que tu étais magicien !

job75 · 25 Septembre 2020

Bon Dugenou sauf que j'ai cherché sur le web (pas longtemps) sans beaucoup de succès...

laurent950 · 25 Septembre 2020

Bonjour,
Voici la Formule :
Ecrire en G2 : DUBOIS Marie / Prénom Nom / --->MARDUB
Ou
Ecrire en G2 : Lambert DUBOIS Marie / Prénom Nom Nom / ----> MARLAMDUB

Formule en G2 à recopier vers le bas ci dessous.
* Sans gestion des espaces entre les noms = pour

VB:

(DUBOIS Marie) ou (Lambert DUBOIS Marie)

* Avec gestion des espaces entre les noms = pour

VB:

(DUBOIS     Marie) ou (Lambert    DUBOIS                   Marie)

Formule : si il y a des 1 seul espace entre les noms et le prénom.

VB:

En G2 pour Test : (AA1rrrrrrr BB2rrrrrrrrrr CC3rrrrrr)  ------>>>>   CC3AA1BB2
Formule a recopier en H2 : =SI(SOMMEPROD((NBCAR(G2)-NBCAR(SUBSTITUE(G2;" ";""))))=1;MAJUSCULE(STXT(DROITE(G2;NBCAR(G2)-TROUVE(" ";G2;1));1;3)&STXT(GAUCHE(G2;TROUVE(" ";G2;1));1;3));MAJUSCULE(STXT(DROITE(G2;NBCAR(G2)-TROUVE(" ";G2;TROUVE(" ";G2;1)+1));1;3)&STXT(GAUCHE(G2;TROUVE(" ";G2;1));1;3)&GAUCHE(SUPPRESPACE(STXT(G2;TROUVE(" ";G2;1);TROUVE(" ";G2;TROUVE(" ";G2;1)+1)-TROUVE(" ";G2;1)));3)))

Formule Bonus : si il y a des beaucoup d'espaces entre les nom et prénom soit 2 ou 3 ou 4 ou 5 etc.

VB:

En G2 pour Test : (AA1rrrrrrr         BB2rrrrrrrrrr           CC3rrrrrr)  ------>>>>   CC3AA1BB2
ormule a recopier en H2 : =SI(SOMMEPROD((NBCAR(SUPPRESPACE(G2))-NBCAR(SUBSTITUE(SUPPRESPACE(G2);" ";""))))=1;MAJUSCULE(STXT(DROITE(SUPPRESPACE(G2);NBCAR(SUPPRESPACE(G2))-TROUVE(" ";SUPPRESPACE(G2);1));1;3)&STXT(GAUCHE(SUPPRESPACE(G2);TROUVE(" ";SUPPRESPACE(G2);1));1;3));MAJUSCULE(STXT(DROITE(SUPPRESPACE(G2);NBCAR(SUPPRESPACE(G2))-TROUVE(" ";SUPPRESPACE(G2);TROUVE(" ";SUPPRESPACE(G2);1)+1));1;3)&STXT(GAUCHE(SUPPRESPACE(G2);TROUVE(" ";SUPPRESPACE(G2);1));1;3)&GAUCHE(SUPPRESPACE(STXT(SUPPRESPACE(G2);TROUVE(" ";SUPPRESPACE(G2);1);TROUVE(" ";SUPPRESPACE(G2);TROUVE(" ";SUPPRESPACE(G2);1)+1)-TROUVE(" ";SUPPRESPACE(G2);1)));3)))

herve62 · 25 Septembre 2020

@laurent950 !!!!t'aurais pas un peu plus compliqué ???

laurent950 à dit:
Lambert DUBOIS Marie

pour ce cas il veut : MARLAM et pas MARLAMDUB c'est ce que j'avais trouvé mais si on etend ma formule avec juste 1 espace ...ça va plus
vous avez bien une solution ..non ???? à mon avis il n'y a que celle de Patrick !!! mais prendre abonnement avec décodeur Excel + !!!!

mapomme · 26 Septembre 2020

Bonjour à tous ,

Pour le fun, une formule matricielle.

Deux hypothèses :

les noms sont entièrement en majuscule
les prénoms sont entièrement en minuscule sauf la première lettre qui est en majuscule

Formule matricielle en H2 à tirer vers le bas :

VB:

=MAJUSCULE(GAUCHE(GAUCHE(G2;CHERCHE(" ";G2))&"   ";3) & STXT(G2&"   ";MIN(SI(EXACT(MINUSCULE(STXT(SUBSTITUE(G2&"aaa";" ";"A");LIGNE($2:$99);3));STXT(SUBSTITUE(G2&"aaa";" ";"A");LIGNE($2:$99);3));LIGNE($2:$99)-1;""));3))

job75 · 26 Septembre 2020

Bonjour le forum,

Moi j'attends qu'un XLDnaute courageux me fournisse la liste des 33000 prénoms recensés en France.

Cela devrait pouvoir se trouver sur le web.

Et cela sera utile pour choisir les prénoms de mes futurs arrières-petits-enfants qui ne vont pas tarder à arriver.

Bon week-end.

XL 2016 Extraite lettre de cellule - RESOLU

gigiwin

XLDnaute Occasionnel

Pièces jointes

Dugenou

XLDnaute Barbatruc

herve62

XLDnaute Barbatruc

Pièces jointes

gigiwin

XLDnaute Occasionnel

gigiwin

XLDnaute Occasionnel

Dugenou

XLDnaute Barbatruc

gigiwin

XLDnaute Occasionnel

Victor21

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

Dugenou

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

laurent950

XLDnaute Barbatruc

herve62

XLDnaute Barbatruc

mapomme

XLDnaute Barbatruc

Pièces jointes

job75

XLDnaute Barbatruc

Discussions similaires