Calculer semaine

[abrium]

Bonjour

La nouvelle année debute à peine et deja je bloque.

Savez vous si d'une date je peux calculer la semaine

Ex : 03/01/2007 = S01


Merci par avance et tous mes voeux pour cette année 2007

 

[mjo]

Re : Calculer semaine

Bonjour,

="S"&TEXTE(NO.SEMAINE(A1);"00")

Vérifier si l'Utulitaire d'Analyse sous les Macros complémentaires du menu Outils est coché.

Cette fonction n'est valable que jusqu'en 2009, année à partir de laquelle la norme US n'est identique à la norme ISO (Eur).

mjo

.

 

[Tibo]

Re : Calculer semaine

Bonjour abrium, mjo,

Une autre solution (sans la macro complémentaire Utilitaire d'analyse) :

avec la date en A1

="S"&TEXTE(SI(A1="";"";ENT(MOD(ENT((A1-2)/7)+0.6;52+5/28)))+1;"00")

@+

 

[Monique]

Re : Calculer semaine

Bonjour,

Résumé (?) ou complément

N° de semaine selon la norme européenne
(la 1ère semaine contient au moins 4 jours) :
=ENT(MOD(ENT((A1-2)/7)+0,6;52+5/28))+1

=ENT((A1-SOMME(MOD(DATE(ANNEE(A1-MOD(A1-2;7)+3);1;2);{1E+99;7})*{1;-1})+5)/7)

=NO.SEMAINE(A1;2)-(JOURSEM(DATE(ANNEE(A1);1;1);2)>4)

N° de semaine selon Excel
Semaine commençant le lundi :
=NO.SEMAINE(A1;2)

Semaine commençant le dimanche :
=NO.SEMAINE(A1)
=NO.SEMAINE(A1;1)

Pour pouvoir utiliser la fonction No.Semaine(),
barre de menu - Outils - Macros complémentaires
et cocher "Utilitaire d'analyse"