Différences dates

[gotlapal]

Bonjours à tous,

je n'arrive pas à trouver le solution pour une formule en n'utilisant qu'une seule cellule.

Dans la case A1, j'entre une date

je voudrai qu'en A2 s'inscrive "oui" si cette date est dépassée depuis 2 ans
et "" si ça fait 2 ans ou moins.

je mettrait une MfC après mais ça je sais faire..

j'ai essayer d'associer DATEDIF et AUJOURDHUI mais je tourne en rond.

Pouvez vous m'aider?

Merci

 

[kjin]

Re : Différences dates

Bonsoir,
Avec Datedif
=SI(DATEDIF(A1;AUJOURDHUI();"d")>730;"Oui";"Non")
Mais la formule de Jean Marcel est tout aussi valable
A+
kjin

 

[gotlapal]

Re : Différences dates

Merci beaucoup
ça marche très bien

 

[ROGER2327]

Re : Différences dates

Bonsoir à tous,

Je vous propose ceci :

=SI(OU(A1="";A1>DATE(ANNEE(AUJOURDHUI())-2;MOIS(AUJOURDHUI());JOUR(AUJOURDHUI())));"";"oui")

qui devrait être valable même si une année bissextile vient se glisser dans le calendrier (ça arrive quelquefois...).​

Bonne nuit !
ROGER2327

 

[Catrice]

Re : Différences dates

Bonsoir,

Cette formule devrait gérer les années bisextile aussi :
=SI(DATEDIF(A8;AUJOURDHUI();"y")>=2;"oui";"non")
ou bien
=SI(DATEDIF(A8;AUJOURDHUI()-1;"y")>=2;"oui";"non")
Pour régler à 1 jour près

voir fichier joint avec la MFC

 

[ROGER2327]

Re : Différences dates

Bonsoir à vous, Catrice

D'accord avec vous, et bien vu pour le jour près !
Toutefois, vos formules renvoient une erreur si A8 contient un date postérieure à aujourd'hui.

Bonne nuit !
ROGER2327

 

[Catrice]

Re : Différences dates

Bonjour,

Effectivement, ça renvoie une erreur.
Mais ce n'était pas dans la question.
"je voudrai qu'en A2 s'inscrive "oui" si cette date est dépassée depuis 2 ans et "" si ça fait 2 ans ou moins."
A priori, les dates sont inférieures, il faut en revanche traiter la cellule vide.
J'ai adapté la formule comme ceci :
=SI(OU(A2="";A2>AUJOURDHUI());"";SI(DATEDIF(A2;AUJOURDHUI();"y")>=2;"oui, depassé";""))
ou pour gérer tous les cas de figures :
=SI(A2="";"pas de date";SI(A2>AUJOURDHUI();"date postérieure";SI(DATEDIF(A2;AUJOURDHUI();"y")>=2;"oui, depassé";"moins de 2 ans")))

En revanche, ça n'a pas d'influence sur la MFC qui in fine était l'objet de la question.

 

[Pyrof]

Re : Différences dates

Bonjour,

Voici une solution avec une fonction personnalisée.

Je calcule la date year+2 et je la compare à aujourd'hui

Ainsi pas de problème avec les années bissextiles

 

[ROGER2327]

Re : Différences dates

Bonjour à tous,

Pyrof offre la version VBA de ma solution par formule. Les formules de Catrice fonctionnent on ne peut mieux. gotlapal n'a plus que l'embarras du choix. C'est bien chez les XLD !​

Bonne journée !
ROGER2327

 

[Gael]

Re : Différences dates

Bonsoir à tous,

Avec un métro de retard, une formule alternative:

=SI(A1<MOIS.DECALER(AUJOURDHUI();-24);"Dépassé";"")

qui nécessite cependant d'activer la macro complémentaire "Utilitaire d'analyse" (Outils - macros complémentaires").

@+

Gael