zone de traçage sur graph nuages de points

[dam3117]

Bonjour à tous les exceliens,
J'ai un fichier avec un graph nuages de points et un zone de traçage ou se trouve une carte météo.
Dans un même dossier j'ai plusieurs de ces cartes (format.png).
je voudrai à partir d'un combobox pourvoir choisir une de ces carte pour changer ma zone de traçage.

merci d'avance

dam

 

[PMO2]

Re : zone de traçage sur graph nuages de points

Bonjour,

Une piste avec les codes ci-dessous à ajouter à votre classeur.

FAIRE
1) créer un UserForm (avec le nom UserForm2)
2) Y mettre un ComboBox et un CommandButton ayant pour nom, respectivement, ComboBox1 et CommandButton1
3) coller le code suivant dans la fenêtre de code du UserForm

Private CB As ComboBox

Private Sub CommandButton1_Click()
Dim C As Chart
If CB.SelText = "" Then
  Me.Hide
  Exit Sub
End If
Set C = Sheets("CARTE").ChartArea.Parent
C.PlotArea.Fill.UserPicture PictureFile:= _
    ActiveWorkbook.Path & "\" & CB.SelText & ".png"
Me.Hide
End Sub

Private Sub UserForm_Initialize()
Dim FS As FileSearch
Dim i&
Dim A$
Me.Caption = "Choisir une carte"
Set CB = Me.ComboBox1
Set FS = Application.FileSearch
With FS
  .LookIn = ActiveWorkbook.Path
  .Filename = "*.png"
  .Execute (msoSortByFileName)
  For i& = 1 To .FoundFiles.Count
    A$ = .FoundFiles(i&)
    A$ = Mid(A$, 1, Len(A$) - 4)
    A$ = Mid(A$, InStrRev(A$, "\") + 1)
    CB.AddItem A$
  Next i&
End With
End Sub

4) dans module standard copier le code suivant

Sub Launch_pmo()
UserForm2.Show vbModeless
End Sub

Dans le MEME dossier contenant votre classeur, ajoutez vos cartes .png
Il n'y a plus qu'à lancer la macro Launch_pmo.

Cordialement.

PMO
Patrick Morange