Worksheet Change [copier/coller entre 2 feuilles]

[melanie06]

Bonjour,
je rencontre actuellement un soucis sur un fichier excel et plus particulièrement sur un Worksheet Change.

Je souhaiterais que dès qu'une cellule de la colonne A est remplie, il y ai un copié/collé d'une plage de cellule située sur une autre feuille juste a côté de la case remplie. (Feuil2)

En gros si la case A1 est remplie, le copié / collé de la plage de cellule aura lieu sur la case B1.

J'ai déjà essayé avec diverses formules mais rien ne fonctionne...
Je vous joint un fichier annoté pour une meilleure compréhension en espérant que vous pourrez m'aider!

Merci d'avance je suis totalement bloquée!

 

[Robert]

Re : Worksheet Change [copier/coller entre 2 feuilles]

Bonjour Mélanie et bienvenue, bonjour le forum,

Peut-être comme ça :

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Column <> 1 Then Exit Sub 'si l'édition a lieu ailleurs que dans la colonne 1, sort de la procédure
 
If Target.Value <> "" Then 'condition "si la cellule modifiée n'est pas effacée
    Sheets("Feuil2").Range("A1:C1").Copy Target.Offset(0, 1) 'copie la plage A1:C1 de l'onglet "Feuil2" et la colle a coté de la cellule modifiée
Else 'sinon
    Range(Target.Offset(0, 1), Target.Offset(0, 3)).Clear 'supprime le contenu des colonnes B à D de la cellule effacée
End If 'fin de la condition
End Sub

 

[Dull]

Re : Worksheet Change [copier/coller entre 2 feuilles]

Salut melanie06 et Bienvenue, le Forum

Pas sur d'avoir compris mais essaye ce code dans le Module de la Feuille

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, [A:A]) Is Nothing Then
Feuil2.Range("A1:C1").Copy Destination:=Feuil1.Range(Target.Offset(, 1).Address)
End If
End Sub

EDIT: Salut Robert 🙂, Salut Misange 🙂
Bonne Journée

 

[Misange]

Re : Worksheet Change [copier/coller entre 2 feuilles]

Bonjour et bienvenue

ta question est quasi la même que celle-ci
https://www.excel-downloads.com/threads/si-cellule-nest-pas-vide-alors.169772/
c'est un hasard ?
En tous cas la réponse que je donne dans ce fil est la même que pour cette question. Pas besoin de macro pour cela.

 

[melanie06]

Re : Worksheet Change [copier/coller entre 2 feuilles]

Bonjour à tous et merci pour votre accueil !
en adaptant vos réponses à mon fichier personnel tout fonctionne à merveille merci Dull et Robert
Merci également à Misange, c'est un projet donné à plusieurs personnes dans un certain cadre, cela m'étonne un peu de retrouver un congénère sur ce forum!

Comme quoi cela nous donne vraiment du fil à retorde!

Encore une fois milles merci!

 

[Theze]

Re : Worksheet Change [copier/coller entre 2 feuilles]

Bonjour,

Teste ceci :

Private Sub Worksheet_Change(ByVal Target As Range)
    
    Dim T
    
    If Target.Column = 1 Then
    
        If Target = "" Then Exit Sub
        
        With Worksheets("Feuil2")
        
            T = .Range(.Cells(Target.Row, 1), .Cells(Target.Row, 3))
            
        End With
        
        Range(Cells(Target.Row, 2), Cells(Target.Row, 4)) = T
        
    End If
    
End Sub

hervé.