chaine de caractaire

[akramenergie]

Bonjour le forum,

SVP quelqu'un peut m'aider à diviser une chaîne de caractère en deux partie

ma_chaîne : carac_1\carac_2\carac_3\fich_4.xlsm

résulta souhaité:

chaîne 1= carac_1\carac_2\carac_3\

chaîne 2= fich_4.xlsm

Merci d'avance pour votre aide

 

[R@chid]

Re : chaine de caractaire

Bonjour,
Si ton texte est en A1, alors :
en B1,

=GAUCHE(A1;TROUVE("*";SUBSTITUE(A1;"\";"*";3)))

en C1,

=SUBSTITUE(A1;B1;)

@ + +

 

[Amilo]

Re : chaine de caractaire

Bonsoir akramergie, Re Rachid,

Sinon dans l'autre sens en inversant les résultats :

En B1 :

=STXT(A1;TROUVE("*";SUBSTITUE(A1;"\";"*";NBCAR(A1)-NBCAR(SUBSTITUE(A1;"\";))))+1;NBCAR(A1))

En C1 :

=SUBSTITUE(A1;B1;)

Bonne soirée à tous

 

[mapomme]

Re : chaine de caractaire

Bonsoir akramenergie, à tous,

Pour le fun et pour le cas, fort improbable, où la chaine finale se retrouverait deux fois ou plus dans la chaine initiale:

Pour le terme final:

=SUBSTITUE(DROITE(SUBSTITUE(A1;"\";REPT("\";255));255);"\";"")

Pour l'autre terme, par une formule matricielle:

=GAUCHE(A1;MAX((STXT(A1;LIGNE(INDIRECT("$1:$" & NBCAR(A1)));1)="\")*LIGNE(INDIRECT("$1:$" & NBCAR(A1))))-1)

Formule matricielle: Elle doit être validée par la combinaison des touches Ctrl+Maj+Entrée au lieu de la seule touche Entrée comme une formule classique.
Si la validation matricielle est correcte, alors Excel entoure la formule d'accolades {=.......}.
Chaque fois que cette formule sera modifiée, la validation devra se faire par Ctrl+Maj+Entrée. Les accolades apparaissent à la validation et ne doivent pas être saisies au clavier.

 

[R@chid]

Re : chaine de caractaire

Bonsoir @ tous,
Salut mapommme,
Si c'est le cas on peut toute fois garder ma première formule en B1,
alors qu'en C1,

=STXT(A1;NBCAR(B1)+1;255)

@ + +