Autres Excel 2007 - Clic sur une cellule et faire changer de couleur une autre cellule

[Massenie57]

Bonjour à tous, n'étant pas un professionnel de Excel, je cherche le moyen lors d'un clic sur une cellule (ex: B6) faire changer de couleur en jaune une autre cellule (ex: C16). Quelqu'un peut il m'aider en m'expliquant la démarche ? Je suis sous Excel 2007. Merci

 

[Calvus]

Bonjour et bienvenue,

A mettre dans le code de la feuille.

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Intersect(Range("B6"), Target) Is Nothing And Target.Count = 1 Then Exit Sub
[C16].Interior.Color = 65535
Cancel = True
End Sub

A+

 

[Massenie57]

Merci Calvus pour l'aide. Une dernière chose je reproduit le code autant de fois que nécessaire en changeant la valeur des cellules si je veux cliquer sur D6 qui active D17 etc....

 

[Calvus]

Re,

Je dois regarder.

A+

 

[Calvus]

Re,

Comme ça alors :

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Address = [B6].Address Then
    [C16].Interior.Color = 65535
Else
    If Target.Address = [D6].Address Then
        [D17].Interior.Color = 65535
    End If
End If
Cancel = True
End Sub

A+

 

[Calvus]

Re,

Maintenant, on peut mieux faire, mais sans fichier...

A+

 

[Massenie57]

Merci beaucoup Calvus.

 

[Staple1600]

Bonjour le fil,

Un autre code

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
On Error Resume Next
Target.Offset(1, 10).Interior.Color = vbYellow
End Sub

[dernière phrase]
Mais comme le signale, Calvus (que je salue au passage ), avec un fichier exemple et plus de détails et explication, on pourrait répondre plus précisément.
[/dernière phrase]

 

[Calvus]

Bonjour Massenie57, Staple ,

@Staple1600 Tu ne peux pas décaler de cette façon dans ce cas, puisqu'il décale une fois de 10 et une fois de 11..

Bonne journée.

 

[Staple1600]

Re

D'où la présence de ma dernière phrase dans mon précédent message

 

[Calvus]

Re,

Oui c'est sûr !

 

[Massenie57]

Merci pour vos réponses. Je vous joint le fichier.
J'aimerai pouvoir quand je clique sur une autre case que la précédente revienne en blanc.
Dans le tableau il y a des suites de cases mais il n'y a pas forcément d’ordre logique entre le bandeau de la baie et le répartiteur.
Si cela est trop compliqué on laisse tombé. Je ne veux pas être un boulet.
Merci à vous tous.

 

[Dranreb]

Bonjour.
Une proposition avec une MeFC, règle Formule : =C22=ValCel, Format en jaune, s'appliquant à =$C$22:$J$27
et dans le module de l'objet Worksheet :

Option Explicit
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
   Me.Names.Add "ValCel", Target(1 + Target.Row Mod 2, 1).Value
   End Sub

 

[Staple1600]

Re

Merci pour le fichier joint.
Testes ce code
(à mettre dans le code de la feuille)

Private Sub Worksheet_SelectionChange(ByVal T As Range)
Static r As Range
If Not Intersect(Range("C22:J27,C30:J40"), T) Is Nothing Then
    On Error Resume Next
    r.FormatConditions.Delete
    T.FormatConditions.Add(Type:=2, _
    Formula1:=-1).Interior.Color = vbYellow
    Set r = T
End If
End Sub

Est-ce qu'on se rapproche du résultat souhaité?

EDITION
Bonjour Dranreb
Je n'avais pas rafraichi la page avant de poster.

 

[eriiic]

Bonjour à tous,

en restant sur le double-clic :

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    Dim v, c As Range
    If Not Intersect(Target, Rows("5:16")) Is Nothing Then
        Cancel = True
        v = Cells(Int((Target.Row + 1) / 2) * 2, Target.Column)
        With [C22:J40]
            .Interior.ColorIndex = xlNone
            If v <> "" Then
                Set c = .Find(v, , xlValues, xlWhole)
                If Not c Is Nothing Then c.Interior.Color = vbYellow
            End If
        End With
    End If
End Sub

tu peux double-cliquer également sur le n° indiqué au-dessus de la valeur (ie : B9 ou B10)
eric