Comptage avec critères nb.si.ens

[oliv134]

Bonjour,

je souhaites compter le nombre de catégories différentes selon deux critères (date comprise dans un interval et le centre).

Cela revient à compter le nombre de centre dans l'intervalle des dates mais sans doublons de catégories:
Je dois aussi prendre en compte que la taille de la feuille est variable. En effet cette feuille est alimentée par une connexion avec un fichier csv lui même créé par une extraction d'une base de données.

Ci-joint un fichier d'exemple.

Je vous remercie par avance de votre aide.

 

[oliv134]

Re : Comptage avec critères nb.si.ens

J'ai trouvé ceci comme formule mais je ne sais pas comment y inclure mes critères de date et de centre:

=SOMME(SI(FREQUENCE(EQUIV(D2:D10;D2:D10;0);EQUIV(D2:D10;D2:D10;0))>0;1))

 

[JHA]

Re : Comptage avec critères nb.si.ens

Bonjour a tous,

A essayer en formule matricielle pour les centres

=SOMME((FREQUENCE(SI((C2:C10>=J4)*(C2:C10<=J5);EQUIV(B2:B10;B2:B10;0));LIGNE(B2:B10)-1)>0)*1)

en formule matricielle pour les categories

=SOMME((FREQUENCE(SI((C2:C10>=J4)*(C2:C10<=J5)*(B2:B10=J2);EQUIV(D2:D10;D2:D10;0));LIGNE(D2:D10)-1)>0)*1)

JHA

 

[R@chid]

Re : Comptage avec critères nb.si.ens

Bonjour @ tous,
une petite variante :

=SOMME(SI((C2:C10>=J4)*(C2:C10<=J5);N(EQUIV(B2:B10;B2:B10;0)=LIGNE(INDIRECT("1:"&LIGNES(B2:B10))))))

@ valider par Ctrl+Maj+Entree
Amicalement

Edit : Pour les categories :

=SOMME(SI((C2:C10>=J4)*(C2:C10<=J5)*(B2:B10=J2);N(EQUIV(D2:D10;D2:D10;0)=LIGNE(INDIRECT("1:"&LIGNES(D2:D10))))))

Toujours en Matricielle.

 

[oliv134]

Re : Comptage avec critères nb.si.ens

Merci pour vos réponses,

la formule qui m’intéresse le plus est:

=SOMME(SI((C2:C10>=J4)*(C2:C10<=J5)*B2:B10=J2);N(EQUIV(D2:D10;D2:D10;0)=LIGNE(INDIRECT("1:"&LIGNES(D2:D10))))))

Mais si une catégorie du centre B est déjà présente pour le centre A cette formule ne me la compte pas.

 

[R@chid]

Re : Comptage avec critères nb.si.ens

Bonjour,

Mais si une catégorie du centre B est déjà présente pour le centre A cette formule ne me la compte pas.

Pour le B tu as les TTT et RRR donc, elle renvoie 2, tu peux etre plus claire sur ta demande si c'est possible??
Amicalement

 

[oliv134]

Re : Comptage avec critères nb.si.ens

Bonjour Rachid,

Pour le centre B j'ai en catégorie pour la plage de date du 01 au 31/01:

RRR
TTT
CCC

Je devrai avoir en résultat donc 3 catégories pour le centre B

Mais comme une catégorie TTT apparaît aussi pour le centre A, alors le résultat est faux.

 

[R@chid]

Re : Comptage avec critères nb.si.ens

Bonjour,
essaayer avec :

=SOMME(N(FREQUENCE(SI((B2:B10=J2)*(MOIS(C2:C10)=MOIS(J4));EQUIV(D2:D10;D2:D10;0));LIGNE(INDIRECT("1:"&LIGNES(D2:D10))))>0))

Toujours matricielle
Amicalement

 

[oliv134]

Re : Comptage avec critères nb.si.ens

Super Rachid !!!!

Cela fonctionne.
Merci beaucoup.

Bonne soirée.

 

[R@chid]

Re : Comptage avec critères nb.si.ens

Bonsoir @ tous,
la derniere formule etait deja sur le post #3 de notre ami JHA.
Amicalement

 

[oliv134]

Re : Comptage avec critères nb.si.ens

Et bien je ne sais pas ce que j'ai fait pour passer à coté.

merci JHA.