Calcul age à partir d'une date

[marinanetrol]

Bonjour à tous,

j'ai un petit problème pour calculer l'age d'un animal à partir de sa date de naissance et de sa date de vente.
A1 : Date de vente de l'animal (../../....)
B1 : Date de naissance (../../....)

comment faire pour calculer un age sous la forme Année,Mois puisqu'après je voudrais faire une moyenne pour regrouper certains animaux.

Merci d'avance,

Marinanetrol

 

[hoerwind]

Re : Calcul age à partir d'une date

Bonjour,

La formule :

=DATEDIF(A2;A1;"y")&" an(s) et "&DATEDIF(A2;A1;"ym")&" mois"

renverra le nombre d'années et de mois, mais elle ne te permettra pas de calculer une moyenne, puisque le résultat est un format texte.

Avec en pièce jointe un petit exemple de ce que tu souhaites réaliser, ainsi que le résultat attendu, ce sera plus facile pour te montrer comment faire.

 

[KenDev]

Re : Calcul age à partir d'une date

Bonjour Marina, bonjour le fil,

Si tu disposes tes dates de vente en colonne A, et tes dates de naissance en colonne B (avec la ligne 1 réservée aux titres) des colonnes alors :

en C2 (puis copier sur la colonne) l'age de l'animal (nb années) :

=ENT((A2-B2)/365,24)

en D2 (puis copier sur la colonne) l'age de l'animal (nb mois) :

=ARRONDI(((A2-B2)-C2*365,24)*12/365,24;0)

N'importe ou (sauf sous le tableau, colonnes A et B car le contenu de ces 2 colonnes sont comptées lors des formules), la moyenne des ages des animaux (nb années) :

=ENT((SOMME(A:A)-SOMME(B:B))/NB(A:A)/365,24)

N'importe ou (idem), la moyenne des ages des animaux (nb de mois) :

=ARRONDI(((SOMME(A:A)-SOMME(B:B))-E2*365,24*NB(A:A))*12/365,24/NB(A:A);0)

Si tu souhaites avoir l'age sous la forme "3 ans 2 mois" alors :

en C2 (puis copier sur la colonne) l'age de l'animal :

=SI(ENT((A2-B2)/365,24)>1;CONCATENER(ENT((A2-B2)/365,24); " ans ";ARRONDI(((A2-B2)-ENT((A2-B2)/365,24)*365,24)*12/365,24;0); " mois");CONCATENER(ENT((A2-B2)/365,24); " an ";ARRONDI(((A2-B2)-ENT((A2-B2)/365,24)*365,24)*12/365,24;0); " mois"))

N'importe ou (avec les mêmes réserves), la moyenne des ages des animaux :

=SI(ENT((SOMME(A:A)-SOMME(B:B))/NB(A:A)/365,24)>1;CONCATENER(ENT((SOMME(A:A)-SOMME(B:B))/NB(A:A)/365,24); " ans ";ARRONDI(((SOMME(A:A)-SOMME(B:B))-ENT((SOMME(A:A)-SOMME(B:B))/NB(A:A)/365,24)*365,24*NB(A:A))*12/365,24/NB(A:A);0); "mois");CONCATENER(ENT((SOMME(A:A)-SOMME(B:B))/NB(A:A)/365,24); " an ";ARRONDI(((SOMME(A:A)-SOMME(B:B))-ENT((SOMME(A:A)-SOMME(B:B))/NB(A:A)/365,24)*365,24*NB(A:A))*12/365,24/NB(A:A);0); "mois"))

Ces 2 dernières formules sont un peu longues parceque j'ai tenu à écrire "an" au singulier lorsque l'age est inférieur à 2 ans. 🙂 .

365,24 est le nombre moyen de jours par an (sur 100 ans 76 années ont 365 jours et 24 en ont 366).
365,24/12 représente donc le nombre moyen de jours par mois.

Je joint un classeur exemple.

Edit : J'enlève l'avertissement sur la longueur de la dernière formule, sous Excel2010 ça devrait aller...

 

[KenDev]

Re : Calcul age à partir d'une date

2 Corrections:

en D2 l'age de l'animal (nb mois) :

=ARRONDI(((A2-B2)-C2*365,24)*12/365,24;0)

devient :

=ENT(((A2-B2)-C2*365,24)*12/365,24

Pour éviter d'avoir par exemple un animal de 4 ans 12 mois...
Les colonnes C et D donnent donc l'age révolu

De même pour la forme la forme "3 ans 2 mois" :

=SI(ENT((A2-B2)/365,24)>1;CONCATENER(ENT((A2-B2)/365,24); " ans ";ARRONDI(((A2-B2)-ENT((A2-B2)/365,24)*365,24)*12/365,24;0); " mois");CONCATENER(ENT((A2-B2)/365,24); " an ";ARRONDI(((A2-B2)-ENT((A2-B2)/365,24)*365,24)*12/365,24;0); " mois"))

devient :

=SI(ENT((A2-B2)/365,24)>1;CONCATENER(ENT((A2-B2)/365,24); " ans ";ENT(((A2-B2)-ENT((A2-B2)/365,24)*365,24)*12/365,24); " mois");CONCATENER(ENT((A2-B2)/365,24); " an ";ENT(((A2-B2)-ENT((A2-B2)/365,24)*365,24)*12/365,24); " mois"))

Les 4 autres formules inchangées.

KD

 

[marinanetrol]

Re : Calcul age à partir d'une date

Merci à tous, cela m'a bien aidé pour faire mon état!!

Marinanetrol