Evolution d'un classement

[seblosc1]

Bonjour à tous,
j'ai un tableau excel qui classe des équipes de foot selon leurs résultats quotidiens. Chaque jour j'entre leurs scores, et j'execute une petite macro pour classer mon tableau par points.

J'aimerai savoir s'il est possible d'avoir quelque chose comme une petite flèche, associée à chaque nom d'équipe, qui permet de montrer l'évolution du classement d'une équipe entre chaque jour, mais de manière automatique. Cela supposerait qu'excel se "souvienne" du classement précédent le tri à chaque fois mais je ne sais pas si ça existe...

Merci d'avance !

 

[Hulk]

Re : Evolution d'un classement

Salut seblosc1, le Forum,

Si je peux me permettre, joins un petit bout de ton classeur, tu auras plus de chance d'être aidé !

Bonne journée.

Hulk.

 

[Lord Nelson]

Re : Evolution d'un classement

Salut Seblosc, Hulk,

Voici une piste :

L'évènement WorkSheet_Activate retient le classement précédent dans un tableau "Rang".
Lorsque le nombre de points est modifié, le nouveau classement est comparé au tableau "Rang" et la colonne D reçoit une des trois flèches.

A+
Horatio

 

[seblosc1]

Re : Evolution d'un classement

C'est nickel chrome ! ! exactement ça ! Merci beaucoup Lord Nelson !
Par contre je ne comprends pas comment marche la colonne D, il n'y a aucune formule dedans... C'est surement ce que tu appelles "Form_Activate" mais je ne sais pas comment ça s'active.
En tout cas merci encore !

 

[Lord Nelson]

Re : Evolution d'un classement

Re,

Tu trouveras le code en tapant Alt F11 pour basculer sous VBA puis un double-clic sur "Feuil1".

Tu verras alors ceci :

Dim Rang(9) As Long

Private Sub Worksheet_Activate()
Dim I As Long
For I = 3 To 9
  Rang(I) = Range("C" & I)
Next

End Sub

Cette boucle mémorise le classement des équipes.

Puis ceci :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim I As Long
If Not Intersect(Target, Range("B3:B9")) Is Nothing Then
  For I = 3 To 9
    If Range("C" & I) < Rang(I) Then
      Range("D" & I) = Chr(246)
    ElseIf Range("C" & I) > Rang(I) Then
      Range("D" & I) = Chr(248)
    Else
      Range("D" & I) = Chr(243)
    End If
  Next
End If
End Sub

Là on guette les changements survenus dans la colonne B (attribution des points) et, pour chaque équipe, on compare le nouveau classement (colonne C) avec le classement précédent.
Si le nouveau classement est inférieur, on fait apparaître en colonne D une flèche montante (le caractère 246 de la police Wingdings). S'il est supérieur, on appelle le caractère 248 (flèche descendante), sinon la flèche horizontale (code 243).

Content d'avoir pu t'aider.

A+
Horatio

 

[seblosc1]

Re : Evolution d'un classement

Génial merci beaucoup c'est très clair !
A+