Comptage avec critères nb.si.ens

O

oliv134

XLDnaute Nouveau

• 4 Avril 2012

• #2

Re : Comptage avec critères nb.si.ens

J'ai trouvé ceci comme formule mais je ne sais pas comment y inclure mes critères de date et de centre:

Code:

=SOMME(SI(FREQUENCE(EQUIV(D2:D10;D2:D10;0);EQUIV(D2:D10;D2:D10;0))>0;1))

 

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 4 Avril 2012

• #3

Re : Comptage avec critères nb.si.ens

Bonjour a tous,

A essayer en formule matricielle pour les centres

=SOMME((FREQUENCE(SI((C2:C10>=J4)*(C2:C10<=J5);EQUIV(B2:B10;B2:B10;0));LIGNE(B2:B10)-1)>0)*1)

Cliquez pour agrandir...

en formule matricielle pour les categories

Code:

=SOMME((FREQUENCE(SI((C2:C10>=J4)*(C2:C10<=J5)*(B2:B10=J2);EQUIV(D2:D10;D2:D10;0));LIGNE(D2:D10)-1)>0)*1)

JHA

 

Dernière édition: 4 Avril 2012

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 4 Avril 2012

• #4

Re : Comptage avec critères nb.si.ens

Bonjour @ tous,
une petite variante :

Code:

=SOMME(SI((C2:C10>=J4)*(C2:C10<=J5);N(EQUIV(B2:B10;B2:B10;0)=LIGNE(INDIRECT("1:"&LIGNES(B2:B10))))))

@ valider par Ctrl+Maj+Entree
Amicalement

Edit : Pour les categories :

Code:

=SOMME(SI((C2:C10>=J4)*(C2:C10<=J5)*(B2:B10=J2);N(EQUIV(D2:D10;D2:D10;0)=LIGNE(INDIRECT("1:"&LIGNES(D2:D10))))))

Toujours en Matricielle.

 

Dernière édition: 4 Avril 2012

Vote positif 0 Vote négatif

O

oliv134

XLDnaute Nouveau

• 4 Avril 2012

• #5

Re : Comptage avec critères nb.si.ens

Merci pour vos réponses,

la formule qui m’intéresse le plus est:

Code:

=SOMME(SI((C2:C10>=J4)*(C2:C10<=J5)*B2:B10=J2);N(EQUIV(D2:D10;D2:D10;0)=LIGNE(INDIRECT("1:"&LIGNES(D2:D10))))))

Mais si une catégorie du centre B est déjà présente pour le centre A cette formule ne me la compte pas.

 

Pièces jointes

• Exemple PB v2.xlsx

  12 KB · Affichages: 83

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 4 Avril 2012

• #6

Re : Comptage avec critères nb.si.ens

Bonjour,

Mais si une catégorie du centre B est déjà présente pour le centre A cette formule ne me la compte pas.

Cliquez pour agrandir...

Pour le B tu as les TTT et RRR donc, elle renvoie 2, tu peux etre plus claire sur ta demande si c'est possible??
Amicalement

 

Vote positif 0 Vote négatif

O

oliv134

XLDnaute Nouveau

• 5 Avril 2012

• #7

Re : Comptage avec critères nb.si.ens

Bonjour Rachid,

Pour le centre B j'ai en catégorie pour la plage de date du 01 au 31/01:

RRR
TTT
CCC

Je devrai avoir en résultat donc 3 catégories pour le centre B

Mais comme une catégorie TTT apparaît aussi pour le centre A, alors le résultat est faux.

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 5 Avril 2012

• #8

Re : Comptage avec critères nb.si.ens

Bonjour,
essaayer avec :

Code:

=SOMME(N(FREQUENCE(SI((B2:B10=J2)*(MOIS(C2:C10)=MOIS(J4));EQUIV(D2:D10;D2:D10;0));LIGNE(INDIRECT("1:"&LIGNES(D2:D10))))>0))

Toujours matricielle
Amicalement

 

Vote positif 0 Vote négatif

O

oliv134

XLDnaute Nouveau

• 5 Avril 2012

• #9

Re : Comptage avec critères nb.si.ens

Super Rachid !!!!

Cela fonctionne.
Merci beaucoup.

Bonne soirée.

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 5 Avril 2012

• #10

Re : Comptage avec critères nb.si.ens

Bonsoir @ tous,
la derniere formule etait deja sur le post #3 de notre ami JHA.
Amicalement

 

Vote positif 0 Vote négatif

O

oliv134

XLDnaute Nouveau

• 5 Avril 2012

• #11

Re : Comptage avec critères nb.si.ens

Et bien je ne sais pas ce que j'ai fait pour passer à coté.

merci JHA.

 

Vote positif 0 Vote négatif