Envoi e-mail auto contenant link Excel

Lauglé · 17 Janvier 2008

Bonjour,
Je souhaiterai créer, à partir d'EXCEL, un mail automatique qui contiendrait le lien (link) du fichier EXCEL, et non le fichier EXCEL attaché en pièce jointe.
Comment faire ?

Merci pour votre aide.
Cordialement.
Christophe.

MichelXld · 17 Janvier 2008

Re : Envoi e-mail auto contenant link Excel

bonsoir

Le classeur qui contient la macro est supposé placé en réseau:

Code:

Sub CreationMailEtLienHypertexte()
    Dim OlApp As Outlook.Application
    Dim OlItem As Outlook.MailItem
    'Nécessite d'activer la référence "Microsoft Outlook xx.x Object Library"
    
    Set OlApp = New Outlook.Application
    Set OlItem = OlApp.CreateItem(olMailItem)
    
    With OlItem
        .To = "[EMAIL="NomPrenom@mail.fr"]NomPrenom@mail.fr[/EMAIL]"
        .Subject = "Le titre du message"
        .Body = "Découvrez Microsoft Office sur le site Developpez" & _
            vbLf & ThisWorkbook.FullName & vbLf & vbLf & _
            "Cordialement" & vbLf & "[EMAIL="emetteur@mail.fr"]mailto:emetteur@mail.fr[/EMAIL]"
        .Display
        .Save
        .Send
    End With
    
    Set OlItem = Nothing
    Set OlApp = Nothing
End Sub

Un autre exemple en utilisant la méthode CDO.

Code:

Sub liensDansCorpsDuMessage_CDO()
'adapté de : [url=http://support.microsoft.com/default.aspx?kbid=286430]How To Send HTML Formatted Mail Using CDO for Windows 2000 and the Local Pickup Directory[/url]
Dim iMsg As Object, iConf As Object
Dim strHTML As String

Set iMsg = CreateObject("CDO.Message")
Set iConf = CreateObject("CDO.Configuration")

strHTML = ""
strHTML = strHTML & "<HEAD>"
strHTML = strHTML & "<BODY>"
strHTML = strHTML & "Bonjour , <BR>Découvrez Microsoft Office sur le site Developpez<BR><BR>"
strHTML = strHTML & "<A href='" & ThisWorkbook.FullName & "'>Cliquez ici.</A>"

strHTML = strHTML & "<BR><BR>Cordialement<BR>" & Environ("UserName") & "<BR>"
strHTML = strHTML & "<A href=mailto:emetteur@mail.fr>Mon adresse mail</A>"
strHTML = strHTML & "</BODY>"
strHTML = strHTML & ""

With iMsg
    Set .Configuration = iConf
    .To = "[EMAIL="NomPrenom@mail.fr"]NomPrenom@mail.fr[/EMAIL]" 'Renvoie une erreur si l'adresse est non valide
    '.From = "[EMAIL="youralias@yourdomain.com"]youralias@yourdomain.com[/EMAIL]"
    .Subject = "Test Envoi liens par mail"
    .HTMLBody = strHTML
    .Send
End With
End Sub

Bonne soirée
MichelXld

Lauglé · 21 Janvier 2008

Re : Envoi e-mail auto contenant link Excel

Bonjour,
Merci pour l'aide. J'ai adopté la première solution. Cependant, est-il possible que le contenu du lien reprenne le nom exact du fichier (sachant que ce fichier excel n'est jamais le même) ?
En vous remerciant. Cordialement.
Christophe.

Effectuez une recherche sur Excel Downloads...

Envoi e-mail auto contenant link Excel

Lauglé

Guest

MichelXld

XLDnaute Barbatruc

Lauglé

Guest

Discussions similaires

Nous accordons de l'importance à votre vie privée