XL 2013 Date 00/01/1900

[Garamante]

Bonjour à tous!

j'utilise une formule matricielle pour récupérer la date la plus proche de la précédente se trouvant sur la colonne d'une autre feuille, ce qui donne un truc comme ça (J'utilise INDIRECT car je gère la liste des onglets dynamiquement):

=MIN(SI(INDIRECT("'"&$T$7&"'!"&"$A$3:$A$1000")>$AC6;INDIRECT("'"&$T$7&"'!"&"$A$3:$A$1000");""))

01/01/2015
03/01/2015
07/01/2015
08/01/2015
12/01/2015

Ainsi la formule me permet de récupérer le 03/01/2015 puis le 07/01/2015 etc. Le problème: une fois arrivé en bout de liste, ma formule m'affiche un beau 00/01/1900 et recommence le processus depuis le début, genre:

.
.
.
28/02/2015
15/04/2015
18/04/2015
04/06/2015
00/01/1900
01/01/2015
03/01/2015
07/01/2015


Comment faire pour que la formule n'affiche plus rien après le 04/06/2015 (par exemple). J'ai essayé plusieurs techniques mais pour l'instant j'ai fais choux blanc

Merci pour votre aide !

 

[Nairolf]

Re : Date 00/01/1900

Salut Garamante, salut le forum,

Je te propose la formule matricielle suivante qui fonctionne quelles que soient les dates de début et de fin :

=SIERREUR(PETITE.VALEUR((Produits!$A$3:$A$19>=$F$7)*(Produits!$A$3:$A$19<=$G$7)*Produits!$A$3:$A$19;LIGNE(K1)+NB.SI(Produits!$A$3:$A$19;"<"&$F$7)+NB.SI(Produits!$A$3:$A$19;">"&$G$7));"")

 

[R@chid]

Re : Date 00/01/1900

Bonjour @ tous,
une formule classique,

en L7 :

=SIERREUR(PETITE.VALEUR(Produits!A:A;NB.SI(Produits!A:A;"<"&F7)+1);"")

en L8 :

=SI(L7="";"";SIERREUR(PETITE.VALEUR(Produits!A:A;NB.SI(Produits!A:A;"<="&L7)+1);""))

@ tirer vers le bas



@ + +

 

[djidji59430]

Re : Date 00/01/1900

Bonjour à tout 3;
J'y vais aussi de ma petite formule !

en L7 :

{=SIERREUR(INDEX(INDIRECT("'"&$E$7&"'!"&"$A$3:$A$1000");PETITE.VALEUR(SI(((INDIRECT("'"&$E$7&"'!"&"$A$3:$A$1000")>=Feuil2!$F$7)*(INDIRECT("'"&$E$7&"'!"&"$A$3:$A$1000")<=Feuil2!$G$7))<>0;LIGNE($1:$998));LIGNES($1:1)));"")}

 

[Garamante]

Re : Date 00/01/1900

Whaou coool ;o) Vos deux solutions fonctionnent à merveille! Merci les gars !

 

[Garamante]

Re : Date 00/01/1900

trois solutions ;o)

 

[Claude38]

Re : Date 00/01/1900

bonjour tous,

Une autre en L7,valider en matricielle

=SI(MAX(L$6:L6)>=MAX(Produits!A$3:A$1000);"";MIN(SI(Produits!A$3:A$1000>MAX(L$6:L6);Produits!A$3:A$1000)))
Bon après- midi