deplacer le contenu d'une cellule qui contient un caractere vers une autre colonne

[adnanestoune]

bonjour a tous,
ça fais 2h que je cherche sur le forum sans résultat; ma question est simple:
j'ai une liste de mails dans une colonne pour un mailing-liste, mais il ya des adresses erroné c'est sur...
alors j'aurai besoin d'une astuce qui peux bouger des cellules avec "@" ou "hotmail.fr" "company.com" ou n'importe quelle chaîne de caractères ds une autre colonne


Je me doute que cela doit représenter un peu de travail, mais si quelqu'un pouvait m'aider, ça serait vraiment aide précieuse

merci Bcp


adnanestoune

 

[adnanestoune]

Re : rechercher le nombre d'un caracter dans une column

désole je viens de relire;
le titre de la discutions n'est pas ma demande

desole

 

[Pierrot93]

Re : rechercher le nombre d'un caracter dans une column

Bonjour,

désole je viens de relire;
le titre de la discutions n'est pas ma demande

desole

tu peux toujours éditer ton premier message et modifier le titre.... A noter qu'un petit fichier avec données initiales et résultat attendu aiderait pour te répondre...

bon après midi
@+

 

[CISCO]

Re : rechercher le nombre d'un caracter dans une column

Bonjour à tous, bonjour Pirrot93

Une possibilité en pièce jointe, avec une formule matricielle à valider avec ctrl+maj+entrer. Si cela ne convient pas, à toi de détailler davantage ta demande, en mettant si besoin un fichier en pièce jointe.

@ plus

 

[adnanestoune]

Re : deplacer le contenu d'une cellule qui contient un caractere vers une autre colon

respect CISCO

mais si ca va prendre du temps pour comprendre la formule

 

[CISCO]

Re : deplacer le contenu d'une cellule qui contient un caractere vers une autre colon

Bonjour

En E2

NBCAR(SUBSTITUE(A$1:A$100;D$2;""))<NBCAR(A$1:A$100

renvoie vrai pour chaque terme de la plage A$1:A$100 contenant le texte de D$2 (par exemple orange)

NB.SI(E$1:E1;A$1:A$100)=0

renvoie vrai pour les termes A$1:A$100 non encore cités en E$1:E1.

(NBCAR(SUBSTITUE(A$1:A$100;D$2;""))<NBCAR(A$1:A$100))*(NB.SI(E$1:E1;A$1:A$100)=0)

renvoie 1 pour les termes de la plage A$1:A$100 vérifiant les deux conditions ci-dessus en même temps.

SI((NBCAR(SUBSTITUE(A$1:A$100;D$2;""))<NBCAR(A$1:A$100))*(NB.SI(E$1:E1;A$1:A$100)=0);LIGNE(A$1:A$100))

remplace ces 1 par le n° de la ligne des termes de la plage A$1:A$100 vérifiant les deux conditions ci-dessus, les 0 par un FAUX.

MIN(SI((NBCAR(SUBSTITUE(A$1:A$100;D$2;""))<NBCAR(A$1:A$100))*(NB.SI(E$1:E1;A$1:A$100)=0);LIGNE(A$1:A$100)))

renvoie le premier de ces n° de ligne.

et INDEX(A$1:A$100;MIN(.....)) renvoie le contenu de la cellule de la plage A$1:A$100 de cette ligne.

En E3, cela fonctionne pareil, mais le contenu de E2 est éliminé de la liste des cellules acceptables par la partie en NB.SI(E$1:E2;A$1:A$100)=0.

Et ainsi de suite.

@ plus