Charger une zone de liste modifiable à partir d'un code VBA

[medino55]

Bonjour Tout le monde,🙂
une Petite aide SVP;
dans un Formulaire je veux charger une zone de liste modifiable par la colonne "Code Client" et lorsque je choisi un code les autres zones de texte se changent selon les données dans la feuille;
Vous pouvez voir le fichier attaché.
Merci 😀

 

[Dranreb]

Re : Charger une zone de liste modifiable à partir d'un code VBA

Bonjour.
Code de l'userform:

Option Explicit

Private Sub UserForm_Initialize()
Me.ComboBox1.List = Feuil1.Range("B4:B" & Feuil1.[B65536].End(xlUp).Row).Value
End Sub

Private Sub ComboBox1_Change()
Dim L As Long, T() As Variant
L = Me.ComboBox1.ListIndex + 1
If L > 0 Then
   T = Feuil1.[B4:F65536].Rows(L).Value
   Me.TextBox1.Text = T(1, 2)
   Me.TextBox2.Text = T(1, 3)
   Me.TextBox3.Text = T(1, 4)
   Me.TextBox4.Text = T(1, 5)
Else
   Me.TextBox1.Text = ""
   Me.TextBox2.Text = ""
   Me.TextBox3.Text = ""
   Me.TextBox4.Text = ""
   End If
End Sub

à +

 

[BOISGONTIER]

Re : Charger une zone de liste modifiable à partir d'un code VBA

Bonsoir,

Private Sub UserForm_Initialize()
  Set f = Sheets("feuil1")
  Me.ComboBox1.List = f.Range("B4:F" & [B65000].End(xlUp).Row).Value
End Sub

Private Sub ComboBox1_Click()
  For i = 1 To 4
    Me("textbox" & i) = Me.ComboBox1.Column(i)
  Next i
End Sub

JB

 

[medino55]

Re : Charger une zone de liste modifiable à partir d'un code VBA

Un grand merci pour Dranreb et BOISGONTIER, les deux réponse ça marche bien,

 

[medino55]

Re : Charger une zone de liste modifiable à partir d'un code VBA

Mr BOISGONTIER, stp tu peux me montrer comment faire apparaitre deux colonnes dans un combobox comme tu la fait dans le fichier envoyé

 

[BOISGONTIER]

Re : Charger une zone de liste modifiable à partir d'un code VBA

Bonjour,

Propriété ColumnCount: 2
Propriété ColumnWidth: 50;50

JB