données sources graphique

knaekes

XLDnaute Occasionnel
Bonjour,

Les données sources du graphique sont amenées à être déplacées par copier/coller.

problème 1
- je souhaite cependant que le graphique associé ne suive pas ces déplacement, c'est a dire par exemple qu il prenne systématiquement en compte la valeur qui figure en A1 même si je déplace cette cellule autre part

problème 2
- lorsque l'une des cellules de données source est vide, je souhaite que le graphique ne la prenne pas en compte et ne laisse pas d'intervalle de libre

ci-joint mon fichier

merci d'avance pour votre aide
 

Pièces jointes

  • graphique -.xlsm
    17 KB · Affichages: 45

job75

XLDnaute Barbatruc
Re : données sources graphique

Bonjour knaekes,

Je pense qu'il vous faut un 2ème tableau qui traitera les données du 1er : élimination des cellules vides, tri alphabétique.

Tout ça par formule matricielle, il y a de nombreux exemples sur le forum.

Ce tableau sera nommé pour le rendre dynamique (évolutif) et c'est son nom qui sera utilisé pour définir la série.

A+
 

job75

XLDnaute Barbatruc
Re : données sources graphique

Bonjour knaekes, le forum,

Au cas où vous n'auriez pas trouvé, voyez le fichier joint.

Formule matricielle en A3 :

Code:
=INDEX(1:1;EQUIV(PETITE.VALEUR(SI($A1:$J1<>"";NB.SI($A1:$J1;"<"&$A1:$J1));COLONNES($A3:A3));SI($A1:$J1<>"";NB.SI($A1:$J1;"<"&$A1:$J1));0))
A valider par Ctrl+Maj+Entrée et tirer vers la droite.

Formule en A4 :

Code:
=RECHERCHEH(A3;$A1:$J2;2;0)
Voyez les noms définis abscisses et ordonnees (plages dynamiques) qui permettent de définir la série du graphique.

Nota : les lignes 3 et 4 ne doivent pas être masquées mais on peut leur donner une hauteur 1...

A+
 

Pièces jointes

  • graphique(1).xls
    44.5 KB · Affichages: 43
  • graphique(1).xls
    44.5 KB · Affichages: 44
  • graphique(1).xls
    44.5 KB · Affichages: 42
Dernière édition:

job75

XLDnaute Barbatruc
Re : données sources graphique

Re,

En fait on peut n'utiliser qu'une seule formule en A3 et la tirer à droite et vers le bas :

Code:
=INDEX(1:1;EQUIV(PETITE.VALEUR(SI($A$1:$J$1<>"";NB.SI($A$1:$J$1;"<"&$A$1:$J$1));COLONNES($A3:A3));SI($A$1:$J$1<>"";NB.SI($A$1:$J$1;"<"&$A$1:$J$1));0))
Mais le temps de calcul est sans doute un peu plus grand.

Fichier (2).

A+
 

Pièces jointes

  • graphique(2).xls
    46 KB · Affichages: 35
  • graphique(2).xls
    46 KB · Affichages: 37
  • graphique(2).xls
    46 KB · Affichages: 35

job75

XLDnaute Barbatruc
Re : données sources graphique

Bonsoir,

Si l'on craint d'entrer (par erreur...) du texte en ligne 2, définir le nom abscisses par :

Code:
=DECALER(Feuil1!$A$3;;;;NB.SI(Feuil1!$3:$3;"><"))
Fichier (3).

A+
 

Pièces jointes

  • graphique(3).xls
    45 KB · Affichages: 36
  • graphique(3).xls
    45 KB · Affichages: 36
  • graphique(3).xls
    45 KB · Affichages: 38
Dernière édition:

job75

XLDnaute Barbatruc
Re : données sources graphique

Bonjour knaekes,

Un complément pour rendre vraiment le tableau dynamique.

Nom défini plage :

Code:
=DECALER(Feuil1!$A$1;;;;EQUIV("zzz";Feuil1!$1:$1))
Formule matricielle en A3 :

Code:
=INDEX(1:1;EQUIV(PETITE.VALEUR(SI(plage<>"";NB.SI(plage;"<="&plage));COLONNES($A3:A3));NB.SI(plage;"<="&plage);0))
Notez le "<=" au lieu du "<" précédemment, on économise un test SI...

Fichier (4).

A+
 

Pièces jointes

  • graphique(4).xls
    43.5 KB · Affichages: 41

knaekes

XLDnaute Occasionnel
Re : données sources graphique

Merci Job75

Effectivement cette solution fonctionne, toutefois elle m'oblige à passer par un tableau intermédiaire.
Dans mon cas ce graphique est construit à partir de données générées par une macro.
Je profite donc de cette macro pour construire le graphique à partir de données que je stocke dans un tableau de variables.

ci-joint la solution retenue

exellente journée
 

Pièces jointes

  • parametres graph.xlsm
    139.6 KB · Affichages: 30
  • parametres graph.xlsm
    139.6 KB · Affichages: 34
  • parametres graph.xlsm
    139.6 KB · Affichages: 32

Discussions similaires

Réponses
6
Affichages
388

Statistiques des forums

Discussions
312 800
Messages
2 092 242
Membres
105 305
dernier inscrit
Momone59