aide importation feuille ce calsseur excel

[titooooo]

bonjour

serait il possible de m'aider dans ma quête

je possède un fichier que vais appeler synthèse

dans le même dossier je met chaque jours plusieurs fichier excel 5 ,6, 10 , 30..... ça dépend de la journée parmi eux un fichier qui s'appelle groupe.

dans ce fichier je veux en exécutant une macro que excel importe la feuille 1 du fichier groupe dans la feuille groupe et de chaque fichier présent dans ce meme dossier la 1ere feuille chacune dans une feuille a part

exemple

dossier qui contient
groupe.xls
1.xls
2.xls
3.xls


je désire que excel importe la 1ére feuille de groupe dans feuille groupe
premiére feuille de 1.xls dans feuille 2...... etc 1ére feuille de 3.xls dans feuille 4..

 

[titooooo]

Re : aide importation feuille ce calsseur excel

bonjour

pouvez vous au moins me donner un début de réponse

je compte sur vous

d'avance merci

 

[titooooo]

Re : aide importation feuille ce calsseur excel

bonjour

voici un exemple de ce que je veut avoir

j'ai mis ma matrice en plus d'un dossier avec mes fichier que je veux exporter dans le classer excel


d'avance 1000 merci

 

[job75]

Re : aide importation feuille ce calsseur excel

Bonsoir titooooo,

Après 329 posts vous avez enfin compris que joindre les fichiers aide à obtenir des réponses 🙄

Affectez au bouton cette macro :

Sub Importer()
Dim chemin$, fich$, nom$
chemin = ThisWorkbook.Path & "\export\"
Application.ScreenUpdating = False
Application.DisplayAlerts = False
On Error Resume Next 'si les feuilles n'existent pas
fich = Dir(chemin & "*.xls*") '1er fichier du dossier
While fich <> ""
  nom = Left(fich, InStrRev(fich, ".") - 1)
  ThisWorkbook.Sheets(nom).Delete
  With Workbooks.Open(chemin & fich)
    .Sheets(1).Copy After:=ThisWorkbook.Sheets(1)
    ThisWorkbook.Sheets(2).Name = nom
    .Close
  End With
  fich = Dir
Wend
ThisWorkbook.Sheets(1).Activate
End Sub

Bien sûr le fichier contenant la macro et le dossier "export" doivent être dans le même répertoire.

Bonne fin de soirée.

A+

 

[job75]

Re : aide importation feuille ce calsseur excel

Re,

Si les noms des feuilles sont modifiés peut-être faut-il supprimer toutes les feuilles sauf la 1ère et la feuille "recap" :

Sub Importer()
Dim chemin$, w As Worksheet, fich$
chemin = ThisWorkbook.Path & "\export\"
Application.ScreenUpdating = False
Application.DisplayAlerts = False
On Error Resume Next
For Each w In ThisWorkbook.Worksheets
  If w.Index > 1 And w.Name <> "recap" Then w.Delete
Next
fich = Dir(chemin & "*.xls*") '1er fichier du dossier
While fich <> ""
  Set w = Workbooks.Open(chemin & fich).Sheets(1)
  w.Copy After:=ThisWorkbook.Sheets(1)
  ThisWorkbook.Sheets(2).Name = Left(fich, InStrRev(fich, ".") - 1)
  w.Parent.Close
  fich = Dir
Wend
ThisWorkbook.Sheets(1).Activate
End Sub

A+

 

[titooooo]

Re : aide importation feuille ce calsseur excel

merci bien job75 je te remercie et merci le forum

 

[job75]

Re : aide importation feuille ce calsseur excel

Re,

J'ai juste fait une petite modif au post #5 avec Set w etc..., juste pour vous montrer cette méthode.

Bonne nuit