Eviter addition dans SOMMEPROD

[culty]

Bonjour à tous,

Sauriez-vous comment éviter les additions dans SOMMEPROD, exemple :

=SOMMEPROD((A1:A50=X)+(A1:A50=Y)+(A1:A50=Z) etc ... ; B1:B50)

En fait je veux la somme de toutes les lignes ayant dans la colonne A une valeur appartenant à une colonne prédéfinie dans une autre feuille.

Il me faudrait :

=SOMMEPROD(A1:A50=appartient à colonne W ; B1:B50)

"W"
X
Y
Z
...

Merci beaucoup d'avance

 

[Tibo]

Re : Eviter addition dans SOMMEPROD

Bonjour,

J'ai un peu de mal à comprendre ce que tu veux obtenir.

L'idéal : joins nous un petit bout de fichier avec suffisamment de lignes et exemples pour que ce soit plus clair pour nous

A te (re)lire avec ce fichier

@+

 

[abcd]

Re : Eviter addition dans SOMMEPROD

Bonjour,

Pas facile à comprendre.
Avec un exemple en pièce jointe, reprenant les données de départ et le résultat à obtenir, on pourra essayer de t'aider.

abcd

Edition :
Salut Tibo, je craignais être le seul !

 

[culty]

Re : Eviter addition dans SOMMEPROD

Voilà l'exemple
Cordialement

 

[JeanMarie]

Re : Eviter addition dans SOMMEPROD

Bonjour tout le monde

Tu as plusieurs solutions :

° Formule à valider par les touches Ctrl+Shift+Entrer

=SOMME((H$2:H$50=TRANSPOSE(A18:A23))*$I$2:$I$50)

° Formule à valider normalement

=SOMMEPROD(NB.SI(A18:A22;$H$2:$H$50)*$I$2:$I$50)

° une dernière pour la route, à valider par les trois touches

=SOMMEPROD(FREQUENCE(SI($H$2:$H$50=TRANSPOSE($A$18:$A$23);LIGNE($H$2:$H$50));LIGNE($H$2:$H$49));$I$2:$I$50)

Edit : pour être complet
à valider par les trois touches

=SOMMEPROD(FREQUENCE(SI(ESTNUM(EQUIV($H$2:$H$50;A$18:A$23;0));LIGNE($H$2:$H$50));LIGNE(H2:H49))*$I$2:$I$50)

PS : http://www.excel-downloads.com/foru...le pour comprendre l'utilisation du TRANSPOSE

Edit : Ces quatres formules fonctionnent, elles retournent le même résultat. Ce qui change c'est la manière de traiter les tableaux de données. Ne vous fiez pas à la longueur de la formule, la dernière étant la plus rapide

@+Jean-Marie

 

[culty]

Re : Eviter addition dans SOMMEPROD

La seconde formule à valider normalement fonctionne parfaitement , merci beaucoup JeanMarie pour ton aide et aux autres pour le temps passé.

très cordialement