Calcul de moyenne sans tenir compte du 0

[Bernard 69]

Bonjour à tous

Pour un calcul de moyenne on peux apliquer la fonction suivante si les cellules se suivent
=SOMME.SI(A1:A10;">0")/NB.SI(A1:A10;">0")

Mais si les cellules ne se touches pas comment fait t'on?

Ex le calcule de A3,D3,G3

Merci a l'avance.
Bernard

 

[Monique]

Bonjour,

=MOYENNE(A3;D3;G3)

Si les autres cellules sont vides ou contiennent du texte :
=MOYENNE(A3:G3)

Si tes données sont 1 cellule sur 3 (ici, colonnes 1, 4 et 7) :
=SOMMEPROD((MOD(COLONNE(A3:G3);3)=1)*A3:G3)/SOMMEPROD((MOD(COLONNE(A3:G3);3)=1)*1)

Si tes données sont 1 cellule sur 3 :
=MOYENNE(SI(MOD(COLONNE(A3:G3);3)=1;A3:G3))
formule matricielle, à valider par ctrl, maj et entrée

 

[Jean-Marie]

Bonjour Bernard

Si les cellules sont toujours espacées de deux cellules, voici une fonction matricielle à valider par les touches Ctrl+Shift+Entrer

=MOYENNE(SI((A3:G3>0)*(MOD(2+COLONNE(A3:G3);3)=0);A3:G3;""))

Les fonctions matricielles n'aiment pas les plages entières. Tu dois avoir après validation par les trois touches "{" en début et } en fin de formules.

@+Jean-Marie

 

[Bernard 69]

Bonjour à tous.

Tout d'abort un merci a Monique et Jean-Marie

Je n'arrive pas à mettre en application vos fonctions.
je vous joins mon fichier qui me casse la tette depuis 3h ce matin
Merci à l'avance.
Bernard

 

[Jean-Marie]

Re

La répétition des cellules est d'un facteur de 6 et non 5.
Tu commences en colonne C (3ème), mod(3;6) retourne 3, cette valeur sera donc la valeur du comparateur.

Pourquoi diviser par SOMMEPROD((MOD(COLONNE(C34:AA34);6)=3)*1), autant diviser par 5 ou par ENT(colonnes(C34:AA34)/5)

=SOMMEPROD((MOD(COLONNE(C34:AA34);6)=3)*C34:AA34)/5

@+Jean-Marie

 

[Monique]

Bonjour,

Première série de formules : du Decaler() à gogo
Deuxième série : tu as le choix entre 2 méthodes.
Tu as dans ton classeur une feuille "Essais"
où les formules de la 1ère série sont décomposées.

 

[Bernard 69]

Re bonjour.

Encore merci pour ce coup de main.

Je me dis que ce monde n'est pas si égoiste que cela grace à des personnes comme vous.
Vous etes un exemple à montrer.
Mille mercis...
Je vous suis redevable

Amitié.
Bernard.

 

[Bernard 69]

Re bonjour.
Comment faire votre fonction sans prendre en compte les cellues ou il y a un zéro.
Voici la fontion que j'utilise
=SOMMEPROD((MOD(COLONNE($C34:$AF34);6)=MOD(COLONNE();6))*$C34:$AF34)/5
Merci à l'avance.
Bonne soirée.
Bernard

 

[Monique]

Re,

En colonne C (ou I ou O) pour faire un essai :
=MOYENNE(SI(MOD(COLONNE($C34:$AF34);6)=MOD(COLONNE();6);SI($C34:$AF34>0;$C34:$AF34)))
formule matricielle, à valider par ctrl, maj et entrée