XL 2013 VBA Sélection d'une feuille selon un critère

[angie19]

Bonjour,

J'aimerais créer une macro me permettant de récupérer les données d'une feuille excel qui est la plus récente dans mon classeur.
Dans ce classeur, chaque feuille est identique mise à part les données qui la composent et chaque feuille a une date entrée manuellement en B3.
Dans ma macro, j'aimerais pouvoir sélectionner la feuille telle que la date en B3 (toutes feuilles du classeur confondues) est la plus récente et j'aimerais savoir si c'est possible ?

J'espère avoir été claire sur mon problème et vous remercie par avance

Angie

 

[Bernard_XLD]

Bonjour angie19, le forum

Voici une macro qui devrait faire cela !

Bien cordialement, @+

Sub Trouver_Date_Max()
Dim Wsht As Worksheet, WshtF As Worksheet, DateMax As Date
For Each Wsht In ActiveWorkbook.Worksheets 'pour chaque feuille de travail du classeur actif
    If IsDate(Wsht.Range("B3").Value) Then 'si B3 est une date
        If Wsht.Range("B3").Value > DateMax Then 'si B3 est supérieur à date max
            DateMax = Wsht.Range("B3").Value 'date max = B3
            Set WshtF = Wsht ' feuille finale=feuille en cours
        End If
    End If
Next Wsht
If WshtF Is Nothing Then 'si feuille finale n'existe pas
    MsgBox "Feuille introuvable", vbOKOnly + vbInformation
Else
    WshtF.Select 'feuille finale sélectionnée si existe
    Range("B3").Select 'date sélectionnée
    MsgBox "Feuille " & WshtF.Name & " sélectionnée", vbOKOnly + vbInformation
End If
End Sub

 

[angie19]

Oh merci beaucoup, j'essaie de comprendre la syntaxe puis j'irai tester cette solution dès que possible !
En tout cas, merci pour votre temps, à bientôt !

 

[Bernard_XLD]

Re,

j'essaie de comprendre la syntaxe

j'ai documenté le code du post 2 pour vous aider.

Bonne journée
Bien cordialement, @+

 

[angie19]

Re

Merci pour les précisions, ça m'a bien aidé.
J'ai pu tester et intégrer votre solution dans ma macro et ça a fonctionné nickel !

Mille mercis !!