XL 2019 Boite de dialogue Save as affiche mauvaise extension

Créer une discussion
Répondre

Boostez vos compétences Excel avec notre communauté !

Rejoignez Excel Downloads, le rendez-vous des passionnés où l'entraide fait la force. Apprenez, échangez, progressez – et tout ça gratuitement ! 👉 Inscrivez-vous maintenant !

S'inscrire
E

Electronull

XLDnaute Junior
Bonsoir à tous,

Quand j'ouvre une boite de dialogue Save as en mettant le nom du fichier et l'extension .xlsm, la boite affiche le nom et .xlsx
Comment je peux remédier à ça?

VB: 
' --- SAVE AS .xlsm ---
    Application.DisplayAlerts = True   ' réactive les alertes pour le dialogue
    baseName = wbDest.Name
    If InStrRev(baseName, ".") > 0 Then baseName = Left(baseName, InStrRev(baseName, ".") - 1)

    With Application.FileDialog(msoFileDialogSaveAs)
        .Title = "Enregistrer le fichier CIBLE sous..."
        .InitialFileName = wbDest.Path & "\" & baseName & "_MAJ_" & Format(Date, "yyyy_mm_dd") & ".xlsm"
        If .Show = -1 Then
            nomFichier = .SelectedItems(1)
            If LCase$(Right$(nomFichier, 5)) <> ".xlsm" Then nomFichier = nomFichier & ".xlsm"
            Application.DisplayAlerts = False
            wbDest.SaveAs Filename:=nomFichier, FileFormat:=xlOpenXMLWorkbookMacroEnabled
            Application.DisplayAlerts = True
            MsgBox "Fichier enregistré sous :" & vbCrLf & nomFichier, vbInformation
        Else
            MsgBox "Enregistrement annulé : le classeur cible reste ouvert sans sauvegarde.", vbExclamation
        End If
    End With

Merci
 
Trier par date Trier par votes
Bonjour,
à tester,

VB: 
With Application.FileDialog(msoFileDialogSaveAs)
    .Title = "Enregistrer le fichier CIBLE sous..."
    .InitialFileName = wbDest.Path & "\" & baseName & "_MAJ_" & Format(Date, "yyyy_mm_dd") & ".xlsm"

    ' Ajoute les filtres : ici uniquement .xlsm
    .Filters.Clear
    .Filters.Add "Classeur Excel avec macros (*.xlsm)", "*.xlsm"
    .FilterIndex = 1  ' applique ce filtre par défaut

    If .Show = -1 Then
        nomFichier = .SelectedItems(1)

        If LCase$(Right$(nomFichier, 5)) <> ".xlsm" Then
            nomFichier = nomFichier & ".xlsm"
        End If

        Application.DisplayAlerts = False
        wbDest.SaveAs Filename:=nomFichier, FileFormat:=xlOpenXMLWorkbookMacroEnabled
        Application.DisplayAlerts = True

        MsgBox "Fichier enregistré sous :" & vbCrLf & nomFichier, vbInformation
    Else
        MsgBox "Enregistrement annulé : le classeur cible reste ouvert sans sauvegarde.", vbExclamation
    End If
End With

Nicolas
 
Vote positif 0 Vote négatif
Bonjour
je te propose le dialog autre que celui de l'application il est plus simple et moins retord que celui de l'application.fildialog

voici ton code repris
VB: 
 ' --- SAVE AS .xlsm ---
     BaseName = wbdest.Name
    If InStrRev(BaseName, ".") > 0 Then BaseName = Mid(BaseName, 1, InStrRev(BaseName, ".") - 1)
  
  
    nomfichier = Application.GetSaveAsFilename( _
                                               InitialFileName:=wbdest.Path & "\" & BaseName & "_MAJ_" & Format(Date, "yyyy_mm_dd") & ".xlsm", _
                                               filefilter:="Excel Files (*.xlsm), *.xlsm", _
                                               Title:="Enregistrer le fichier CIBLE sous...")
  
     If nomfichier <> "Faux" Then
        Application.DisplayAlerts = False
        wbdest.SaveAs Filename:=nomfichier, FileFormat:=xlOpenXMLWorkbookMacroEnabled
        Application.DisplayAlerts = True
        MsgBox "Fichier enregistré sous :" & vbCrLf & nomfichier, vbInformation
    Else
        MsgBox "Enregistrement annulé : le classeur cible reste ouvert sans sauvegarde.", vbExclamation
    End If
testé et éprouvé😉

faire la différence entre les deux
1° Application.FileDialog(msoFileDialogSaveAs)
2° Application.GetSaveAsFilename


Patrick
 
Dernière édition:
Vote positif 0 Vote négatif
Nicolas JACQUIN à dit:
Bonjour,
à tester,

VB: 
With Application.FileDialog(msoFileDialogSaveAs)
    .Title = "Enregistrer le fichier CIBLE sous..."
    .InitialFileName = wbDest.Path & "\" & baseName & "_MAJ_" & Format(Date, "yyyy_mm_dd") & ".xlsm"

    ' Ajoute les filtres : ici uniquement .xlsm
    .Filters.Clear
    .Filters.Add "Classeur Excel avec macros (*.xlsm)", "*.xlsm"
    .FilterIndex = 1  ' applique ce filtre par défaut

    If .Show = -1 Then
        nomFichier = .SelectedItems(1)

        If LCase$(Right$(nomFichier, 5)) <> ".xlsm" Then
            nomFichier = nomFichier & ".xlsm"
        End If

        Application.DisplayAlerts = False
        wbDest.SaveAs Filename:=nomFichier, FileFormat:=xlOpenXMLWorkbookMacroEnabled
        Application.DisplayAlerts = True

        MsgBox "Fichier enregistré sous :" & vbCrLf & nomFichier, vbInformation
    Else
        MsgBox "Enregistrement annulé : le classeur cible reste ouvert sans sauvegarde.", vbExclamation
    End If
End With

Nicolas
Cliquez pour agrandir...
Salut,
Merci pour le bout de code, mais j'ai une erreur sur le .Filters.clear
 
Vote positif 0 Vote négatif
allez c'est kado
voici la même avec la possibilité de choisir le type (3 filtres)
l'estension par defaut etant le premier
VB: 
 Dim nomfichier As String
    Set wbdest = ThisWorkbook
    ' --- SAVE AS .xlsm ---
    BaseName = wbdest.Name
    If InStrRev(BaseName, ".") > 0 Then BaseName = Mid(BaseName, 1, InStrRev(BaseName, ".") - 1)
    
    
    nomfichier = Application.GetSaveAsFilename( _
                                               InitialFileName:=wbdest.Path & "\" & BaseName & "_MAJ_" & Format(Date, "yyyy_mm_dd") & ".xlsm", _
                                               filefilter:="Classeur macro (*.xlsm), *.xlsm, Classeur sans macro(*.xlsx),*.xlsx, Classeur binnaire (*.xlsb),*.xlsb", _
                                               Title:="Enregistrer le fichier CIBLE sous...")
    
    If nomfichier <> "Faux" Then
        Application.DisplayAlerts = False
        wbdest.SaveAs Filename:=nomfichier, FileFormat:=xlOpenXMLWorkbookMacroEnabled
        Application.DisplayAlerts = True
        MsgBox "Fichier enregistré sous :" & vbCrLf & nomfichier, vbInformation
    Else
        MsgBox "Enregistrement annulé : le classeur cible reste ouvert sans sauvegarde.", vbExclamation
    End If
démonstration
1756927790294.png
 
Vote positif 0 Vote négatif
patricktoulon à dit:
Bonjour
je te propose le dialog autre que celui de l'application il est plus simple et moins retord que celui de l'application.fildialog

voici ton code repris
VB: 
 ' --- SAVE AS .xlsm ---
     BaseName = wbdest.Name
    If InStrRev(BaseName, ".") > 0 Then BaseName = Mid(BaseName, 1, InStrRev(BaseName, ".") - 1)
 
 
    nomfichier = Application.GetSaveAsFilename( _
                                               InitialFileName:=wbdest.Path & "\" & BaseName & "_MAJ_" & Format(Date, "yyyy_mm_dd") & ".xlsm", _
                                               filefilter:="Excel Files (*.xlsm), *.xlsm", _
                                               Title:="Enregistrer le fichier CIBLE sous...")
 
     If nomfichier <> "Faux" Then
        Application.DisplayAlerts = False
        wbdest.SaveAs Filename:=nomfichier, FileFormat:=xlOpenXMLWorkbookMacroEnabled
        Application.DisplayAlerts = True
        MsgBox "Fichier enregistré sous :" & vbCrLf & nomfichier, vbInformation
    Else
        MsgBox "Enregistrement annulé : le classeur cible reste ouvert sans sauvegarde.", vbExclamation
    End If
testé et éprouvé😉

faire la différence entre les deux
1° Application.FileDialog(msoFileDialogSaveAs)
2° Application.GetSaveAsFilename


Patrick
Cliquez pour agrandir...
Bonsoir patricktoulon,

Marche super, toujours au taquet.
Je vais regarder ça d'un peu plus près pour pouvoir le réutiliser.
Merci et bonne soirée.
 
Vote positif 0 Vote négatif
VB: 
' --- SAVE AS .xlsm (via GetSaveAsFilename) ---
Application.DisplayAlerts = True   ' réactive les alertes pour le dialogue

Dim baseName As String, nomFichier As Variant
baseName = wbDest.Name
If InStrRev(baseName, ".") > 0 Then baseName = Left$(baseName, InStrRev(baseName, ".") - 1)

nomFichier = Application.GetSaveAsFilename( _
    InitialFileName:=wbDest.Path & "\" & baseName & "_MAJ_" & Format(Date, "yyyy_mm_dd") & ".xlsm", _
    FileFilter:="Classeur Excel avec macros (*.xlsm), *.xlsm", _
    Title:="Enregistrer le fichier CIBLE sous..." _
)

If nomFichier <> False Then
    If LCase$(Right$(CStr(nomFichier), 5)) <> ".xlsm" Then nomFichier = CStr(nomFichier) & ".xlsm"
    Application.DisplayAlerts = False
    wbDest.SaveAs Filename:=CStr(nomFichier), FileFormat:=xlOpenXMLWorkbookMacroEnabled
    Application.DisplayAlerts = True
    MsgBox "Fichier enregistré sous :" & vbCrLf & CStr(nomFichier), vbInformation
Else
    MsgBox "Enregistrement annulé : le classeur cible reste ouvert sans sauvegarde.", vbExclamation
End If

ou bonus

Code: 
Dim baseName As String, p As String
Dim choix As Variant, fmt As XlFileFormat

baseName = wbDest.Name
If InStrRev(baseName, ".") > 0 Then baseName = Left$(baseName, InStrRev(baseName, ".") - 1)
p = wbDest.Path & "\" & baseName & "_MAJ_" & Format(Date, "yyyy_mm_dd")

choix = Application.GetSaveAsFilename( _
    InitialFileName:=p & ".xlsm", _
    FileFilter:="Classeur Excel avec macros (*.xlsm), *.xlsm,Classeur Excel (*.xlsx), *.xlsx,Classeur Excel 97-2003 (*.xls), *.xls", _
    Title:="Enregistrer le fichier CIBLE sous..." _
)

If choix <> False Then
    Dim f As String: f = LCase$(CStr(choix))
    If Right$(f, 5) = ".xlsm" Then
        fmt = xlOpenXMLWorkbookMacroEnabled
    ElseIf Right$(f, 5) = ".xlsx" Then
        fmt = xlOpenXMLWorkbook
    ElseIf Right$(f, 4) = ".xls" Then
        fmt = xlExcel8
    Else
        ' Par défaut, force .xlsm si aucune extension reconnue
        f = f & ".xlsm": fmt = xlOpenXMLWorkbookMacroEnabled
    End If

    Application.DisplayAlerts = False
    wbDest.SaveAs Filename:=f, FileFormat:=fmt
    Application.DisplayAlerts = True
    MsgBox "Fichier enregistré sous :" & vbCrLf & f, vbInformation
Else
    MsgBox "Enregistrement annulé : le classeur cible reste ouvert sans sauvegarde.", vbExclamation
End If
 
Vote positif 0 Vote négatif
j'ajouterais et cela pour vous deux que le ".xlsm" est inutile avec getsavefilename
pour la simple et bonne raison que l'extension est la première pas defaut
donc @Nicolas JACQUIN ceci
If LCase$(Right$(CStr(nomFichier), 5)) <> ".xlsm" Then nomFichier = CStr(nomFichier) & ".xlsm"
est inutile

par contre oui j'avais oublié de changer le type dans le save as
mais il se fait par rapport au ".xlsx" ou autres
VB: 
Sub saveAs()
    Dim nomfichier As String, forme&
    Set wbdest = ThisWorkbook
    ' --- SAVE AS .xlsm ---
    BaseName = wbdest.Name
    If InStrRev(BaseName, ".") > 0 Then BaseName = Mid(BaseName, 1, InStrRev(BaseName, ".") - 1)
  
  
    nomfichier = Application.GetSaveAsFilename( _
                                               InitialFileName:=wbdest.Path & "\" & BaseName & "_MAJ_" & Format(Date, "yyyy_mm_dd"), _
                                               filefilter:="Classeur macro (*.xlsm), *.xlsm, Classeur sans macro(*.xlsx),*.xlsx, Classeur binnire (*.xlsb),*.xlsb", _
                                               Title:="Enregistrer le fichier CIBLE sous...")
  
    If nomfichier <> "Faux" Then
        If Right(nomfichier, 5) <> ".xlsx" Then forme = xlOpenXMLWorkbookMacroEnabled Else forme = xlOpenXMLWorkbook
        Application.DisplayAlerts = False
        wbdest.SaveAs Filename:=nomfichier, FileFormat:=forme
        Application.DisplayAlerts = True
        MsgBox "Fichier enregistré sous :" & vbCrLf & nomfichier, vbInformation
    Else
        MsgBox "Enregistrement annulé : le classeur cible reste ouvert sans sauvegarde.", vbExclamation
    End If
 End Sub
vous pouvez constater que dans le initialfilename je ne met pas l'extension
pourtant à l'affichage vous l'aurez
patrick
maintenant elle est complète
 
Vote positif 0 Vote négatif
re:
juste en passant vous avez un descriptif ici
patricktoulon

Discussion 'la boite de dialog Application.GetsaveFilename'

Bien utiliser le dialog (Application.GetSaveAsFilename)
par patricktoulon​

Bonjour a tous
la demande étant apparue plusieurs fois cette année ,je vous propose un mini tuto sur ce dialog


La fonction "Application.GetSaveAsFilename" permet d’ouvrir une boîte de dialogue
d’enregistrement de fichier, sans pour autant enregistrer réellement.
Elle retourne uniquement le chemin du fichier choisi par l’utilisateur.

----------------------------------------------------
Syntaxe de base :
----------------------------------------------------...
  • J'aime
 
Vote positif 0 Vote négatif
Rejoins nos membres "Supporter XLD" et booste ton expérience Excel !
- Navigue sans publicité
- Accède à Cléa, notre assistante IA experte Excel... et pas que...
- Profite de fonctionnalités exclusives
Ton soutien permet à Excel Downloads de rester 100% gratuit et de continuer à rassembler les passionnés d'Excel.
Je deviens Supporter XLD

Discussions similaires

Lu76Fer
Office XLS : Fonction simplifiant l'utilisation de la fenêtre FileDialog
Réponses
6
Affichages
509
Lu76Fer
Lu76Fer
M
  • Question Question
XL 2016 Erreur d'execution '52': Nom ou numéro de fichier incorrect
Réponses
4
Affichages
1 K
macseb
M
9
  • Question Question
Microsoft 365 Copier Coller les données (cellules) de plusieurs feuilles d'un classeur vers plusieurs autres feuilles d'un classeur
Réponses
5
Affichages
1 K
92lever
9
M
  • Résolu(e)
XL 2013 Mémoriser le dernier emplacement de sauvegarde
Réponses
9
Affichages
1 K
M.Ben
M
R
  • Question Question
XL 2016 Gestion de chemin de fichiers + VBA
Réponses
0
Affichages
3 K
Ryoken
R
secours
  • Question Question
XL 2010 debogage boite de dialogue save
Réponses
1
Affichages
691
secours
secours
BALANCIE
  • Question Question
XL 2019 Problème ouverture box.
Réponses
1
Affichages
1 K
sylvanu
sylvanu
L
  • Question Question
XL 2019 Problème de boucle ou de variables
Réponses
1
Affichages
1 K
Lucien31
L
N
  • Question Question
Access Access Boite de dialoge enregistrer sous
Réponses
6
Affichages
2 K
netparty
N
R
  • Résolu(e)
Autres Copier des feuilles d'un classeur à partir de données identiques
Réponses
2
Affichages
1 K
Renaud22
R
bellenm
  • Question Question
Gmail via CDO, attacher un fichier PDF, des adresses, un objet et un corps bien définit, code de Roland_M.
2 3
Réponses
43
Affichages
6 K
Roland_M
Roland_M
D
  • Question Question
Convertir tous les .xls des sous-dossiers d'un dossier
Réponses
1
Affichages
1 K
Disten
D
C
  • Question Question
XL 2010 Changer le nom dans une boîte de dialogue
Réponses
3
Affichages
2 K
Cydor007
C
J
  • Question Question
XL 2010 VBA Boite de dialogue Ouvrir et Enregistrer sous
Réponses
2
Affichages
6 K
jl456
J
S
  • Question Question
Améliorer une macro pour fusion de fichiers
Réponses
7
Affichages
1 K
Dranreb
Dranreb
P
  • Question Question
VBA : Boite de dialogue qui demande le Chemin
Réponses
3
Affichages
1 K
Pierrotv136
P
R
  • Question Question
VBA : "enregistrer sous" sans boite de dialogue
Réponses
8
Affichages
12 K
rico83600
R
M
  • Question Question
Mise à jour de plusieur fichiers dans des dossiers et sous dossiers
2
Réponses
16
Affichages
3 K
Morgane
M
W
  • Question Question
Besoin d'un coup de main en VBA
Réponses
1
Affichages
1 K
Alyrio
Alyrio
Y
  • Question Question
ouvrir word depuis excel avec une boite de dialogue fichier ouvrir sous word
Réponses
8
Affichages
7 K
sigismond
S
Retour