Comparaison de MOIS

[Nataq]

Bonjour,

J'ai chercher partout et ne trouve pas de solutions... 🙁

Je désire faire un compteur à toute les fois qu'une donnée de format date d'une colonne X correspond au mois Y.

Par exemple, compter les occurences de date en mois de février.

La fonction MOIS() me renvoi bien le mois d'une cellule au format date. Par exemple, me donnera "2" si le mois de la date est en février. Par contre, comment comparer une date pour savoir si elle est au mois de février dans un compteur ?

Je voudrais faire quelque chose du genre :

=NB.SI(F:F;MOIS()=2)
(pour la colonne F, compte 1 chaque fois que le mois est février)

Toute aide sera grandement appréciée!

MErci!

 

[job75]

Re : Comparaison de MOIS

Bonsoir Nataq, bienvenue sur le forum,

SOMMEPROD(1*(MOIS(F1:F1000)=2))

A+

 

[ROGER2327]

Re : Comparaison de MOIS

Bonsoir à tous

1. Formule matricielle (donc à valider par Ctrl + Maj + Entrée)

   =SOMME((F1:F1000<>"")*(MOIS(F1:F1000)=2))

2. =SOMMEPROD((F1:F1000<>"")*(MOIS(F1:F1000)=2))

La matrice (F1:F1000<>"") est nécessaire pour ne pas compter les cellules vides comme contenant une date du mois de janvier.​

ROGER2327

 

[job75]

Re : Comparaison de MOIS

Re, bonsoir Roger,

Je venais juste Roger de penser à ce cas et aussi s'il y a des cellules contenant du texte :

=SOMME(1*SI(ESTNUM(F1:F1000);MOIS(F1:F1000)=2))

Formule matricielle à valider par Ctrl+Maj+Entrée.

Bonne nuit.

 

[Nataq]

Re : Comparaison de MOIS

Merci ça marche nickel!

Et si je voudrais ajouter une 2e conditon dans la ligne ?

Genre :

=SOMME(1*SI(ESTNUM(Reservations_Usagers!F1:F5000);(MOIS(Reservations_Usagers!F1:F5000)=2*Reservations_Usagers!M1:M5000="26")))

Le * est bien un ET ?

Merci!

 

[Nataq]

Re : Comparaison de MOIS

J'ai joué avec vos propositions pour faire cela :

=SOMMEPROD((ESTNUM(Reservations_Usagers!F2:F9000))*(MOIS(Reservations_Usagers!F2:F9000)=2)*(Reservations_Usagers!M2:M9000=26))

... qui a l'air de bien fonctionner.

J'applique partout! 😀

Un énorme merci encore!