XL 2010 Ajouter ligne.

[DAVID-44-]

Bonjour à tous,
J'ai un tableau "Stock" avec un bouton "Insérer ligne" : macro dans le module 4. Quand je l'utilise, il permet d'ajouter une ligne sur tous les sous-produits de la feuille sous "Fournisseurs". J'aimerais changer cette macro et pouvoir ajouter (avec un copier/coller) une ligne ou plusieurs lignes sous une ligne ou sous plusieurs lignes sélectionnées un peu comme le bouton "Supprimer ligne" : macro dans le module 4.
Merci de votre aide.
Bon après-midi.
David.

 

[DAVID-44-]

Bonjour à tous,
J'ai à nouveau essayé de créer une macro pour insérer une ligne où je le souhaite à l'aide d'un bouton malheureusement, ça me copie plusieurs lignes !
Merci de votre aide.
Bonne journée.
David.

 

[job75]

Bonjour DAVID-44-,

Voyez le fichier joint et cette macro dans Module4 :

Sub Inserer()
Dim r&, x$, n&, i&
r = ActiveCell.Row
If Cells(r, 3).Interior.Color <> RGB(218, 238, 243) Then MsgBox "Sélectionnez une cellule sous FOURNISSEURS...", , "Insérer": Exit Sub
Do
    x = InputBox("Nombre de lignes à insérer :", "Insérer", x)
    If x = "" Then Exit Sub
    n = Int(Val(x))
Loop While n < 1
Application.ScreenUpdating = False
ActiveSheet.Protect Password:=Password, UserInterfaceOnly:=True
Rows(r + 1).Resize(n).Insert
For i = 1 To n
    Rows(r).Copy Rows(r + i) 'pour les formules et les formats (MFC)
Next
If Cells(r, 15).MergeCells Then Range(Cells(r, 15).MergeArea, Cells(r + 1, 15).Resize(n)).Merge 'colonne O
On Error Resume Next 'si aucune SpecialCell
Rows(r + 1).Resize(n, 13).SpecialCells(xlCellTypeConstants) = Empty 'colonnes A à M
End Sub

La boucle est nécessaire pour que les MFC soient copiées correctement.]

[Edit] coquille corrigée sur l'avant-dernière ligne de la macro.

A+

 

[DAVID-44-]

Bonjour job75,
Merci beaucoup, c'est exceptionnel.
Bonne soirée.
David.