Ceci est une page optimisée pour les mobiles. Cliquez sur ce texte pour afficher la vraie page.

Copier valeur d'une cellule d'une feuille vers une autre

Créer une discussion
  • Initiateur de la discussion Initiateur de la discussion amarbaix
  • Date de début Date de début

Boostez vos compétences Excel avec notre communauté !

Rejoignez Excel Downloads, le rendez-vous des passionnés où l'entraide fait la force. Apprenez, échangez, progressez – et tout ça gratuitement ! 👉 Inscrivez-vous maintenant !

S'inscrire
A

amarbaix

Guest
Bonjour

Dans ma colonne M (la colonne 13) de ma feuille "PLANS", j'ai fait une formule qui me donne un état de mes documents.
La formule de ma colonne M me donne 3 réponses possible : "Doc. en attente" ; "OK" ; " "
Idem avec la colonne M (la colonne 13) de ma feuille "Fiche technique".
Idem avec la colonne N (la colonne 13) de ma feuille "NC ; note de calcul".

La colonne 1 de ces trois feuilles donne le nom du document. La colonne 2, la version du document et la colonne 3, le nom

J'essaye depuis des jours de créer une macro qui me fait une liste (dans une feuille nommée "LISTE") des documents avec la valeur "Doc. en attente" et cela avec les trois feuilles ci-dessus (PLANS, Fiche technique, note de calcul)


J'ai essayé de faire une macro avec une feuille mais ça ne marche pas.

Sub Copy()
Dim Nom As String
Dim i, j As Integer
Sheets("PLANS").Select
i = 7
j = 2
Do
Nom = "Doc. en attente"
If Sheets("PLANS").Cells(i, 13).Value = Nom Then
Sheets("LISTE").Cells(j, 1).Value = Sheets("PLANS").Cells(i, 1).Value
i = i + 1
End If
j = j + 1
Loop While i = 1000
End Sub
 

Pièces jointes

Trier par date Trier par votes
Re : Copier valeur d'une cellule d'une feuille vers une autre

Bonjour amarbaix, bienvenue sur XLD,

La macro (dans Module1) se lance par Ctrl+A :

Code: 
Sub DocEnAttente() 'raccourci clavier Ctrl+A
Dim Feuille, Ncol, critere$, lig&, i As Byte, plage As Range
Feuille = Array("PLANS", "Fiche technique", "NC ; note de calcul")
Ncol = Array(13, 13, 12)
critere = "Doc. en attente"
Sheets(critere).[3:65536].Clear
lig = 2 '1ère ligne de recopie
Application.ScreenUpdating = False
For i = 0 To UBound(Feuille)
  With Sheets(Feuille(i))
    .AutoFilterMode = False
    Set plage = .Range("A4", .[A65536].End(xlUp)).Resize(, Ncol(i))
    plage.AutoFilter Ncol(i), critere
    Set plage = plage.Offset(1).SpecialCells(xlCellTypeVisible)
    Set plage = Intersect(.[A:C], plage) 'on garde 3 colonnes
    plage.Copy Sheets(critere).Cells(lig, 1) 'restitution
    lig = lig + plage.Count / 3 'nouvelle ligne de recopie
    .AutoFilterMode = False
  End With
Next
Sheets(critere).Activate 'facultatif
End Sub
Fichier joint.

Il m'a paru naturel de nommer Doc. en attente la feuille de restitution.

Seules les 3 colonnes A:C sont conservées car les autres ne se correspondent pas toujours.

A+
 

Pièces jointes

Vote positif 0 Vote négatif
Re : Copier valeur d'une cellule d'une feuille vers une autre

Bonjour amarbaix, Gorfael, le forum,

Une amélioration intéressante.

Pour chaque feuille, les colonnes à copier sont prédéterminées (colonnes communes) :

Code: 
Sub DocEnAttente() 'raccourci clavier Ctrl+A
Dim Feuille, Ncol, GardeCol, critere$, lig&, i As Byte, plage As Range
Feuille = Array("PLANS", "Fiche technique", "NC ; note de calcul")
Ncol = Array(13, 13, 12)
GardeCol = Array("A:F,H:J", "A:C,E:J", "A:I") 'colonnes à copier
critere = "Doc. en attente"
Sheets(critere).[3:65536].Clear
lig = 3 '1ère ligne de recopie
Application.ScreenUpdating = False
For i = 0 To UBound(Feuille)
  With Sheets(Feuille(i))
    .AutoFilterMode = False
    Set plage = .Range("A4", .[A65536].End(xlUp)).Resize(, Ncol(i))
    plage.AutoFilter Ncol(i), critere
    Set plage = plage.Offset(1).SpecialCells(xlCellTypeVisible)
    Set plage = Intersect(.Range(GardeCol(i)), plage) 'choix des colonnes
    plage.Copy Sheets(critere).Cells(lig, 1) 'restitution
    lig = lig + Intersect(.[A:A], plage).Count 'nouvelle ligne de recopie
    .AutoFilterMode = False
  End With
Next
Sheets(critere).Activate 'facultatif
End Sub
Fichier (2).

A+
 

Pièces jointes

Dernière édition:
Vote positif 0 Vote négatif
Re : Copier valeur d'une cellule d'une feuille vers une autre

Bonjour

Encore merci pour tout.

Pour que la macro "DocEnattente" soit parfaite, il faudrait qu'elle réalise les macros màjplans, màjFT, màjPE et màjNC au préalable

Au-dessus des lignes correspondant à chaque feuille, il faudrait indiquer dans la colonne A en gras souligné le nom de celle-ci

Après il faudrait supprimer les lignes vides entre.
J'avais mis la formule suivante mais ça ralentit vraiment tout
Selection.SpecialCells(xlCellTypeBlanks).Select
Selection.Delete Shift:=xlUp

A+
 

Pièces jointes

Vote positif 0 Vote négatif
Re : Copier valeur d'une cellule d'une feuille vers une autre

Re,

amarbaix à dit:
Pour que la macro "DocEnattente" soit parfaite, il faudrait qu'elle réalise les macros màjplans, màjFT, màjPE et màjNC au préalable
Cliquez pour agrandir...

Appelez-les donc en début de macro :

Code: 
Sub DocEnAttente() 'raccourci clavier Ctrl+A
Dim Feuille, Ncol, GardeCol, critere$, lig&, i As Byte, plage As Range
màjplans
màjFT
màjPE
màjNC
'reste du code
End Sub
amarbaix à dit:
Au-dessus des lignes correspondant à chaque feuille, il faudrait indiquer dans la colonne A en gras souligné le nom de celle-ci
Cliquez pour agrandir...

Voici donc la version (3) :

Code: 
Sub DocEnAttente() 'raccourci clavier Ctrl+A
Dim Feuille, Ncol, GardeCol, critere$, lig&, i As Byte, plage As Range
Feuille = Array("PLANS", "Fiche technique", "NC ; note de calcul")
Ncol = Array(13, 13, 12)
GardeCol = Array("A:F,H:J", "A:C,E:J", "A:I") 'colonnes à copier
critere = "Doc. en attente"
Sheets(critere).[3:65536].Clear
lig = 4 '1ère ligne de recopie après le nom de la feuille
Application.ScreenUpdating = False
For i = 0 To UBound(Feuille)
  With Sheets(Feuille(i))
    With Sheets(critere).Cells(lig - 1, 1) 'nom en gras et souligné
      .Value = Feuille(i)
      .Font.Bold = True
      .Font.Underline = xlUnderlineStyleSingle
    End With
    .AutoFilterMode = False
    Set plage = .Range("A4", .[A65536].End(xlUp)).Resize(, Ncol(i))
    plage.AutoFilter Ncol(i), critere
    Set plage = plage.Offset(1).SpecialCells(xlCellTypeVisible)
    Set plage = Intersect(.Range(GardeCol(i)), plage) 'choix des colonnes
    plage.Copy Sheets(critere).Cells(lig, 1) 'restitution
    lig = lig + Intersect(.[A:A], plage).Count 'nouvelle ligne de recopie
    .AutoFilterMode = False
  End With
Next
Sheets(critere).Activate 'facultatif
End Sub
A+
 

Pièces jointes

Vote positif 0 Vote négatif
Re : Copier valeur d'une cellule d'une feuille vers une autre

Re,

Bon, je ne m'étais pas occupé de votre dernier fichier.

Vos 4 macros de mise à jour ne me satifaisant pas du tout, je les ai revues :

Code: 
Sub MAJ(W As Worksheet) 'complète les formules de la feuille W colonnes K:M
Dim lig1&, lig2&
lig1 = W.[L65536].End(xlUp).Row 'dernière ligne colonne L
lig2 = W.[A65536].End(xlUp).Row 'dernière ligne colonne A
If lig2 > lig1 Then W.Range("K" & lig1 & ":M" & lig1).AutoFill W.Range("K" & lig1 & ":M" & lig2)
End Sub

Sub BoutonMAJ() 'à affecter aux boutons
MAJ ActiveSheet
End Sub
Bien entendu, la macro DocEnAttente appelle la macro MAJ avant de traiter chaque feuille.

Votre fichier complété.

A+
 

Pièces jointes

Dernière édition:
Vote positif 0 Vote négatif
Re : Copier valeur d'une cellule d'une feuille vers une autre

Re,

Un petit must, exécuter la macro DocEnAttente quand on active la feuille Doc. en attente :

Code: 
Private Sub Worksheet_Activate()
DocEnAttente
End Sub
Fichier (2).

A+
 

Pièces jointes

Vote positif 0 Vote négatif
Re : Copier valeur d'une cellule d'une feuille vers une autre

Re,

Bien entendu, on peut traiter la feuille EN RETARD de la même manière que Doc. en attente.

Il suffit de modifier légèrement la macro (Ncol et critère).

A priori, il n'y a pas de Date IN ou Approbation, on peut ne pas copier ces colonnes.

Fichier (3).

A+
 

Pièces jointes

Vote positif 0 Vote négatif
Re : Copier valeur d'une cellule d'une feuille vers une autre

Bonjour amarbaix, le forum,

Pour alléger le code on peut paramétrer la macro Liste avec les arguments Feuille, Ncol, GardeCol, critere.

Je roule tout seul mais avec cela on aura fait le tour du problème.

Fichier (4).

Edit : le code est "allégé" mais entre les versions (3) et (4) le poids du fichier augmente de 21 Ko...

Au lieu de 2 macros il y en a 3 en effet.

A+
 

Pièces jointes

Dernière édition:
Vote positif 0 Vote négatif
Re : Copier valeur d'une cellule d'une feuille vers une autre

Bonjour,

Très impressionné par le résultat obtenu, je vais regarder les macros pour tenter d'en comprendre une partie pour les adapter à mes besoins.
Je n'ai pas de question, juste du respect et des compliments.

Cordialement
 
Vote positif 0 Vote négatif
Identifiez-vous ou inscrivez-vous pour participer.
Rejoins nos membres "Supporter XLD" et booste ton expérience Excel !
- Navigue sans publicité
- Accède à Cléa, notre assistante IA experte Excel... et pas que...
- Profite de fonctionnalités exclusives
Ton soutien permet à Excel Downloads de rester 100% gratuit et de continuer à rassembler les passionnés d'Excel.
Je deviens Supporter XLD
Assurez vous de marquer un message comme solution pour une meilleure transparence.

Discussions similaires

R
  • Question Question
XL 2021 Recherche formule pour compléter une cellule a partir des données d'une autre feuille du classeur (16/03/2026)
2
Réponses
18
Affichages
572
laurent950
  • Question Question
XL 2016 ajouter, une nouvelle feuille avec le contenu d'une cellule
Réponses
7
Affichages
353
job75
C
  • Question Question
XL 2021 Exporter des données vers une autre feuille...
Réponses
7
Affichages
201
sylvanu
C
  • Résolu(e)
XL 2019 User Form qui renvoi dans un tableau avec celulle fusionnée
2
Réponses
16
Affichages
363
Piment
P
  • Question Question
Microsoft 365 Excel VBA: manipuler des fichiers partagés via Teams / Sharepoint
Réponses
2
Affichages
130
Eric 888
B
  • Résolu(e)
XL 2021 VBA : activer une feuille dont le nom est la valeur d'une cellule
Réponses
2
Affichages
203
berru76
B
N
  • Résolu(e)
Microsoft 365 Copier une image d'une feuille de calcul vers un UserForm
Réponses
4
Affichages
193
NONO14
N
  • Question Question
XL 2019 Prénoms à souhaiter
2
Réponses
15
Affichages
786
lynyrd
N
  • Question Question
XL 2021 Affecter automatiquement une valeur dans une cellule en fonction d'une saisie dans une autre cellule
Réponses
9
Affichages
318
Nico Gre
N
  • Résolu(e)
XL 2016 En VBA, Automatiser la réponse en fonction de l'état d'une cellule.
Réponses
7
Affichages
875
piga25
S
  • Question Question
Microsoft 365 Extraire dans une nouvelle feuille les cellules non vide d'une colonne
2
Réponses
15
Affichages
598
Gégé-45550
G
  • Question Question
XL 2021 Macro pour changer les titres de fichier d'archive
Réponses
3
Affichages
700
fanch55
L
  • Question Question
XL 2021 Renvoi d'une valeur texte dans une colonne d une autre feuille
Réponses
6
Affichages
396
laurent34750
L
J
  • Question Question
XL 2021 activesheet.shapes suivant la valeur d'une cellule
Réponses
5
Affichages
326
JUAN45
J
K
  • Résolu(e)
XL 2016 Affichage TextBox
Réponses
6
Affichages
820
KRUG WOO
K
M
  • Résolu(e)
XL 2021 Copier/Coller des valeurs d’une feuille à une autre à partir d’une cellule
Réponses
11
Affichages
700
MANU64360
M
Y
  • Question Question
XL 2019 Masquer automatiquement des lignes selon la valeur d'une cellule ?
Réponses
2
Affichages
560
Yogean
Y
A
  • Résolu(e)
XL 2016 Recherche d'un mot dans une cellule et surlignage de la ligne
Réponses
4
Affichages
571
Abi23
A
M
  • Question Question
XL 2019 Transposer des données d'une feuille vers une autre sous forme de synthèse
Réponses
8
Affichages
761
mromain
  • Résolu(e)
XL 2019 Problème de copie de plages non contiguës vers une autre feuille en VBA
Réponses
9
Affichages
450
flc13090
Menu
Connexion
S'inscrire
Les cookies sont requis pour utiliser ce site. Vous devez les accepter pour continuer à utiliser le site. En savoir plus…