Afficher les lignes sous condition

[Ilino]

Bonjour Forum
Je vous sollicite a compléter mon code .
Dans la feuille j’ai une dizaine de tableaux indépendants chaque tableau ( de 101 lignes ) a une zone de saisie ( le code de zone de saisie pour remplir le tableau est fonctionnel ,merci JOb)
J’ai masqué les lignes de chaque tableau et Je souhaite afficher la ligne chaque fois que je saisie dans la zone de saisie est il possible ?*
Grazie
a+

 

[Ilino]

Re : Afficher les lignes sous condition

FORUM BONJOUR
JE RELANCE MA DEMANDE EST IL POSSIBLE 😕
A+

 

[job75]

Re : Afficher les lignes sous condition

Bonjour Ilino,

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Count > 1 Then 'interdit de modifier une plage (copier-coller)
  With Application: .EnableEvents = False: .Undo: .EnableEvents = True: End With
ElseIf Target.Column > 6 And Target.Interior.ColorIndex <> xlNone Then
  If Target = "Saisir ici !" Then Exit Sub
  If Target(101) <> "" Then
    MsgBox "La dernière cellule de la colonne est occupée !", 48
  'ElseIf Application.CountIf(Target.Resize(10), Target) > 1 Then
    'MsgBox "La donnée '" & Target & "' existe déjà !", 48
  Else
    If Target <> "" Then
      With Target(101).End(xlUp)(2)
        .Value = Target
        .EntireRow.Hidden = False 'affiche la ligne
      End With
    End If
  End If
  Target = "Saisir ici !": Target.Select
End If
End Sub

Nota : les tableaux ont 102 lignes (la ligne d'en-têtes compte), tu peux corriger...

A+

 

[job75]

Re : Afficher les lignes sous condition

Bonjour Ilino, le forum,

En complément, et pour bien commencer la journée :

Sub Afficher()
'touches Ctrl+A
Rows.Hidden = False
End Sub

Sub Masquer()
'touches Ctrl+M
Dim nlig&, ncol%, i&, dercel As Range, m As Range
nlig = 102 'nombre de lignes de chaque tableau
ncol = 11 'nombre de colonnes
For i = 4 To Me.UsedRange.Row + Me.UsedRange.Rows.Count - 1
  With Cells(i, 7) 'colonne G
    If .Interior.ColorIndex <> xlNone Then
      Set dercel = .Resize(nlig, ncol).Find("*", , , , xlByRows, xlPrevious)
      If dercel Is Nothing Then Set dercel = .Cells
      If dercel.Row < .Cells(nlig).Row Then
        With Rows(dercel.Row + 1 & ":" & .Cells(nlig).Row)
          Set m = Union(.Cells, IIf(m Is Nothing, .Cells, m))
        End With
      End If
    End If
  End With
Next
Application.ScreenUpdating = False
Afficher
If Not m Is Nothing Then m.EntireRow.Hidden = True
End Sub

Fichier joint.

A+

 

[job75]

Re : Afficher les lignes sous condition

Re,

En testant on remarquera que si des tableaux ont plus de 102 lignes ce n'est pas bien grave.

Par contre si des tableaux ont moins de 102 lignes c'est le pataquès.

A+

 

[job75]

Re : Afficher les lignes sous condition

Re,

Ah Ilino, petit coquin, je viens de me rendre compte que tu avais mis une couleur blanche à la cellule G5.

Ce genre de chose peut créer de sérieux problèmes avec les macros !

J'efface cette couleur sur le fichier du post #4, ne recommence pas.

A+

 

[Ilino]

Re : Afficher les lignes sous condition

Bonjour Job
désolé pour le retard and soory pour la couleor des cellule and ..... Mais je te dis que tu es le mielleur😱 super c'est exactement ce que je cherche un gros Merci MAITRE
GRAZIE