copier des colonnes sous conditions dans un autre onglet

[dindin]

comment faire pour copier des colonnes sous condtions dans un autre onglet.
en fait j'ai un oglet feuil1 avec un tableau et j'ai veut si j'ai mat2 dans la 1ère collone du feuil1 qu'il copie toutes les colonnes sur un autre onglet automatiqument.
merci pour votre aide.

 

[Robert]

Re : copier des colonnes sous conditions dans un autre onglet

Bonjour Dindin, bonjour le forum,

Peut-être comme ça :

Sub Macro1()
Dim dl As Integer 'déclare la variable dl (dernière Ligne)
Dim pl As Range 'déclare la variable pl (PLage)
Dim dest As Range 'déclare la variable dest (cellule de DESTination)

With Sheets("Feuil1") 'prend en compte l'onglet "Feuil1"
    dl = .Cells(Application.Rows.Count, 1).End(xlUp).Row 'définit la dernière ligne éditée dl de la colonne 1 (=A)
    Set pl = .Range("A4:D" & dl) 'définit la plage pl
    .Range("A3").AutoFilter 'lance le filtre automatique
    .Range("A3").AutoFilter Field:=1, Criteria1:="mat2" 'filtre automatique de la colonne 1 (=A), critère "mat2"
    Set dest = Sheets("Copie filtrée").Cells(Application.Rows.Count, 1).End(xlUp).Offset(1, 0) 'définit la cellule de destination dest
    pl.SpecialCells(xlCellTypeVisible).Copy dest 'copie les cellules visibles de la plage pl et les colle dans dest
    .Range("A3").AutoFilter 'annule le filtre automatique
End With 'fin de la prise en compte de l'onglet "Feuil1"
End Sub

 

[dindin]

Re : copier des colonnes sous conditions dans un autre onglet

salut
merci pour ton code
je l'ai essayé comme suit ca fonctionne mais il répête à chaque fois les même ligne en les rajoutant de nouveau.
je sais pas comment le placer pour qu'il filtre automatiquement Feuil1 sans bloquer l'onglet.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim dl As Integer 'déclare la variable dl (dernière Ligne)
Dim pl As Range 'déclare la variable pl (PLage)
Dim dest As Range 'déclare la variable dest (cellule de DESTination)

With Sheets("Feuil1") 'prend en compte l'onglet "Feuil1"
dl = .Cells(Application.Rows.Count, 1).End(xlUp).Row 'définit la dernière ligne éditée dl de la colonne 1 (=A)
Set pl = .Range("A4😀" & dl) 'définit la plage pl
.Range("A3").AutoFilter 'lance le filtre automatique
.Range("A3").AutoFilter Field:=1, Criteria1:="mat2" 'filtre automatique de la colonne 1 (=A), critère "mat2"
Set dest = Sheets("Copie filtrée").Cells(Application.Rows.Count, 1).End(xlUp).Offset(1, 0) 'définit la cellule de destination dest
pl.SpecialCells(xlCellTypeVisible).Copy dest 'copie les cellules visibles de la plage pl et les colle dans dest
.Range("A3").AutoFilter 'annule le filtre automatique
End With 'fin de la prise en compte de l'onglet "Feuil1"

End Sub

 

[Robert]

Re : copier des colonnes sous conditions dans un autre onglet

Bonjour Dindin, bonjour le forum,

je sais pas comment le placer pour qu'il filtre automatiquement Feuil1 sans bloquer l'onglet.

Je n'ai pas compris ce que tu demandes... Est-ce que tu veux que les lignes déjà copiées ne le soient plus la seconde fois ? Si oui, pourquoi ne pas les déplacer au lieu de les copier ? Bref, éclaire nous...

 

[dindin]

Re : copier des colonnes sous conditions dans un autre onglet

salut
Mon but c'est copier les lignes qui contiennent Mat2 automatiqument sans avoir les copier /coller.
j'ai trouvé un code mais il va avec un bouton .peux tu l'adapter pour qu'il copie automatqiuement sans intervention de ma part .

Sub tri()
Set FE = Sheets("BD")
Set FG1 = Sheets("MAT")

Derligne = FE.Range("A" & Application.Rows.Count).End(xlUp).Row
Derligne2 = FG1.Range("A" & Application.Rows.Count).End(xlUp).Row + 1

FG1.Rows("2:" & Derligne2).Delete Shift:=xlUp

For i = 1 To Derligne
If FE.Cells(i, 1).Value = "MAT" Then
Derligne2 = FG1.Range("B" & Application.Rows.Count).End(xlUp).Row + 1
With FG1
.Cells(Derligne2, 1).Value = FE.Cells(i, 2).Value
.Cells(Derligne2, 2).Value = FE.Cells(i, 3).Value
.Cells(Derligne2, 3).Value = FE.Cells(i, 4).Value
.Cells(Derligne2, 4).Value = FE.Cells(i, 5).Value
.Cells(Derligne2, 5).Value = FE.Cells(i, 6).Value
End With
End If
Next

MsgBox "Traitement terminé"
End Sub

merci d'avance

 

[Robert]

Re : copier des colonnes sous conditions dans un autre onglet

Bonjour Dindin, bonjour le forum,

La macro événementielle Change ci-dessous réagit à la validation d'une cellule en colonne D.
Le code :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim pl As Range 'déclare la variable pl (PLage)
Dim dest As Range 'déclare la variable dest (cellule de DESTination)

If Target.Column <> 4 Or Target.Row < 4 Then Exit Sub 'si la cellule éditée n'est pas dans la colonne 4 (=D) ou dans une ligne inférieure à 4, sort de la procédure
If Target.Offset(0, -3).Value = "mat2" Then 'condition : si la cellule déclalée de trois colonne à gauche (donc en colonne A)contient "mat2"
    Set pl = Range(Target.Offset(0, -3), Target) 'définit la plage pl
    Set dest = Sheets("Copie filtrée").Cells(Application.Rows.Count, 1).End(xlUp).Offset(1, 0) 'définit la cellule de destination dest
    pl.Copy dest 'copie la plage pl et la colle dans dest
End If 'fin de la condition
End Sub

Le fichier :