XL 2010 Creer tableau avec chiffres aleatoire

Sub InitListeAl(TAl() As Long, Optional ByVal NMax As Long, Optional ByVal Graine As Double)
Rem. ——— Garnit un tableau à une dimension base 1 de numéros sans doublon ou change aléatoirement l'ordre
'        des numéros y étant déjà portés.
'  Arguments :
'     TAl :   Le tableau à traiter.
'     NMax:   Numéro maxi. Si spécifié, le tableau est redimensionné TAl(1 To NMax), puis garni de numéros de 1 à NMax.
'     Graine: Base de départ de la série. Si omis la série sera différente à chaque exécution.
   Dim P As Long, R As Long, X As Long
 
Rem. Initialisation :
   If NMax > 0 Then
      ReDim TAl(1 To NMax): For P = 1 To NMax: TAl(P) = P: Next P
   Else: NMax = UBound(TAl): End If
   If Graine <= 0 Then Randomize Else Rnd -1: Randomize Graine
 
Rem. Mélange de Fisher-Yates :
   For P = NMax To 2 Step -1
      R = Int(Rnd * P) + 1: X = TAl(R): TAl(R) = TAl(P): TAl(P) = X
      Next P
   End Sub

Option Explicit
Sub Test()
   Dim TTest() As Long
   ReDim TTest(1 To 10, 1 To 10)
   InitListeAl2D TTest
   [B2].Resize(10, 10).Value = TTest
   End Sub
Sub InitListeAl2D(TAl() As Long, Optional ByVal Graine As Double, Optional ByVal Init As Boolean = True)
Rem. ——— Garnit un tableau à 2 dimensions base 1 de numéros sans doublon ou change aléatoirement l'ordre
'        des numéros y étant déjà portés.
'  Arguments :
'     TAl :   Le tableau à traiter. Doit être dimensionné.
'     Graine: Base de départ de la série. Si omis la série sera différente à chaque exécution.
'     Init: Si spécifié False le contenuu initial du tableau est conservé, seulement mélangé.
   Dim L1 As Long, C1 As Long, L2 As Long, C2 As Long, P As Long, Q As Long, X As Long
 
Rem. Initialisation :
   If Init Then
      For L1 = 1 To UBound(TAl, 1): For C1 = 1 To UBound(TAl, 2)
         X = X + 1: TAl(L1, C1) = X: Next C1, L1
      End If
   If Graine <= 0 Then Randomize Else Rnd -1: Randomize Graine
 
Rem. Mélange de Fisher-Yates :
   For P = UBound(TAl, 1) * UBound(TAl, 2) To 2 Step -1
      L2 = (P - 1) \ UBound(TAl, 2) + 1: C2 = (P - 1) Mod UBound(TAl, 2) + 1
      Q = Int(Rnd * P) + 1
      L1 = (Q - 1) \ UBound(TAl, 2) + 1: C1 = (Q - 1) Mod UBound(TAl, 2) + 1
      X = TAl(L1, C1): TAl(L1, C1) = TAl(L2, C2): TAl(L2, C2) = X
      Next P
   End Sub

Sub test()
Dim dico, t#, x&, plage As Range
Randomize
Set dico = CreateObject("scripting.dictionary")
Set plage = [A1].Resize(40, 40)
t = Timer
Do While x < (40 * 40)
num = Round(1 + (Rnd * 1599))
If Not dico.exists(num) Then
x = x + 1
plage.Cells(x) = num
dico(num) = plage.Cells(x)
End If
Loop
MsgBox Format(Timer - t, "#0.000 sec")
End Sub

Sub test2()
Dim dico, t#, x&, plage As Range, tb()
Randomize
Set dico = CreateObject("scripting.dictionary")
Set plage = [A1].Resize(40, 40)
ReDim tb(1 To 40, 1 To 40)
t = Timer
l = 1: col = 1
Do Until x = (40 * 40)
  num = Round(1 + (Rnd * 1599))
  If Not dico.exists(num) Then
   x = x + 1
    dico(num) = num
   tb(l, col) = num
   col = col + 1
   If col = 40 And l < 40 Then col = 1: l = l + 1
   If l = 40 And col = 40 Then Exit Do
  End If
Loop
plage.Value = tb
MsgBox Format(Timer - t, "#0.000 sec")
End Sub