Calcul d'occurence en fonction du mois

[citizenbaban]

Bonjour à tous, le forum,

J'espère qu'il restera un peu de forumeurs ici, que tout le monde n'est pas parti profiter des premiers rayons de soleil de juillet ^^.

Je vous expose rapidement mon problème ; j'ai du mal à pondre 2 formules (pas de macro):
1ère qui permet de : calculer parmi une plage de date au format JJ/MM/AAAA (une seule colonne) le nombre de valeur pour janvier, février, etc.

2ème qui permet de : une fois la page identifiée par la 1ère formule (comme A3:A7 pour les tests de janvier par exemple) faire une somme de la colonne B pour les mêmes lignes (B3:B7).

Ce n'est pas évident à expliquer en fait 😕, j'ai mis un fichier exemple en PJ qui sera plus parlant je pense.

Je ne sais pas si cela est faisable par une formule mais j'évite les macros au boulot 😛


Merci pour votre temps

Citizen

 

[R@chid]

Re : Calcul d'occurence en fonction du mois

Bonjour,
Si j'ai bien compris,
en B3,

=SOMMEPROD(N(MOIS(Feuil1!A$3:A$10)=MOIS(1&A3)))

en C3,

=SOMMEPROD((MOIS(Feuil1!A$3:A$10)=MOIS(1&A3))*(Feuil1!B$3:B$10))

@ tirer vers le bas


Enlever le "s" à la fin du Mai.

@ + +

 

[citizenbaban]

Re : Calcul d'occurence en fonction du mois

Merci pour la réponse rapide R@chid
Effectivement, Mai sans le "s" c'est mieux.

Par contre j'ai un petit souci avec la 1ère formule car c'est un tableau qui sera rempli au jour le jour donc je ne peux pas définir de plage fixe pour les dates, j'aimerai donc tirer entre A3:A300 par exemple mais lorsque la formule tombe sur une case vide, celle-ci est compté comme "janvier".

Je vais essayer de bricoler la SOMMEPROD dans un SI, ça devrait le faire.
Je reviens pour tenir informé.

Citizen

 

[R@chid]

Re : Calcul d'occurence en fonction du mois

Re,
T'as rien à bricoler avec la fonction SI().

Dans le gestionnaire de noms, tu peux créer des champs dynamiques nommés :

Col_Dates :

=DECALER(Feuil1!$A$3;;;NB(Feuil1!$A:$A))

Col_Test :

=DECALER(Col_Dates;;1)

Puis réécrire les formules de calculs comme suit :
en B3 :

=SOMMEPROD(N(MOIS(Col_Dates)=MOIS(1&A3)))

en C3 :

=SOMMEPROD((MOIS(Col_Dates)=MOIS(1&A3))*(Col_Test))

@ + +

 

[job75]

Re : Calcul d'occurence en fonction du mois

Bonjour citizenbaban, hello R@chid,

Annulé, mais ça m'aura donné l'occasion de vous saluer 🙂

A+

 

[R@chid]

Re : Calcul d'occurence en fonction du mois

Bonjour @ tous,
Salut Job75,
la fonction INDIRECT() peut faire l'affaire aussi :
Col_Dates :

=INDIRECT("Feuil1!A3:A"&NB(Feuil1!$A:$A)+2)

@ + +

 

[citizenbaban]

Re : Calcul d'occurence en fonction du mois

Bonjour à tous,

Désolé pour le délai entre les posts mais j'ai été out à cause d'un semblant de grippe.
Je me suis repenché sur la formule de R@chid

=SOMMEPROD((MOIS(Col_Dates)=MOIS(1&A3))*(Col_Test))

Et ça marche au top...sauf que....il faut bien un sauf 🙂
Comme je l'avais marqué dans le fichier exemple, les valeurs de la colonne B, Feuil1 peuvent prendre d'autres valeurs que 0 et 1. Du coup quand je me retrouve avec un 2 et 3, forcément, le SOMMEPROD biaise.
Il faudrait un SOMMEPROD qui prenne "1" comme valeur de B, dès que B est <>0, et pas sa valeur réelle.

J'ai bien essayé de le faire en solo mais je crois que mes sinus bouchés empêchent l'oxygène d'arriver au cerveau, je n'arrive à rien 😀

@++

 

[job75]

Re : Calcul d'occurence en fonction du mois

Bonjour citizenbaban, le forum,

Pour éviter de réveiller R@chid :

=SOMMEPROD((MOIS(Col_Dates)=MOIS(1&A3))*SIGNE(Col_Test))

A+

 

[citizenbaban]

Re : Calcul d'occurence en fonction du mois

Vous êtes au courant que c'est quand même vachement frustrant de voir quelqu'un trouver la solution aussi rapidement? 😛

Job75, R@chid, merci pour votre aide, ça tourne nickel.