encore pb si

[sandrine]

Re bonjour à tous!!
j'ai pas trés bien compris comment faire pour rajouter des conditions.
Voici la formule ou j'aimerais rajouter des conditions:

=SI(E3='';'';SI(E3>1000000;pertes!$K$26;SI('Sous stations'!$C$8=1;INDEX(pertes!$K$2:$K$26;EQUIV(synthèseA!E3;pertes!$E$2:$E$26)+1);SI('Sous stations'!$C$8=2;INDEX(pertes!$K$2:$K$26;EQUIV(synthèseA!E3;pertes!$F$2:$F$26)+1);SI('Sous stations'!$C$8=3;INDEX(pertes!$K$2:$K$26;EQUIV(synthèseA!E3;pertes!$G$2:$G$26)+1);SI('Sous stations'!$C$8=4;INDEX(pertes!$K$2:$K$26;EQUIV(synthèseA!E3;pertes!$H$2:$H$26)+1);0))))))

Merci de votre aide

 

[flo2002]

re bonjour,
Un exemple serai le bien venu!

 

[Dan]

Bonjour Sandrine,

Tu peux rajouter une nouvelle condition si la condition est fausse.

Exemple :
SI(condition; VRAI; FAUX)

1. A1<A2 si Vrai A1=A2, si Faux A1=0
=si(A1<A2;A1=A2;0)

2. ajout d'une deuxième condition au point 1 avec A1=1
= si(A1 Lien supprimé

Message édité par: Dan, à: 12/05/2006 13:43

 

[Jocelyn]

Re bonjour Sandrine,

Je ne maitrise poas bien la fonction choisir mais pour suprimer une bonne partie des SI a essayer:

SI(E3='';'';SI(E3>1000000;pertes!$K$26;choisir('Sous stations'!$C$8;INDEX(pertes!$K$2:$K$26;EQUIV(synthèseA!E3;pertes!$E$2:$E$26)+1);INDEX(pertes!$K$2:$K$26;EQUIV(synthèseA!E3;pertes!$F$2:$F$26)+1);INDEX(pertes!$K$2:$K$26;EQUIV(synthèseA!E3;pertes!$G$2:$G$26)+1);INDEX(pertes!$K$2:$K$26;EQUIV(synthèseA!E3;pertes!$H$2:$H$26)+1));0))

Jocelyn

oup's Bonjour flo2002, dan désolé pour la colision

Message édité par: Jocelyn, à: 12/05/2006 13:44

 

[sandrine]

je vais essayer de trouver avec choisir merci bcp

 

[Monique]

Bonjour;

Quelque chose comme ça ?
=SI(E3='';'';SI(E3>1000000;pertes!$K$26;INDEX(pertes!$K$2:$K$26;EQUIV(SynthèseA!E3;DECALER(pertes!$E$2:$E$26;;'Sous stations'!$C$8-1))+1)))

Si Sous stations'!$C$8=1 tu prends pertes!$E$2:$E$26
Si Sous stations'!$C$8=2 tu prends pertes!$F$2:$F$26
Etc
tu décales E2:E26 vers la droite de 0, 1, 2 colonnes selon la valeur de C8

Avec l'argument 0 pour Equiv pour avoir la valeur exacte :
=SI(E3='';'';SI(E3>1000000;pertes!$K$26;INDEX(pertes!$K$2:$K$26;EQUIV(SynthèseA!E3;DECALER(pertes!$E$2:$E$26;;'Sous stations'!$C$8-1);0)+1)))

 

[sandrine]

J'ai essayé mais ca marchepas merci qd même

 

[sandrine]

merci bcp ca a marché