XL 2019 Aide formule avec trop d'arguments

  • Initiateur de la discussion Initiateur de la discussion Guillaumeg3
  • Date de début Date de début

Boostez vos compétences Excel avec notre communauté !

Rejoignez Excel Downloads, le rendez-vous des passionnés où l'entraide fait la force. Apprenez, échangez, progressez – et tout ça gratuitement ! 👉 Inscrivez-vous maintenant !

Guillaumeg3

XLDnaute Junior
Bonjour à tous,

Je bloque sur cette formule qui me revient en erreur en disant qu'il y a trop d'arguments.
Je n'arrive pas à localiser l'erreur
Je vous remercie pour votre aide:

Code:
=si([@[PHOTO OFFICIELS]]<>"";"";si(et([@[Longueur m]]<=14;[@[Type M/Y]]="M/Y");"1";si(et([@[Longueur m]]>14;[@[Longueur m]]<=25;[@[Type M/Y]]="M/Y");"2");si(et([@[Longueur m]]>25;[@[Longueur m]]<40;[@[Type M/Y]]="M/Y");"3";si(et([@[Longueur m]]>=40;[@[Type M/Y]]="M/Y");"4";si(et([@[Longueur m]]<=18;[@[TYPE S/Y]]="S/Y");"5";si(et([@[Longueur m]]>20;[@RIG]="";[@[TYPE S/Y]]="S/Y");"6";si(et([@[TYPE S/Y]]="S/Y";[@RIG]="CATAMARAN");"7";si(et([@[Type M/Y]]="M/Y";[@RIG]="CATAMARAN");"8";FAUX))))))))
 
Bonjour.
La parenthèse fermante finissant 'si(et([@[Longueur m]]>14;[@[Longueur m]]<=25;[@[Type M/Y]]="M/Y");"2")' est en trop.
Le cas "8" ne peut pas arriver, que [@RIG]="CATAMARAN" ou pas, il entre dans une catégorie précédente, contrairement au cas 7 qui va pour Longueur m > 18.
Cette version de la formule peut aboutir au cas "8" :
Code:
=SI([@[Type M/Y]]="M/Y";SI([@RIG]="CATAMARAN";"8";EQUIV([@[Longueur m]];{0;14,001;25,001;40})&"");
SI([@[Type S/Y]]="S/Y";SI([@RIG]="CATAMARAN";"7";INDEX({5;FAUX;6};EQUIV([@[Longueur m]];{0;18,001;20}))&"")))
 
Dernière édition:
J'avais oublié le test sur PHOYTO OFFICIELS. En l'intégrant j'ai fini par trouver ça :
Code:
=SI([@[PHOTO OFFICIELS]]="";
CHOISIR(1+([@[Type M/Y]]="M/Y")+2*([@[Type S/Y]]="S/Y");"Err. ni M/Y ni S/Y ?";
SI([@RIG]="CATAMARAN";"8";EQUIV([@[Longueur m]];{0;14,001;25,001;40})&"");
SI([@RIG]="CATAMARAN";"7";INDEX({5;"Err. 18 < Longueur <= 20";6};EQUIV([@[Longueur m]];{0;18,001;20,001}))&"");
"Err. M/Y et M/S ?");"")
Mais je soupçonne que pour les Type S/Y "S/Y" ce n'est pas exactement ce que vous vouliez pour les Longueur compris entre 18.001 et 20 mais sauf erreur de ma part c'est ce qui découlait de votre formule. Dites moi comment vous l'aurez rectifiée …
Et aussi pourquoi vous produisez un String d'un chiffre de "1" à "8" plutot qu'un entier de 1 à 8 ?
 
Dernière édition:
- Navigue sans publicité
- Accède à Cléa, notre assistante IA experte Excel... et pas que...
- Profite de fonctionnalités exclusives
Ton soutien permet à Excel Downloads de rester 100% gratuit et de continuer à rassembler les passionnés d'Excel.
Je deviens Supporter XLD

Discussions similaires

Réponses
5
Affichages
130
Réponses
1
Affichages
115
  • Question Question
Microsoft 365 Aide Excel formule
Réponses
4
Affichages
374
Réponses
20
Affichages
828
Réponses
3
Affichages
491
Réponses
18
Affichages
1 K
Réponses
18
Affichages
2 K
Retour