Calcul des points au bridge

ROGER2327

XLDnaute Barbatruc

• 14 Avril 2012

• #2

Re : Calcul des points au bridge

Bonsoir Polotor

1. En G3, saisir :
   Code:

   =INDEX($J$3:$J$10;EQUIV(LIGNE(1:1);SI(ESTERR(GRANDE.VALEUR($D$3:$D$10;LIGNE($1:$8)));EQUIV(PETITE.VALEUR($E$3:$E$10;LIGNE($1:$8)-NB($D$3:$D$10));$E$3:$E$10;0);EQUIV(GRANDE.VALEUR($D$3:$D$10;LIGNE($1:$8));$D$3:$D$10;0));0))

2. Valider par Ctrl Maj Entrée.
3. Recopier vers le bas jusqu'à G10.

ROGER2327
#5778

Dimanche 22 Clinamen 139 (Fête des Polyèdres - fête Suprême Seconde)
24 Germinal An CCXX, 9,2385h - roquette
2012-W15-5T22:10:21Z

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 14 Avril 2012

• #3

Re : Calcul des points au bridge

Bonsoir @ tous,
Salut Roger
Une proposition en PJ.
Amicalement

 

Pièces jointes

• Polotor.xlsx

  11.4 KB · Affichages: 331

Dernière édition: 14 Avril 2012

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 14 Avril 2012

• #4

Re : Calcul des points au bridge

Rebonsoir,
Apres avoir bien reflechis, on peut faire simple , en G3 sur ton fichier original :

Code:

=SI(D3<>"";GRANDE.VALEUR(J$3:J$10;RANG(D3;D$3:D$10));0)+SI(E3<>"";GRANDE.VALEUR(J$3:J$10;RANG(E3;E$3:E$10;1)+NBVAL(D$3:D$10));0)

@ tirer vers le bas
Amicalement

 

Vote positif 0 Vote négatif

ROGER2327

XLDnaute Barbatruc

• 14 Avril 2012

• #5

Re : Calcul des points au bridge

Suite... (bonsoir Rachid_0661)

Si le tableau J3:J10 n'est jamais modifié, on peut s'en passer avec

Code:

=16-2*EQUIV(LIGNE(1:1);SI(ESTERR(GRANDE.VALEUR($D$3:$D$10;LIGNE($1:$8)));EQUIV(PETITE.VALEUR($E$3:$E$10;LIGNE($1:$8)-NB($D$3:$D$10));$E$3:$E$10;0);EQUIV(GRANDE.VALEUR($D$3:$D$10;LIGNE($1:$8));$D$3:$D$10;0));0)

qui ne fait référence qu'à la plage D3😀10. (Et merde aux frimousses ! On ne peut même plus écrire correctement avec ces saloperies pour demeurés...)​

ROGER2327
#5779

Dimanche 22 Clinamen 139 (Fête des Polyèdres - fête Suprême Seconde)
24 Germinal An CCXX, 9,4275h - roquette
2012-W15-5T22:37:34Z

 

Vote positif 0 Vote négatif

ROGER2327

XLDnaute Barbatruc

• 14 Avril 2012

• #6

Re : Calcul des points au bridge

Rachid_0661 à dit:

Rebonsoir,
Apres avoir bien reflechis, on peut faire simple , en G3 sur ton fichier original :

Code:

=SI(D3<>"";GRANDE.VALEUR(J$3:J$10;RANG(D3;D$3:D$10));0)+SI(E3<>"";GRANDE.VALEUR(J$3:J$10;RANG(E3;E$3:E$10;1)+NBVAL(D$3:D$10));0)

@ tirer vers le bas
Amicalement

Cliquez pour agrandir...

Bravo, bien vu ! Inutile de se compliquer la vie...
Simplifions encore :

Code:

=SI(E3;GRANDE.VALEUR(J$3:J$10;RANG(E3;E$3:E$10;1)+NBVAL(D$3:D$10));GRANDE.VALEUR(J$3:J$10;RANG(D3;D$3:D$10)))

ROGER2327
#5780

Dimanche 22 Clinamen 139 (Fête des Polyèdres - fête Suprême Seconde)
24 Germinal An CCXX, 9,5728h - roquette
2012-W15-5T22:58:29Z

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 14 Avril 2012

• #7

Re : Calcul des points au bridge

ReBonsoir,
@ Roger : comme tu as dit,

Inutile de se compliquer la vie...

Cliquez pour agrandir...

ta derniere formule est la Bonne.
Amicalement
Edit : Je ne sais pas pourquoi notre Cher @mi Victor "Like" ta dernier formule matricielle, j'ai pense quelle gere le cas de doublons dans la meme colonne, mais j'ai trouve le contraire elle renvoie le #N/A

 

Dernière édition: 14 Avril 2012

Vote positif 0 Vote négatif

D

david84

XLDnaute Barbatruc

• 14 Avril 2012

• #8

Re : Calcul des points au bridge

Bonsoir tout le monde,
à tester (validation classique) :

Code:

=INDEX(J$3:J$10;SI(D3<>"";RANG(D3;D$3:D$10);RANG(E3;E$3:E$10;1)+NB(D$3:D$10)))

A+

 

Vote positif 0 Vote négatif

ROGER2327

XLDnaute Barbatruc

• 14 Avril 2012

• #9

Re : Calcul des points au bridge

david84 à dit:

Bonsoir tout le monde,
à tester (validation classique) :

Code:

=INDEX(J$3:J$10;SI(D3<>"";RANG(D3;D$3:D$10);RANG(E3;E$3:E$10;1)+NB(D$3:D$10)))

A+

Cliquez pour agrandir...

De mieux en mieux...
Et pourquoi pas :

Code:

=16-2*SI(D3;RANG(D3;D$3:D$10);RANG(E3;E$3:E$10;1)+NB(D$3:D$10))

tant qu'on y est ?​

ROGER2327
#5781

Dimanche 22 Clinamen 139 (Fête des Polyèdres - fête Suprême Seconde)
24 Germinal An CCXX, 9,8649h - roquette
2012-W15-5T23:40:33Z

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 14 Avril 2012

• #10

Re : Calcul des points au bridge

Rebonsoir,
Il est tres chanceux Polotor, une seule Question va enrichir son savoir en Excel.
Amicalement

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 14 Avril 2012

• #11

Re : Calcul des points au bridge

Bonsoir @ tous,
une autre, pas comme la derniere de Roger en G3 :

Code:

=GRANDE.VALEUR(J$3:J$10;SI(D3;RANG(D3;D$3:D$10);RANG(E3;E$3:E$10;1)+NB(D$3:D$10)))

Amicalement

 

Vote positif 0 Vote négatif

D

david84

XLDnaute Barbatruc

• 14 Avril 2012

• #12

Re : Calcul des points au bridge

Re

Code:

De mieux en mieux...
Et pourquoi pas :
Code :
=16-2*SI(D3;RANG(D3;D$3:D$10);RANG(E3;E$3:E$10;1)+NB(D$3:D$10))
tant qu'on y est ?

j'avais également

Code:

=INDIRECT(ADRESSE(SI(D3;RANG(D3;D$3:D$10);RANG(E3;E$3:E$10;1)+NB(D$3:D$10))+2;10))

ou

Code:

=DECALER(J$2;SI(D3;RANG(D3;D$3:D$10);RANG(E3;E$3:E$10;1)+NB(D$3:D$10));)

mais là je m'incline !
A+

 

Vote positif 0 Vote négatif

J

JJ1

Guest

• 14 Avril 2012

• #13

Re : Calcul des points au bridge

Bonjour David, Roger, Rachid,

Notre ami Polotor va être satisfait, je pense, de ces formules! Bravo pour cette progression d'ingéniosité pour arriver à l'ultime formule!
Bon samedi

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 14 Avril 2012

• #14

Re : Calcul des points au bridge

Bonjour @ tous,

Ma questions est la suivante comment calculer le tableau G3:G10 ? Sachant qu'il y a une complication en cas de résultats identiques mais bon… déjà c'est pour le moment assez dur. J'ai testé avec des mélanges de si et de max, mais je ne dompte pas assez bien la bête !!!

Cliquez pour agrandir...

Sachant qu'il y a une complication en cas de résultats identiques

Cliquez pour agrandir...

On peut le faire avec colonnes Intermediaires,
Voir PJ.
Amicalement

 

Pièces jointes

• Polotor_Doublons.xlsx

  12.3 KB · Affichages: 189
• Polotor_Doublons.xlsx

  12.3 KB · Affichages: 172
• Polotor_Doublons.xlsx

  12.3 KB · Affichages: 180

Vote positif 0 Vote négatif

P

Polotor

Guest

• 15 Avril 2012

• #15

Re : Calcul des points au bridge

Franchement, je viens de m'inscrire, je galère sur cette problématique et vous m'avez tellement donné de réponses que c'est claire que Rachid a bien raison, je vais pouvoir enrichir mon savoir en Excel...

Un grand merci encore à Roger2327, Rachid_0661, David84 et JJ1

Le fichier est toujours pas fini mais vous m'avez vraiment beaucoup aidé.

Merci encore

 

Vote positif 0 Vote négatif