EQUIV sur une condition et non pas sur une valeur cherchée

[lysiounette]

Bonjour à tous, voici mon problème
J'ai la ligne suivante :

A B C D E F G
Chloroforme x 0,03 x 0,1 x 0,2 x


Je désire avoir le numéro de la première colonne pour laquelle il y a une valeur numérique (B) ; puis le numéro de la 2ème colonne (D), puis le numéro de la 3ème colonne (G)

La formule EQUIV(0;A1:G1;-1) ne marche pas, ce qui est normal puisque je n'ai pas la valeur 0 dans ma ligne ; de plus, le -1 ne me renvoie qu'une valeur, et pas la première (colonne B)

Avez-vous qqchose à me proposer?

En vous remerciant chaleureusement 🙂

 

[Habitude]

Re : EQUIV sur une condition et non pas sur une valeur cherchée

Je ne suis pas sur de bien comprendre

Envoie un fichier avec explication et résultat attendu.

 

[lysiounette]

Re : EQUIV sur une condition et non pas sur une valeur cherchée

Ah oui pardon je n'avais pas vu que mon exemple rendait aussi mal 🙂
Voilà un bout du fichier :

 

[david84]

Re : EQUIV sur une condition et non pas sur une valeur cherchée

Bonjour,
à tester : =EQUIV(PETITE.VALEUR(SI(ESTNUM($A$1:$O$1);$A$1:$O$1);LIGNES($1:1));SI(ESTNUM($A$1:$O$1);$A$1:$O$1);0)
Formule matricielle à valider par ctrl, maj et entrée et à tirer vers le bas
Te donne le n° de la colonne.
A+

NB : avec condition permettant de cacher les valeurs d'erreur :
=SI(LIGNES($1:1)>SOMME(N(ESTNUM($A$1:$O$1)));"";EQUIV(PETITE.VALEUR(SI(ESTNUM($A$1:$O$1);$A$1:$O$1);LIGNES($1:1));SI(ESTNUM($A$1:$O$1);$A$1:$O$1);0))

 

[Habitude]

Re : EQUIV sur une condition et non pas sur une valeur cherchée

Matricielle et VBA

 

[JHA]

Re : EQUIV sur une condition et non pas sur une valeur cherchée

Bonjour David84, le forum,

J'étais arrivé au même résultat que toi avec petite.valeur mais si tu mets une valeur supérieure en colonne "B" cela nous donne un résultat qui ne correspond pas avec la demande de notre amie:
Je désire avoir le numéro de la première colonne pour laquelle il y a une valeur numérique

En VBA cela donne le résultat escompté, as tu une idée de modif?

JHA

 

[Tibo]

Re : EQUIV sur une condition et non pas sur une valeur cherchée

Bonjour,

Une adaptation de la formule proposée par David 🙂 :

=EQUIV(PETITE.VALEUR(SI(ESTNUM($A$1:$O$1);ESTNUM($A$1:$O$1)*COLONNE($A$1:$O$1));
LIGNES($1:1));SI(ESTNUM($A$1:$O$1);ESTNUM($A$1:$O$1)*COLONNE($A$1:$O$1));0)

Matricielle, donc validation par CTRL + MAJ + ENTREE

@+

 

[JHA]

Re : EQUIV sur une condition et non pas sur une valeur cherchée

Bonjour Tibo,

Bien vu le rajout de colonne(), cela est parfait.

JHA