VBA - Vérifier la présence d'une liste de validation

[Troudz]

Bonjour,

Je voudrais pouvoir tester la présence d'une liste de validation dans une cellule à l'aide d'une macro mais je ne trouve pas la bonne syntaxe.

J'ai testé :

If .Cells(1,1).Validation Type = xlValidateList Then

et

If .Cells(1,1).Validation.Type = xlValidateList Then

mais aucun ne fonctionne. Auriez vous une idée sur la façon d'effectuer ce test ?

Je vous remercie par avance de votre aide

 

[natorp]

Re : VBA - Vérifier la présence d'une liste de validation

Bjr Troudz,

en s'inspirant de ça, trouvé sur le net par Silkyroad :

Sub Test()
    'Vérifie si la cellule B1 contient une liste de validation.
    MsgBox ValidationExiste(Range("B1"))
End Sub
 
 
Function ValidationExiste(Cell As Range) As Boolean
    Dim Cible As Range
 
    On Error Resume Next
    'Définit toutes les cellules contenant une liste de validation dans la feuille active.
    Set Cible = ActiveSheet.Cells.SpecialCells(xlCellTypeAllValidation)
    On Error GoTo 0
 
    If Not Cible Is Nothing Then
        If Not Intersect(Cible, Cell) Is Nothing Then
            ValidationExiste = True
            Else
            ValidationExiste = False
        End If
    Else
        ValidationExiste = False
    End If
End Function

Cordialement, Gérard

 

[BOISGONTIER]

Re : VBA - Vérifier la présence d'une liste de validation

Bonjour,

Peut être ça.

Function estListe(c As Range)
  On Error Resume Next
  tmp = c.Validation.Formula1
  estListe = (Err = 0)
End Function

JB

 

[Troudz]

Re : VBA - Vérifier la présence d'une liste de validation

En plein dans le mille ! Ça fonctionne impec ! Merci pour le coup de main