XL 2010 Coller les données d'un tableau

[FCMLE44]

Bonjour

Dans un repertoire, j'ai le fichier Absences 2016.

Via un Ctrl U par exemple, j'aimerais ouvrir ce fichier et rapatrier les données des colonnes 7 à 10,13, 16 et 25 dans le fichier ABS Test Feuille ABS.

Quelqu'un peut il m'aider ?

Merci

 

[Paf]

bonjour,

un essai:

 Sub Absences()
Dim ClasAbs As Workbook, Cible As Workbook, DL As Long, Chemin As String
Dim FC As Worksheet
Set Cible = ThisWorkbook
Set FC = Cible.Worksheets("ABS")

Chemin = "C:\répertoire1\répertoire2\répertoire3\" ' à adapter
Set ClasAbs = Workbooks.Open(Chemin & "absences 2016.xls")
With ClasAbs.ActiveSheet
DL = .Range("G" & Rows.Count).End(xlUp).Row
.Range("G1:J" & DL & ",M1:M" & DL & ",P1:P" & DL & ",Y1:Y" & DL).Copy FC.Range("A1")
End With
ClasAbs.Close
End Sub

à copier dans un module standard du fichier qui doit recevoir les données (ABS test.xls)
attribuer à cette macro le raccourci voulu (CTRL+u)
Adapter le chemin du fichier en conservant le \ final.

A+

 

[FCMLE44]

Bonjour et merci

ce fichier se trouvera dans des repertoires differents et le nom pourra differencier
si je ne me trompes pas ce code indique un seul repertoire.

n'y a t il pas un moyen de selectionner le repertoire ainsi que le fichier voulu

cordialement

 

[Paf]

re,

si je ne me trompes pas ce code indique un seul repertoire.

Bah... oui parce que:

Dans un repertoire, j'ai le fichier Absences 2016.

Mais puisque :

ce fichier se trouvera dans des repertoires differents et le nom pourra differencier

peut-être:

Sub Absences()
Dim ClasAbs As Workbook, Cible As Workbook, DL As Long, Chemin As String
Dim FC As Worksheet
Set Cible = ThisWorkbook
Set FC = Cible.Worksheets("ABS")

With Application.FileDialog(msoFileDialogFilePicker)
.AllowMultiSelect = False 'n'autorise pas choix multiple
If .Show = -1 Then ' si fichier sélectionné
    Set ClasAbs = Workbooks.Open(.SelectedItems(1))
    With ClasAbs.ActiveSheet
     DL = .Range("G" & Rows.Count).End(xlUp).Row
     .Range("G1:J" & DL & ",M1:M" & DL & ",P1:P" & DL & ",Y1:Y" & DL).Copy FC.Range("A1")
    End With
    ClasAbs.Close
Else
    MsgBox "Aucun fichier sélectionné"
    Exit Sub
End If
End With
End Sub

A+

 

[FCMLE44]

Merci
ca fonctionne

j'ai mis un deuxieme post appele croise dynamique automatique ce matin. Auriez vous une idee ?
c'est la suite de ce que l'on vient de faire

en fait a partir de la premiere feuille du fichier ABS je veux faire un croise dynamique sur la feuille TDS en enlevant certains motif MSSIT.
les motifs a enlever sont Pat Pat2 Mat Mat+ Inv.

pouvez vous regarder svp ?
Merci

cordialement