difference de temps / heures ouvrées

[armitage92]

Re-bonjour a tous 🙂

J'ai une question, sur Excel 2003, toujours.

si j'ai deux dates, tel que


05/05/2009 16:31

et

19/05/2009 20:17


je voudrais en faire la différence, mais en y otant les heures non "ouvré" de mon service, soit de 19h00 à 09h00 le matin.

de fait, au lieu d'avoir comme différence, 339:46:01 , j'aurais beaucoup moins.

Merci d'avance a ceux qui ont une idée, je ne sais pas si une fonction existe déja sur excel pour cela, ou pas.

 

[ROGER2327]

Re : difference de temps / heures ouvrées

Bonjour armitage92

Les dates de début et de fin étant placée en A1 et B1, la formule

=SI((A1="")+(B1="");"";SI(MIN(MAX(A1;ENT(A1)+9/24);ENT(A1)+19/24)>MAX(MIN(B1;ENT(A1)+19/24);ENT(A1)+9/24);"";MAX(MIN(B1;ENT(A1)+19/24);ENT(A1)+9/24)-MIN(MAX(A1;ENT(A1)+9/24);ENT(A1)+19/24))+SI(MIN(MAX(A1;ENT(B1)+9/24);ENT(B1)+19/24)>MAX(MIN(B1;ENT(B1)+19/24);ENT(B1)+9/24);"";MAX(MIN(B1;ENT(B1)+19/24);ENT(B1)+9/24)-MIN(MAX(A1;ENT(B1)+9/24);ENT(B1)+19/24))+(ENT(B1)-ENT(A1)-1)*5/12)

donne 142:29:00.​

Bonne nuit.
ROGER2327

 

[hoerwind]

Re : difference de temps / heures ouvrées

Bonjour, salut Roger,

D'après le résultat obtenu (339:46) les samedis, dimanches et jours fériés sont comptés comme jours ouvrés (il y a moyen de les exclure).

Variante de formule renvoyant 142:29 comme résultat :
=SI(A1*B1;(JOUR(B1)-JOUR(A1)-1)*(19/24-9/24)+MAX(0;19/24-MOD(A1;1))+MIN(10/24;MOD(B1;1)-9/24);"")

 

[armitage92]

Re : difference de temps / heures ouvrées

Bonjour a tous, et merci pour vos réponse 🙂

vos deux formules fonctionnent parfaitement, et je vous en remercie 🙂

hoerwind a soulevé une chose a laquelle je n'avais pas encore pensé, mais effectivement, est il possible d'exlure les jours non ouvrés de ce calcul?

encore merci pour votre aide précieuse 🙂

 

[hoerwind]

Re : difference de temps / heures ouvrées

Re,

Remplacer dans la formule :
(JOUR(B1)-JOUR(A1)-1)
par :
(NB.JOURS.OUVRES(A1;B1;fer)-2)
fer étant une plage nommée contenant les jours fériés.

 

[armitage92]

Re : difference de temps / heures ouvrées

Re, 🙂

Alors j'approche de mon résultat, mais sur mes 1000 valeurs "test", j'en ai 51 en erreur, enfin, en #### car le résultat serait négatif...

mais je ne comprend pas pourquoi.

exemple de formule me donnant un résultat qui me parait incohérant :

en H47 : 25/05/2009 15:03
en N47 : 27/05/2009 10:10


je met comme formule dans ma case de résultat :

=SI(N47="";"";SI(H47*N47;(NB.JOURS.OUVRES(H47;N47;fer)-2)*(19/24-9/24)+MAX(0;19/24-MOD(H47;1))+MIN(10/24;MOD(N47;1)-9/24);""))

et il me renvois un résultat en #### car négatif...

Si quelqu'un a une idée 🙂

 

[hoerwind]

Re : difference de temps / heures ouvrées

Re,

Aucun problème, vois la pièce jointe !
Si tu ne trouves pas l'erreur, mets un extrait de ton fichier en pièce jointe.

 

[armitage92]

Re : difference de temps / heures ouvrées

C'est bon, j'ai trouvé 😀

je suis juste pas doué ^^ j'avais mis des dates en trop dans ma plage de jours férié 🙂


Encore un énorme merci, ca fonctionne parfaitement dorénavant 🙂

 

[ROGER2327]

Re : difference de temps / heures ouvrées

Bonjour à tous

Je suis étonné :

(...) vos deux formules fonctionnent parfaitement, et je vous en remercie (...)

Ni ma formule, ni celle de hoerwind ne sont correctes.

________________ ________________ _ROGER_ hoerwind
05/05/2009 08:31 05/05/2009 09:32 1:04:00 1:01:00
​

(la réponse correcte étant 0:32:00).
Je propose donc

=SI(ESTNUM(A1)*ESTNUM(B1);SI(B1<A1;"";ENT(A1)+19/24-MAX(A1;ENT(A1)+9/24)+MIN(B1;ENT(B1)+19/24)-ENT(B1)-9/24+(ENT(B1)-ENT(A1)-(ENT(B1)>=ENT(A1)))*5/12);"")

Je précise que j'en suis resté à la demande initiale. Je n'ai pas étudié le deuxième problème posé.
A ce propos, il serait agréable que les demandeurs posassent directement le problème qu'ils ont à résoudre, plutôt qu'un problème dont la solution n'a pas d'intérêt. Tout le monde y gagnerait son temps.​

ROGER2327

 

[ROGER2327]

Re : difference de temps / heures ouvrées

Complément...
Un fichier de comparaison des formules.
ROGER2327

 

[hoerwind]

Re : difference de temps / heures ouvrées

Re,

Erreur corrigée :

=SI(A1*B1;(NB.JOURS.OUVRES(A1;B1; fer)-2)*(19/24-9/24)+MIN(10/24;19/24-MOD(A1;1))+MIN(10/24;MOD(B1;1)-9/24);"")

 

[armitage92]

Re : difference de temps / heures ouvrées

Merci pour la correction, je n'avais même pas remarqué ce décallage... comme quoi je m'emballe parfois un petit peu vite 🙂

pour information, pour une raison inconnu (de ma part), cette formule retirait une seconde au total de chacune de mes valeurs, donc je lui ai demandé de la rajouté a chaque fois, sinon pour les dossiers ouvert et clos au moment de leur enregistrement, le resultat était négatif.

 

[hoerwind]

Re : difference de temps / heures ouvrées

Re,

La différence d'une seconde pourrait provenir du processeur, mais ne devrait pas être systématique.
Raison : les données sont saisies en valeurs décimales mais le processeur calcule en binaire, de là la possibilité d'avoir un petit reliquat à partir du 7ème chiffre après la virgule, ce qui devrait représenter une seconde.
Pour y remédier : arrondir le résultat.

J'ai également remarqué qu'il y avait un message d'erreur lors d'une erreur dans les saisies, par exemple une date de début plus grande qu'une de fin.
C'est corrigé sous la pièce jointe.

 

[ROGER2327]

Re : difference de temps / heures ouvrées

Re...

Il y a décidément du fil à retordre avec ce sujet. Je viens de m'apercevoir que ma deuxième formule n'était guère meilleure que la première. Je l'ai corrigée dans le classeur joint. J'en ai profité pour en faire une troisième tenant compte des jours ouvrés. Finalement, les résultats de hoerwind et les miens coïncident, à quelques exceptions prés qu'on trouvera dans le classeur.​

Bonne nuit.
ROGER2327

 

[armitage92]

Re : difference de temps / heures ouvrées

Alors effectivement, vos formules remontait des erreurs, mais uniquement si des valeurs "incohérente" apparaissait.

Mais comme je ne pense pas qu'un de mes techniciens ne travaille en dehors de ses heures... je n'avais pas trop de risque ^^