compter des dossiers

[Emmanuel]

Bonjour, j'ai une liste de 600 numéro de dossier
sur 7 positions
exemple
1007501 ; 1007502 ; 1007502
je voudrai compter les dossiers sachant que pour l'exemple ci-dessus, les 5 premières positions donnent le numéro de dossier et la 6ème et septième les avenants.
comment compter les dossiers en faisant l'extraction des 5 premieres positions ( j'ai utilisé la formule gauche(a1;5) ; mais il reste le problème des doublons!!!
merci

 

[Monique]

Bonjour,

Seulement si ce sont des valeurs numériques.
1 ) s'il n'y a pas de cellules vides :
=SOMMEPROD((FREQUENCE(GAUCHE(A$2:A$20;5)*1;GAUCHE(A$2:A$20;5)*1)>0)*1)

2 ) s'il y a des cellules vides, mais seulement en bas de colonne :
=SOMMEPROD((FREQUENCE(GAUCHE(DECALER(A$2:A$20;;;NBVAL(A$2:A$20));5)*1;GAUCHE(DECALER(A$2:A$20;;;NBVAL(A$2:A$20));5)*1)>0)*1)

S'il y a des cellules vides éparpillées, je ne trouve pas de solution.

 

[Jean-Marie]

Bonjour

Tout comme toi, j'ai buté sur les cellules vides dans la plage, et j'ai fini par trouver deux fonctions

en fonction matricielle (validation par Ctrl+Shift+Entrer)
=SOMMEPROD((FREQUENCE(SI(GAUCHE(A$2:A$20;5)<>"";GAUCHE(A$2:A20;5)*1;0);SI(GAUCHE(A$2:A$20;5)<>"";GAUCHE(A$2:A20;5)*1;0))>0)*1)-((NB.SI(A2:A20;"")>0)*1)

et celle-ci non matricielle
=SOMMEPROD((FREQUENCE(("0"&GAUCHE(A$2:A$20;5))*1;("0"&GAUCHE(A$2:A$20;5))*1)>0)*1)-((NB.SI(A2:A20;"")>0)*1)

@+Jean-Marie

 

[CHti160]

Salut "Emmanuel" et "Monique"
en pièce jointe un exemple en VBA à adapter et à améliorer
A+++
Jean Marie

 

[CHti160]

Oupss Salut "JM"
pas vu trop rapides toi
A+++
Jean Marie ............. hihi

 

[Emmanuel]

merci à tous
j'ai testé les deux méthodes formules ou macros
efficace!!

 

[CHti160]

y sont bons les Jean Marie Lol hihi ............JM
A+++
Jean Marie