Microsoft 365 Copier et coller non contigu

Stéfane

XLDnaute Occasionnel
Bonjour à tous,

Je souhaite savoir si il existe une possibilité de copier ( du type (xlCellTypeVisible).Copy) d'une Feuil2 2 colonnes E et M et les coller sur une Feuil1 en A et M (PasteSpecial Paste:=xlPasteValues).

Cela pour éviter les "aller retour"" copier/coller.

Ci-joint pour illustrer ma demande.

Merci pour votre aide.
 

Pièces jointes

  • Copier.Coller.xlsm
    10.6 KB · Affichages: 12

Dranreb

XLDnaute Barbatruc
Bonjour.
Ma proposition :
Code:
Option Explicit
Sub Copy_F2_F1()
   CopieValeursAprès Feuil1.Columns("A"), Source:=VisiblesÀPartirDe(Feuil2.[E2])
   CopieValeursAprès Feuil1.Columns("M"), Source:=VisiblesÀPartirDe(Feuil2.[M2])
   End Sub
Sub CopieValeursAprès(ByVal Cible As Range, ByVal Source As Range)
   Dim Zone As Range, NbL As Long
   Set Cible = PremierLibre(Cible)
   For Each Zone In Source.Areas: NbL = Zone.Rows.Count
      Cible.Resize(NbL).Value = Zone.Value: Set Cible = Cible.Offset(NbL)
      Next Zone
   End Sub
Function PremierLibre(ByVal Rng As Range) As Range
   Set PremierLibre = Rng.Rows(Rng.Rows.Count).End(xlUp).Offset(1)
   End Function
Function VisiblesÀPartirDe(ByVal Cel As Range) As Range
   Dim UR As Range
   Set UR = Cel.Worksheet.UsedRange
   Set VisiblesÀPartirDe = Cel.Resize(UR.Rows.Count - Cel.Row + UR.Row).SpecialCells(xlCellTypeVisible)
   End Function
 
Dernière édition:

Stéfane

XLDnaute Occasionnel
Bonjour Oneida et Dranreb,

Merci beaucoup pour votre aide et vos retour.

Cela fonctionne parfaitement. J'avais juste oublier de préciser que les colonnes intermédiaires sont remplies et que j'applique un filtre.
Mais pas de problème.

Encore merci et bon weekend.
 

Discussions similaires

Réponses
56
Affichages
2 K
Réponses
7
Affichages
536

Statistiques des forums

Discussions
313 317
Messages
2 097 111
Membres
106 840
dernier inscrit
PeteHotmilk