Année N SI entre trois dates

[Xav22]

Bonjour à toutes et à tous,

Je souhaiterais connaitre la formule SI pour avoir le résultat suivant :

si la date est comprise entre mai-06 & avril-07 =2006
si la date est comprise entre mai-07 & avril-08 =2007
si la date est comprise entre mai-08 & avril-09 =2008

=SI(ET(J11>="01/05/06"*1;J11<="30/04/07"*1);"2006";SI(ET(J11>="01/05/07"*1;J11<="30/04/08"*1);"2007");SI(ET(J11>="01/05/08"*1;J11<="30/04/09"*1);"2008"))

Réponse d'Excel : Vous avez tapéun nombre trop important d'argument pour cette fonction.

Merci par avance de votre aide.

Cordialement,

Xavier

 

[JHA]

Re : Année N SI entre trois dates

Bonjour Xavier, le forum,

Juste un petit soucis de parenthese

=SI(ET(J11>="01/05/06"*1;J11<="30/04/07"*1);"2006";SI(ET(J11>="01/05/07"*1;J11<="30/04/08"*1);"2007";SI(ET(J11>="01/05/08"*1;J11<="30/04/09"*1);"2008")))

JHA

 

[Tibo]

Re : Année N SI entre trois dates

Bonjour,

Un tout petit souci de parenthèse :

Essaye cette version :

=SI(ET(J11>="01/05/06"*1;J11<="30/04/07"*1);"2006";
SI(ET(J11>="01/05/07"*1;J11<="30/04/08"*1);"2007";
SI(ET(J11>="01/05/08"*1;J11<="30/04/09"*1);"2008";"")))

@+

Edit : Bing ! Salut JHA, pas très rapide sur le coup !!!

@+

 

[Samantha]

Re : Année N SI entre trois dates

Bonjour,

C'est une petite erreur de parenthèses :

=SI(ET(J11>="01/05/06"*1;J11<="30/04/07"*1);"2006";SI(ET(J11>="01/05/07"*1;J11<="30/04/08"*1);"2007";SI(ET(J11>="01/05/08"*1;J11<="30/04/09"*1);"2008")))
et non
=SI(ET(J11>="01/05/06"*1;J11<="30/04/07"*1);"2006";SI(ET(J11>="01/05/07"*1;J11<="30/04/08"*1);"2007");SI(ET(J11>="01/05/08"*1;J11<="30/04/09"*1);"2008"))

tu peux aussi faire
=SI(ET(J11>=DATE(2006;5;1);J11<=DATE(2007;4;30));"2006";SI(ET(J11>=DATE(2007;5;1);J11<=DATE(2008;4;30));"2007";SI(ET(J11>=DATE(2008;5;1);J11<=DATE(2009;4;30));"2008";0)))

Ou encore plus simple :

• Tu saisis tes bornes dans un coin de ta feuille au format jj/mm/aa
• Tu mets dans ta formule les références à ces cellules
• Ca te permet ainsi de faire les MAJ au fil du temps si nécessaire sans modifier ta formule (juste saisir les bonnes bornes dans ton annexe)
• et avec une formule encore plus courte avec des plages nommées : =INDEX(VALEUR;EQUIV(J11;DEPART;1)) voir tableau joint

Tu nous dis ?

Sam

 

[Xav22]

Re : Année N SI entre trois dates

Merci beaucoup pour votre aide.

Xavier

 

[Monique]

Re : Année N SI entre trois dates

Bonjour,

Je crois que çà marche, à vérifier
=ANNEE(DATE(ANNEE(A1);MOIS(A1)-4;1))

Idem au conditionnel
=SI(OU(A1>="1/5/9"*1;A1<"1/5/6"*1);"";ANNEE(DATE(ANNEE(A1);MOIS(A1)-4;1)))