Conversion date en anglais et en format texte

[christophe9069]

Bonjour tout le monde !

Je lutte depuis plusieurs jours sur le problème suivant:

je travaille actuellement sur un fichier téléchargé à partir d'une base de donnée.
Je dois notamment travailler sur des dates, mais celle-ci sont enregistrées en format texte, et pour compliquer la tâche en anglais.

Voici le format des dates:

Friday 01 June 2012 01:00:29 PM (J'ai aussi joint un fichier)

J'ai cherché une réponse sur le forum mais le fait que les dates soit en anglais semble compliquer la tache.

Merci d'avance pour votre aide !

Christophe.

 

[Dugenou]

Re : Conversion date en anglais et en format texte

Bonjour, bienvenue sur le forum,
Pour ma part je ne vois que deux solutions : disposer d'une version d'excel en anglais ou d'une "extension" qui traite les dates anglaises, ou des formules avec une table de correspondance.
Si les formules est une solution acceptable dis le moi.
Cordialement

Edit : et voir en PJ la formule recopiable vers le bas pour avoir la date en français avec un excel français.

 

[ROGER2327]

Re : Conversion date en anglais et en format texte

Bonsoir à tous

Une formule :​

=(SI(ESTERR(CHERCHE("January";B2));"";SUBSTITUE(DROITE(B2;NBCAR(B2)-CHERCHE(" ";B2));"January";"janvier"))
&SI(ESTERR(CHERCHE("February";B2));"";SUBSTITUE(DROITE(B2;NBCAR(B2)-CHERCHE(" ";B2));"February";"février"))
&SI(ESTERR(CHERCHE("March";B2));"";SUBSTITUE(DROITE(B2;NBCAR(B2)-CHERCHE(" ";B2));"March";"mars"))
&SI(ESTERR(CHERCHE("April";B2));"";SUBSTITUE(DROITE(B2;NBCAR(B2)-CHERCHE(" ";B2));"April";"avril"))
&SI(ESTERR(CHERCHE("May";B2));"";SUBSTITUE(DROITE(B2;NBCAR(B2)-CHERCHE(" ";B2));"May";"mai"))
&SI(ESTERR(CHERCHE("June";B2));"";SUBSTITUE(DROITE(B2;NBCAR(B2)-CHERCHE(" ";B2));"June";"juin"))
&SI(ESTERR(CHERCHE("July";B2));"";SUBSTITUE(DROITE(B2;NBCAR(B2)-CHERCHE(" ";B2));"July";"juillet"))
&SI(ESTERR(CHERCHE("August";B2));"";SUBSTITUE(DROITE(B2;NBCAR(B2)-CHERCHE(" ";B2));"August";"août"))
&SI(ESTERR(CHERCHE("September";B2));"";SUBSTITUE(DROITE(B2;NBCAR(B2)-CHERCHE(" ";B2));"September";"septembre"))
&SI(ESTERR(CHERCHE("October";B2));"";SUBSTITUE(DROITE(B2;NBCAR(B2)-CHERCHE(" ";B2));"October";"octobre"))
&SI(ESTERR(CHERCHE("November";B2));"";SUBSTITUE(DROITE(B2;NBCAR(B2)-CHERCHE(" ";B2));"November";"novembre"))
&SI(ESTERR(CHERCHE("December";B2));"";SUBSTITUE(DROITE(B2;NBCAR(B2)-CHERCHE(" ";B2));"December";"décembre"))
)+0

ROGER2327
#6055

Dimanche 22 Gidouille 139 (Fête de Gidouille - fête Suprême Seconde)
18 Messidor An CCXX, 8,5606h - gesse
2012-W27-5T20:32:43Z

 

[christophe9069]

Re : Conversion date en anglais et en format texte

Merci à Dugenou et ROGER2327 d'avoir répondu aussi vite, les deux solutions sont impeccables ! La longueur des formules est impressionnante, mais cela va bien m'aider. (et vous me faites découvrir de nouvelles fonctions !)

 

[mapomme]

Re : Conversion date en anglais et en format texte

Bonsoir christophe9069 et à tous,

Une autre formule en C2 à copier vers le bas.
Les cellules en colonne C sont formatées avec le format date: jjjj jj mmmm aaaa hh:mm:ss

La Formule de conversion date et heure :

=DATEVAL(STXT(B2;TROUVE(" ";B2)+1;2) & "/" & EQUIV(GAUCHE(STXT(B2;TROUVE("(";SUBSTITUE(SUBSTITUE(B2;" ";"(";2);" ";")";2))+1;99);3);{"Jan";"Feb";"Mar";"Apr";"May";"Jun";"Jul";"Aug";"Sep";"Oct";"Nov";"Dec"};0) & "/" &STXT(B2;TROUVE(":";B2)-7;4))+TEMPSVAL(STXT(B2;TROUVE(":";B2)-2;8)) + SI(DROITE(B2;2)="PM";"12:00:00";0)

 

[amy_8888]

Re : Conversion date en anglais et en format texte

Bonjour à tous,

J'ai le même souci. Par contre, moi j'ai dates dans ce format: 05 March 2015 ou encore 01 June 2013.
Comment faire pour que ces dates soient au format suivant svp: 05/03/2015 ; 01/06/2013

Je vous en remercie!

 

[ROGER2327]

Re : Conversion date en anglais et en format texte

Bonjour amy_8888.

Essayez :​

=SUBSTITUE(
 SUBSTITUE(A1;GAUCHE(STXT(SUBSTITUE(A1;" ";"/";1);CHERCHE("/";SUBSTITUE(A1;" ";"/";1))+1;99);
         CHERCHE(" ";STXT(SUBSTITUE(A1;" ";"/";1);CHERCHE("/";SUBSTITUE(A1;" ";"/";1))+1;99))-1);
"/"&RECHERCHE(GAUCHE(STXT(SUBSTITUE(A1;" ";"/";1);CHERCHE("/";SUBSTITUE(A1;" ";"/";1))+1;99);
         CHERCHE(" ";STXT(SUBSTITUE(A1;" ";"/";1);CHERCHE("/";SUBSTITUE(A1;" ";"/";1))+1;99))-1);
{"April";"August";"December";"February";"January";"July";"June";"March";"May";"November";"October";"September"};
{"04";"08";"12";"02";"01";"07";"06";"03";"05";"11";"10";"09"})&"/");" ";"")

Bonne journée.


ℝOGER2327
#7888

Lundi 9 Merdre 142 (Vidange - Vacuation)
7 Prairial An CCXXIII, 5,6957h - fromental
2015-W22-2T13:40:11Z

 

[amy_8888]

Re : Conversion date en anglais et en format texte

Bonjour ROGER2327,

C'est parfait, vous m'avez sauvé la vie!! Mille merci