Microsoft 365 Dénombrer tous les couples selon 2 listes

sylvanu

XLDnaute Barbatruc

Supporter XLD

• 27 Mars 2025

• #2

Bonsoir Alexitt,
En PJ une méthode simplissime mais nécessite deux colonnes.

 

Pièces jointes

• Classeur9.xlsx

  11.9 KB · Affichages: 5

Vote positif 0 Vote négatif

H

Hecatonchire

XLDnaute Occasionnel

• 27 Mars 2025

• #3

Bonjour,

en H2

=LET(code;A2:A11;ope;B2:B6;
nbOpe;NB(ope);
MAKEARRAY(NB(code)*nbOpe;2;LAMBDA(r;c;INDEX((code;ope);SI(c=1;ENT((r-1)/nbOpe)+1;MOD(r-1;nbOpe)+1);1;c))))

Mais je ne sais pas si tu disposes de ces fonctions

 

Vote positif 0 Vote négatif

Dranreb

XLDnaute Barbatruc

• 27 Mars 2025

• #4

Bonjour.
En H2, à propager sur 50 lignes :

Code:

=INDEX($A$2:$A$11;QUOTIENT(LIGNE()-2;LIGNES($B$2:$B$6))+1)

En I2, à propager sur 50 lignes :

Code:

=INDEX($B$2:$B$6;MOD(LIGNE()-2;LIGNES($B$2:$B$6))+1)

 

Vote positif 0 Vote négatif

A

ALS35

XLDnaute Impliqué

• 27 Mars 2025

• #5

Bonjour à tous,
Pléthore de réponse !
Une autre possibilité pour M365, formule unique en H2 :

VB:

=--FRACTIONNER.TEXTE(CONCAT(A2:A11&"|"&TRANSPOSE(B2:B6)&"_");"|";"_";1)

Cordialement

 

Vote positif 0 Vote négatif

H

Hecatonchire

XLDnaute Occasionnel

• 27 Mars 2025

• #6

Pour ancien Excel :

En H2 à recopier vers la gauche en I2 puis recopier H2:I2 vers le bas

=INDEX(($A$2:$A$11;$B$2:$B$6);SI(COLONNE()=8;ENT((LIGNE()-2)/NB($B$2:$B$6))+1;MOD(LIGNE()-2;NB($B$2:$B$6))+1);1;COLONNE()-7)

 

Vote positif 0 Vote négatif

mapomme

XLDnaute Barbatruc

Supporter XLD

• 27 Mars 2025

• #7

Bonsoir à tous 😀,

Ma pomme veut participer aussi😒.

Deux formules à recopier suffisamment vers le bas jusqu'à obtenir des lignes vides (toutes versions) :
En E2 : =SI((LIGNE()-1)<=(NBVAL(A:A)-1)*(NBVAL(B:B)-1);INDEX(A:A;2+ENT((LIGNE()-2)/(NBVAL(B:B)-1)));"")
En D2 : =SI((LIGNE()-1)<=(NBVAL(A:A)-1)*(NBVAL(B:B)-1);INDEX(B:B;2+MOD(LIGNE()-2;NBVAL(B:B)-1));"")

Et une MFC pour alterner les couleurs des blocs.

nota : fonctionne même si les éléments sont du texte.

 

Pièces jointes

• alexitt- produit cartésien- v1.xlsx

  18.3 KB · Affichages: 2

Dernière édition: 27 Mars 2025

Vote positif 0 Vote négatif

A

alexitt

XLDnaute Nouveau

• 28 Mars 2025

• #8

Bonjour,
Merci à tous pour vos réponses, vous êtes au top.
Disposant de M365, j'ai choisi la méthode la plus simple et qui avec une plage dynamique peut s'adapter si le nombre de code ou opération évolue.

 

Vote positif 0 Vote négatif