Correction de formule SI

[JJ1]

Bonjour à tous,
Je tourne en rond pour une formule SI qui semble en conflit de priorité, je ne joins pas de fichier car elle me semble claire:

SI(OU(SOMMEPROD((NB.SI(C$1:C$5;$A9:$B9)>0)*1)=2;"Tout";NB.SI(C$1:C$5;$A9)=1;$A9;NB.SI(C$1:C$5;$B9)=1;$B9);"")

En clair:
Si C1:C5 ne contient aucun nombre A9 ou B9: ""
Si C1:C5 contient un nombre, je l'inscris (donc A9 OU B9)
Si C1:C5 contient A9 ET B9, j'inscris "Tout"


Avez-vous une idée de correction.
merci et bon app.

 

[Dranreb]

Re : Correction de formule SI

Bonjour.
Essayez comme ça :

=CHOISIR((NB.SI(C$1:C$5;$A9)>0)+(NB.SI(C$1:C$5;$B9)>0)*2+1;"";$A9;$B9;"Tout")

Cordialement.

 

[Misange]

Re : Correction de formule SI

Hello happy Barbatruc 🙂
un petit fichier joint nous permettra quand même de tester nos réponses sans avoir besoin de créer nous même le classeur 🙂
Tu valides en matricielle ? parce que nb.si(C1:C5;A9:B9)... et une matricielle avec une matricielle dedans (sommeprod...) ça passe pas

 

[JCGL]

Re : Correction de formule SI

Bonjour à tous,

Peux-tu essayer :

=SI(SOMMEPROD((NB.SI(C$1:C$5;$A9:$B9)>0)*1)=2;"Tout";SI(NB.SI(C$1:C$5;$A9)=1;$A9;SI(NB.SI(C$1:C$5;$B9)=1;$B9;"")))

A + à tous

Edition : Bonjour Flo, Re Bernard...

 

[JJ1]

Re : Correction de formule SI

Bonjour à tous et merci pour vos réponses.

Effectivement Jean Claude, il me fallait 3 SI au lieu de SI OU 3 fois !
J'aurais du y penser.

Merci et bon AM

 

[Dranreb]

Re : Correction de formule SI

Bonjour Misange, JCGL.
Ma formule ne marcherait elle pas ?
À +

 

[JJ1]

Re : Correction de formule SI

Re,

Bien sûr que si elle fonctionne. Je t'en remercie (je ne connaissais pas cette utilisation de la fonction choisir().
J'ai mis sur le Forum les deux solutions en exemple.

Bon AM à tous.