Adresse d une cellule suivant 3 criteres

[ri2]

Bonjour le Forum,
Je cherche une formule (indirect?) pour trouver l'adresse d'une cellule selon 3 critères différents ( sur 2 colonnes et 1 ligne) sans avoir a passer par une concatenation.
Ci-joint fichier exemple.

 

[Tibo]

Re : Adresse d une cellule suivant 3 criteres

Bonjour,

Une solution avec une formule matricielle, mais avec une concaténation :

=INDEX(BASE!C2:E6;EQUIV(B6&B7;BASE!A2:A6&BASE!B2:B6;0);
EQUIV(B8;BASE!C1:E1;0))

Formule à valider par CTRL + MAJ + ENTREE

Une autre sans concaténation et sans validation matricielle :

=INDEX(BASE!C2:E6;SOMMEPROD((BASE!A2:A6=B6)*(BASE!B2:B6=B7)*
LIGNE(BASE!A2:A6))-1;EQUIV(B8;BASE!C1:E1;0))

Je te laisse tester

@+

 

[Monique]

Re : Adresse d une cellule suivant 3 criteres

Bonjour,

Ou bien
=SOMMEPROD((BASE!A2:A6=B6)*(BASE!B2:B6=B7)*(BASE!C1:E1=B8);BASE!C2:E6)

ou bien
=SOMMEPROD((BASE!A2:A6&BASE!B2:B6=B6&B7)*(BASE!C1:E1=B8);BASE!C2:E6)

 

[ri2]

Re : Adresse d une cellule suivant 3 criteres

Merci, la 2eme solution me convient car je ne veux pas avoir a modifier ma base.
Par contre, j'etais plutot parti sur les fonctions indirect adresse pour avoir a eviter justement la fonction sommeprod qui est "gourmande" sur une grosse base de donnes.
En te remerciant
@+

 

[ri2]

Re : Adresse d une cellule suivant 3 criteres

Oups, pas vu l'arrivée de Monique. Merci à toi également. Maitrisant mal la fonction Index, je pense que je vais retenir ta solution
Cordialement

 

[GIBI]

Re : Adresse d une cellule suivant 3 criteres

bonjour,

dans votre exemple il faut mettre dans la cellule résultat (exemple en D7)

=INDEX(BASE!C2:H20;EQUIV(B7;DECALER(BASE!B2:B20;EQUIV(B6;BASE!A2:A20;0)-1;0;NB.SI(BASE!A2:A20;B6);1);0);EQUIV(B8;BASE!C1:H1;0))

rechercher le 1ier N) de ligne du véhicule EQUIV(B6;BASE!A2:A20;0)
Redefinir la plage du model avec DECALER
Rechercher le n° de ligne du model dans la plage "décaler"
Etc..


Et voila!

Maintenant un peu de reflexion

GIBI


PS Méthode plus génarale car la donnée final peut être alphanumérique, mais il faut que les deux premiers critères soit en séquence

 

[ri2]

Re : Adresse d une cellule suivant 3 criteres

Merci GIBI, je cherchais ce genre de formule ( ma base de données est conséquente ), reste plus qu'a essayer de comprendre un peu mieux !!
Bon WE à vous