date 01/01/2009 donne 1er janvier 2009

[pigvoy]

Bonjour

serait il possible d'avoir une formule qui me donne :

ex: si dans a1 la date est ecrit comme ça : 01/01/2009

dans b1 c'est ecrit comme ça : 1er janvier 2009

donc si le jour de la date (a1)est 1 dans b1 donne 1er.

Dans la piece jointe c'est le seul moyen que j'ai trouvé. mais j'aimerai ne pas avoir autant de colonne (bien que je peux les caccher) une seule formule serait impec.

Merci beaucoup

 

[PascalXLD]

Re : date 01/01/2009 donne 1er janvier 2009

Bonjour

essaies

= SI(JOUR(A2)=1;"1er";JOUR(A2))&" "& TEXTE(MOIS(A2);"mmmm")&" "& ANNEE(A2)

 

[hoerwind]

Re : date 01/01/2009 donne 1er janvier 2009

Bonjour,

A essayer :
G2 : =SI(JOUR(A2)=1;SUBSTITUE(TEXTE(A2;"j mmmm aaaa");1;"1er";1);A2)
formule à copier vers le bas. et cellule au format j mmm aaaa

La date n'est plus un format date, puisque non reconnu comme tel par Excel,mais bien un format texte.

 

[hoerwind]

Re : date 01/01/2009 donne 1er janvier 2009

Bonjour PascalXLd,

Il serait préférable de raccourcir ta formule comme suit :
=SI(JOUR(A2)=1;"1er";JOUR(A2))&" "&TEXTE(A2;"mmmm")&" "&ANNEE(A2)
car dans l'état actuel elle renvoie le mois de janvier pour toutes les dates.

 

[pigvoy]

Re : date 01/01/2009 donne 1er janvier 2009

Merci a vous deux

Pour Pascal XLD la formule fonctionne presque, pour n'importe quel mois la formule indique janvier.
ex : pour le 01/02/09 il met 1er janvier 2009 (pour tout les mois pareil).

Pour hoerwind les deux formules fonctionnent donc j'ai comparé la formule de pascal et la deuxieme de hoerwind et il y a seulement le mot mois en trop dans la formule de pascal pour que ça fonctionne.

un grand merci a vous deux !!!

 

[PascalXLD]

Re : date 01/01/2009 donne 1er janvier 2009

RE

oui tout à fait je me suis planté en la réduisnat

= SI(JOUR(A2)=1;"1er";JOUR(A2))&" "& TEXTE(A2;"mmmm")&" "& ANNEE(A2)

 

[ROGER2327]

Re : date 01/01/2009 donne 1er janvier 2009

Bonjour à tous

Variantes courtes :

[COLOR="DarkSlateGray"]=SUBSTITUE(TEXTE(A1;"j mmmm aaaa");"1 ";"1er ")[/COLOR]

ou, au besoin

[COLOR="DarkSlateGray"]=SI(A1="";"";SUBSTITUE(TEXTE(A1;"j mmmm aaaa");"1 ";"1er "))[/COLOR]

Attention aux espaces dans "1 " et "1er " !​

ROGER2327

 

[Monique]

Re : date 01/01/2009 donne 1er janvier 2009

Bonjour,

Une autre
=TEXTE(A2;SI(JOUR(A2)=1;"j""er"" mmmm aaa";"j mmmm aaa"))

 

[ROGER2327]

Re : date 01/01/2009 donne 1er janvier 2009

Bonjour Monique

Petit problème avec le 11 mars (au hasard).
Même problème avec mes formules, donc je modifie ainsi :

[COLOR="DarkSlateGray"]=SUPPRESPACE(SUBSTITUE(" "&TEXTE(C3;"j mmmm aaaa");" 1 ";"1er "))[/COLOR]

Cordialement,
ROGER2327