Microsoft 365 calcul Statistiques

[pompaero]

Bonjour le forum,

Dans le classeur joint (pour exemple) j'aimerai pouvoir calculer les statistiques de certain évènement.
J'ai bien trouvé la formule avec NB.SI() mais cela ne suffi pas car je voudrais également filtrer sur les mois, l'année et les agents.
Je cherche à comptabiliser les évènements (SV, VDN) en colonne I, qui sont inférieur à 8h et supérieur à 18h sauf le vendredi qui sont supérieur à 16h par rapport à la colonne A.
J'ai tenté un TCD mais sans résultat...
Est il possible d'avoir de l'aide la dessus, merci à vous.

Cordialement

 

[Hasco]

Bonjour,

Dans le fichier joint j'ai ajouté une colonne contenant la fonction :

=AGREGAT(3;3;[@Date])

Qui donne 1 si la ligne est visible et 0 si non filtrée.
Cette colonne permet de ne prendre en compte que les lignes qui correspondent aux choix des segments de la feuille Feuil2.
La colonne Jour sem n'est là que pour vérification.

Comme vous avez 365 j'ai fait avec la fonction FILTRE :

=LIGNES(FILTRE(TabBD;(TabBD[Evevement]=$B$4)*
(TabBD[Visible]=1)*
((TabBD[Hr deb période1]<8/24)+(TabBD[Hr fin période1]> SI(JOURSEM(TabBD[Date];2)=5;16/24;18/24)))))

Qui nous donne un résultat correcte

En B18 de feuil2 j'ai remis provisoirement la fonction filtre qui affiche ses résultats, pour contrôles et vérifications.

La formule avec sommeprod donne des résultats faux si l'heure de début est antérieure à 8 heures et l'heure de fin > 16 ou 18.
Dans ce cas là la ligne est comptée 2 fois.

=SOMMEPROD((TabBD[Evevement]=$B$4)*
(TabBD[Visible]=1)*
((TabBD[Hr deb période1]<8/24)+(TabBD[Hr fin période1]> SI(JOURSEM(TabBD[Date];2)=5;16/24;18/24))))

Pour le moment et ces cas là je n'ai pas de solution avec sommeprod.

Dans les deux formules, pour les vendredi je me suis strictement tenu à l'énoncé :

sauf le vendredi qui sont supérieur à 16h

s'il y a des samedis et dimanches il sont comptés comme les autres jours que le vendredi.

Cordialement

 

[Hasco]

Re,

J'ai trouvé pour le sommeprod, il suffit de rajouter >0 en fin des tests horaires :

=SOMMEPROD((TabBD[Evevement]=$B$4)*
(TabBD[Visible]=1)*
((TabBD[Hr deb période1]<8/24)+(TabBD[Hr fin période1]> SI(JOURSEM(TabBD[Date];2)=5;16/24;18/24))>0))

Explications:
(TabBD[Hr deb période1]<8/24) si vrai = 1
+
TabBD[Hr fin période1]> SI(JOURSEM(TabBD[Date];2)=5;16/24;18/24) si vrai = 1

donc si les deux sont vrais, on obtient 2

Avec ((Test 1 = Vrai)+(Test 2 = Vrai)) >0 on obtient 1 si vrai ou 0 si faux.

Cordialement

 

[pompaero]

Bonjour Hasco,
merci de ton retour et ton implication, c'est cool.
Après analyse, je trouve le résultat très proche de mes attentes. Le fait de filtrer à l'aide des segments est très intéressant.
La fonction Filtre "que je ne connais pas" à l'air de fonctionner.
le fait d'avoir des statistiques par agent est super, maintenant en parallèle est il possible d'avoir la même chose pour les segments année et mois mais sans doublon par évènements sur les dates ?
Par exemple :
- Le 16 juillet 21, nous avons 2 agents avant 8h et 2 agents Après 18h (4 agents au total) ce qui donne 4 avec ta formule mais en réalité cela fait 2 missions supplémentaires dans la journée.
- Le 14 sept 21, nous avons 2 agents avant 8h et 2 agents après 18h (3 agents au total) ce qui donne 3 avec ta formule mais en réalité cela fait 2 missions supplémentaires dans la journée.

J'espère avoir expliquer au mieux, si manque de détails dit le moi.
Merci
Cordialement

 

[Hasco]

Re,

Vous n'avez pas pris en compte mon dernier message pour la correction de sommeprod.

Comprends pas comment déterminer qu'il s'agit de N missions supplémentaires dans la journée.

Mais il y a des gens très intelligents sur ce forum, qui comprendront certainement mieux que moi.

Cordialement

 

[Hasco]

Re,

En reprenant le truc peut-être que :

Une date + même heure debut et même heure fin = une intervention quelque soit le nombre d'agent ?

Si c'est ça se serait plus facile de faire avec Power Query.

Mais je crains qu'il manque quelque chose....

Cordialement

 

[pompaero]

Bonsoir Hasco

Oui c'est ça, l'idée est là